matita/matita/contribs/lambdadelta/basic_2/dynamic/nv_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/cpms_drops.ma".
  16 include "basic_2/dynamic/nv.ma".
  17
  18 (* NATIVE VALIDITY FOR TERMS ************************************************)
  19
  20 (* Advanced dproperties *****************************************************)
  21
  22 (* Basic_2A1: uses: snv_lref *)
  23 lemma nv_lref_drops (a) (h) (G): ∀I,K,V,i,L. ⦃G, K⦄ ⊢ V ![a, h] →
  24                                  ⬇*[i] L ≘ K.ⓑ{I}V →  ⦃G, L⦄ ⊢ #i ![a, h].
  25 #a #h #G #I #K #V #i elim i -i
  26 [ #L #HV #H
  27   lapply (drops_fwd_isid … H ?) -H // #H destruct
  28   /2 width=1 by nv_zero/
  29 | #i #IH #L #HV #H
  30   elim (drops_inv_succ … H) -H #J0 #K0 #HK0 #H destruct
  31   /3 width=1 by nv_lref/
  32 ]
  33 qed.
  34
  35 (* Advanced inversion lemmas ************************************************)
  36
  37 (* Basic_2A1: uses: snv_inv_lref *)
  38 lemma nv_inv_lref_drops (a) (h) (G):
  39                         ∀i,L. ⦃G, L⦄ ⊢ #i ![a, h] →
  40                         ∃∃I,K,V. ⬇*[i] L ≘ K.ⓑ{I}V & ⦃G, K⦄ ⊢ V ![a, h].
  41 #a #h #G #i elim i -i
  42 [ #L #H
  43   elim (nv_inv_zero … H) -H #I #K #V #HV #H destruct
  44   /3 width=5 by drops_refl, ex2_3_intro/
  45 | #i #IH #X #H
  46   elim (nv_inv_lref … H) -H #I #L #HL #H destruct
  47   elim (IH … HL) -IH -HL #J #K #V #HLK #HV
  48   /3 width=5 by drops_drop, ex2_3_intro/
  49 ]
  50 qed-.
  51
  52 (* Properties with generic slicing for local environments *******************)
  53
  54 (* Basic_2A1: uses: snv_lift *)
  55 lemma sv_lifts (a) (h): ∀G. d_liftable1 (nv a h G).
  56 #a #h #G #K #T
  57 @(fqup_wf_ind_eq (Ⓣ) … G K T) -G -K -T #G0 #K0 #T0 #IH #G #K * * [|||| * ]
  58 [ #s #HG #HK #HT #_ #b #f #L #_ #X #H2 destruct
  59   >(lifts_inv_sort1 … H2) -X -K -f //
  60 | #i #HG #HK #HT #H1 #b #f #L #HLK #X #H2 destruct
  61   elim (nv_inv_lref_drops … H1) -H1 #I0 #K0 #V #HK0 #HV
  62   elim (lifts_inv_lref1 … H2) -H2 #j #Hf #H destruct
  63 (**) (* this should be a lemma *)
  64   lapply (drops_trans … HLK … HK0 ??) -HLK [3,6: |*: // ] #H
  65   elim (drops_split_trans … H) -H [1,6: |*: /2 width=6 by after_uni_dx/ ] #Y #HL #HY
  66   lapply (drops_tls_at … Hf … HY) -HY #HY
  67   elim (drops_inv_skip2 … HY) -HY #Z #L0 #HLK0 #HZ #H destruct
  68   elim (liftsb_inv_pair_sn … HZ) -HZ #W #HVW #H destruct
  69 (**) (* end of the lemma *)
  70   /4 width=8 by nv_lref_drops, fqup_lref, drops_inv_gen/
  71 | #l #HG #HK #HT #H1 #b #f #L #_ #X #_ destruct
  72   elim (nv_inv_gref … H1)
  73 | #p #I #V #T #HG #HK #HT #H1 #b #f #L #HLK #X #H2 destruct
  74   elim (nv_inv_bind … H1) -H1 #HV #HT
  75   elim (lifts_inv_bind1 … H2) -H2 #W #U #HVW #HTU #H destruct
  76   /5 width=8 by nv_bind, drops_skip, ext2_pair/
  77 | #V #T #HG #HK #HT #H1 #b #f #L #HLK #X #H2 destruct
  78   elim (nv_inv_appl … H1) #n #p #W0 #U0 #Ha #HV #HT #HVW0 #HTW0
  79   elim (lifts_inv_flat1 … H2) -H2 #W #U #HVW #HTU #H destruct
  80   elim (lifts_total W0 f)
  81   elim (lifts_total U0 (⫯f))
  82   /4 width=17 by nv_appl, cpms_lifts_bi, lifts_bind/
  83 | #V #T #HG #HK #HT #H1 #b #f #L #HLK #X #H2 destruct
  84   elim (nv_inv_cast … H1) #U0 #HV #HT #HVU0 #HTU0
  85   elim (lifts_inv_flat1 … H2) -H2 #W #U #HVW #HTU #H destruct
  86   elim (lifts_total U0 f)
  87   /3 width=12 by nv_cast, cpms_lifts_bi/
  88 ]
  89 qed-.
  90
  91 (* Inversion lemmas with generic slicing for local environments *************)
  92
  93 (* Basic_2A1: uses: snv_inv_lift *)
  94 lemma nv_inv_lifts (a) (h): ∀G. d_deliftable1 (nv a h G).
  95 #a #h #G #L #U
  96 @(fqup_wf_ind_eq (Ⓣ) … G L U) -G -L -U #G0 #L0 #U0 #IH #G #L * * [|||| * ]
  97 [ #s #HG #HL #HU #H1 #b #f #K #HLK #X #H2 destruct
  98   >(lifts_inv_sort2 … H2) -X -L -f //
  99 | #j #HG #HL #HU #H1 #b #f #K #HLK #X #H2 destruct
 100   elim (nv_inv_lref_drops … H1) -H1 #I0 #L0 #W #HL0 #HW
 101   elim (lifts_inv_lref2 … H2) -H2 #i #Hf #H destruct
 102 (**) (* this should be a lemma *)
 103   lapply (drops_split_div … HLK (𝐔❴i❵) ???) -HLK [4,8: * |*: // ] #Y0 #HK #HLY0
 104   lapply (drops_conf … HL0 … HLY0 ??) -HLY0 [3,6: |*: /2 width=6 by after_uni_dx/ ] #HLY0
 105   lapply (drops_tls_at … Hf … HLY0) -HLY0 #HLY0
 106   elim (drops_inv_skip1 … HLY0) -HLY0 #Z #K0 #HLK0 #HZ #H destruct
 107   elim (liftsb_inv_pair_dx … HZ) -HZ #V #HVW #H destruct
 108 (**) (* end of the lemma *)
 109   /4 width=8 by nv_lref_drops, fqup_lref, drops_inv_F/
 110 | #l #HG #HL #HU #H1 #b #f #K #_ #X #_ destruct
 111   elim (nv_inv_gref … H1)
 112 | #p #I #W #U #HG #HL #HU #H1 #b #f #K #HLK #X #H2 destruct
 113   elim (nv_inv_bind … H1) -H1 #HW #HU
 114   elim (lifts_inv_bind2 … H2) -H2 #V #T #HVW #HTU #H destruct
 115   /5 width=8 by nv_bind, drops_skip, ext2_pair/
 116 | #W #U #HG #HL #HU #H1 #b #f #K #HLK #X #H2 destruct
 117   elim (nv_inv_appl … H1) #n #p #W0 #U0 #Ha #HW #HU #HW0 #HU0
 118   elim (lifts_inv_flat2 … H2) -H2 #V #T #HVW #HTU #H destruct
 119   elim (cpms_inv_lifts_sn … HW0 … HLK … HVW) -HW0 #V0 #HVW0 #HV0
 120   elim (cpms_inv_lifts_sn … HU0 … HLK … HTU) -HU0 #X0 #H #HT0
 121   elim (lifts_inv_bind2 … H) -H #X #T0 #HX #HTU0 #H destruct
 122   lapply (lifts_inj … HX … HVW0) -HX #H destruct
 123   /3 width=8 by nv_appl/
 124 | #W #U #HG #HL #HU #H1 #b #f #K #HLK #X #H2 destruct
 125   elim (nv_inv_cast … H1) #U0 #HW #HU #HWU0 #HU0
 126   elim (lifts_inv_flat2 … H2) -H2 #V #T #HVW #HTU #H destruct
 127   elim (cpms_inv_lifts_sn … HWU0 … HLK … HVW) -HWU0 #V0 #HVU0 #HV0
 128   elim (cpms_inv_lifts_sn … HU0 … HLK … HTU) -HU0 #X #HX #HTV0
 129   lapply (lifts_inj … HX … HVU0) -HX #H destruct
 130   /3 width=8 by nv_cast/
 131 ]
 132 qed-.