matita/matita/contribs/lambdadelta/basic_2/dynamic/snv.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/nativevalid_5.ma".
  16 include "basic_2/computation/cpds.ma".
  17 include "basic_2/equivalence/cpcs.ma".
  18
  19 (* STRATIFIED NATIVE VALIDITY FOR TERMS *************************************)
  20
  21 (* activate genv *)
  22 inductive snv (h:sh) (g:sd h): relation3 genv lenv term ≝
  23 | snv_sort: ∀G,L,k. snv h g G L (⋆k)
  24 | snv_lref: ∀I,G,L,K,V,i. ⇩[0, i] L ≡ K.ⓑ{I}V → snv h g G K V → snv h g G L (#i)
  25 | snv_bind: ∀a,I,G,L,V,T. snv h g G L V → snv h g G (L.ⓑ{I}V) T → snv h g G L (ⓑ{a,I}V.T)
  26 | snv_appl: ∀a,G,L,V,W,W0,T,U,l. snv h g G L V → snv h g G L T →
  27             ⦃G, L⦄ ⊢ V •[h, g] ⦃l+1, W⦄ → ⦃G, L⦄ ⊢ W ➡* W0 →
  28             ⦃G, L⦄ ⊢ T •*➡*[h, g] ⓛ{a}W0.U → snv h g G L (ⓐV.T)
  29 | snv_cast: ∀G,L,W,T,U,l. snv h g G L W → snv h g G L T →
  30             ⦃G, L⦄ ⊢ T •[h, g] ⦃l+1, U⦄ → ⦃G, L⦄ ⊢ U ⬌* W → snv h g G L (ⓝW.T)
  31 .
  32
  33 interpretation "stratified native validity (term)"
  34    'NativeValid h g G L T = (snv h g G L T).
  35
  36 (* Basic inversion lemmas ***************************************************)
  37
  38 fact snv_inv_lref_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀i. X = #i →
  39                        ∃∃I,K,V. ⇩[0, i] L ≡ K.ⓑ{I}V & ⦃G, K⦄ ⊢ V ¡[h, g].
  40 #h #g #G #L #X * -G -L -X
  41 [ #G #L #k #i #H destruct
  42 | #I #G #L #K #V #i0 #HLK #HV #i #H destruct /2 width=5/
  43 | #a #I #G #L #V #T #_ #_ #i #H destruct
  44 | #a #G #L #V #W #W0 #T #U #l #_ #_ #_ #_ #_ #i #H destruct
  45 | #G #L #W #T #U #l #_ #_ #_ #_ #i #H destruct
  46 ]
  47 qed-.
  48
  49 lemma snv_inv_lref: ∀h,g,G,L,i. ⦃G, L⦄ ⊢ #i ¡[h, g] →
  50                     ∃∃I,K,V. ⇩[0, i] L ≡ K.ⓑ{I}V & ⦃G, K⦄ ⊢ V ¡[h, g].
  51 /2 width=3 by snv_inv_lref_aux/ qed-.
  52
  53 fact snv_inv_gref_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀p. X = §p → ⊥.
  54 #h #g #G #L #X * -G -L -X
  55 [ #G #L #k #p #H destruct
  56 | #I #G #L #K #V #i #_ #_ #p #H destruct
  57 | #a #I #G #L #V #T #_ #_ #p #H destruct
  58 | #a #G #L #V #W #W0 #T #U #l #_ #_ #_ #_ #_ #p #H destruct
  59 | #G #L #W #T #U #l #_ #_ #_ #_ #p #H destruct
  60 ]
  61 qed-.
  62
  63 lemma snv_inv_gref: ∀h,g,G,L,p. ⦃G, L⦄ ⊢ §p ¡[h, g] → ⊥.
  64 /2 width=8 by snv_inv_gref_aux/ qed-.
  65
  66 fact snv_inv_bind_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀a,I,V,T. X = ⓑ{a,I}V.T →
  67                        ⦃G, L⦄ ⊢ V ¡[h, g] ∧ ⦃G, L.ⓑ{I}V⦄ ⊢ T ¡[h, g].
  68 #h #g #G #L #X * -G -L -X
  69 [ #G #L #k #a #I #V #T #H destruct
  70 | #I0 #G #L #K #V0 #i #_ #_ #a #I #V #T #H destruct
  71 | #b #I0 #G #L #V0 #T0 #HV0 #HT0 #a #I #V #T #H destruct /2 width=1/
  72 | #b #G #L #V0 #W0 #W00 #T0 #U0 #l #_ #_ #_ #_ #_ #a #I #V #T #H destruct
  73 | #G #L #W0 #T0 #U0 #l #_ #_ #_ #_ #a #I #V #T #H destruct
  74 ]
  75 qed-.
  76
  77 lemma snv_inv_bind: ∀h,g,a,I,G,L,V,T. ⦃G, L⦄ ⊢ ⓑ{a,I}V.T ¡[h, g] →
  78                         ⦃G, L⦄ ⊢ V ¡[h, g] ∧ ⦃G, L.ⓑ{I}V⦄ ⊢ T ¡[h, g].
  79 /2 width=4 by snv_inv_bind_aux/ qed-.
  80
  81 fact snv_inv_appl_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀V,T. X = ⓐV.T →
  82                        ∃∃a,W,W0,U,l. ⦃G, L⦄ ⊢ V ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
  83                                    ⦃G, L⦄ ⊢ V •[h, g] ⦃l+1, W⦄ & ⦃G, L⦄ ⊢ W ➡* W0 &
  84                                    ⦃G, L⦄ ⊢ T •*➡*[h, g] ⓛ{a}W0.U.
  85 #h #g #G #L #X * -L -X
  86 [ #G #L #k #V #T #H destruct
  87 | #I #G #L #K #V0 #i #_ #_ #V #T #H destruct
  88 | #a #I #G #L #V0 #T0 #_ #_ #V #T #H destruct
  89 | #a #G #L #V0 #W0 #W00 #T0 #U0 #l #HV0 #HT0 #HVW0 #HW00 #HTU0 #V #T #H destruct /2 width=8/
  90 | #G #L #W0 #T0 #U0 #l #_ #_ #_ #_ #V #T #H destruct
  91 ]
  92 qed-.
  93
  94 lemma snv_inv_appl: ∀h,g,G,L,V,T. ⦃G, L⦄ ⊢ ⓐV.T ¡[h, g] →
  95                     ∃∃a,W,W0,U,l. ⦃G, L⦄ ⊢ V ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
  96                                 ⦃G, L⦄ ⊢ V •[h, g] ⦃l+1, W⦄ & ⦃G, L⦄ ⊢ W ➡* W0 &
  97                                 ⦃G, L⦄ ⊢ T •*➡*[h, g] ⓛ{a}W0.U.
  98 /2 width=3 by snv_inv_appl_aux/ qed-.
  99
 100 fact snv_inv_cast_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀W,T. X = ⓝW.T →
 101                        ∃∃U,l. ⦃G, L⦄ ⊢ W ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
 102                               ⦃G, L⦄ ⊢ T •[h, g] ⦃l+1, U⦄ & ⦃G, L⦄ ⊢ U ⬌* W.
 103 #h #g #G #L #X * -G -L -X
 104 [ #G #L #k #W #T #H destruct
 105 | #I #G #L #K #V #i #_ #_ #W #T #H destruct
 106 | #a #I #G #L #V #T0 #_ #_ #W #T #H destruct
 107 | #a #G #L #V #W0 #W00 #T0 #U #l #_ #_ #_ #_ #_ #W #T #H destruct
 108 | #G #L #W0 #T0 #U0 #l #HW0 #HT0 #HTU0 #HUW0 #W #T #H destruct /2 width=4/
 109 ]
 110 qed-.
 111
 112 lemma snv_inv_cast: ∀h,g,G,L,W,T. ⦃G, L⦄ ⊢ ⓝW.T ¡[h, g] →
 113                     ∃∃U,l. ⦃G, L⦄ ⊢ W ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
 114                            ⦃G, L⦄ ⊢ T •[h, g] ⦃l+1, U⦄ & ⦃G, L⦄ ⊢ U ⬌* W.
 115 /2 width=3 by snv_inv_cast_aux/ qed-.
 116
 117 (* Basic forward lemmas *****************************************************)
 118
 119 lemma snv_fwd_ssta: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ T ¡[h, g] → ∃∃l,U. ⦃G, L⦄ ⊢ T •[h, g] ⦃l, U⦄.
 120 #h #g #G #L #T #H elim H -G -L -T
 121 [ #G #L #k elim (deg_total h g k) /3 width=3/
 122 | * #G #L #K #V #i #HLK #_ * #l0 #W #HVW
 123   [ elim (lift_total W 0 (i+1)) /3 width=8/
 124   | elim (lift_total V 0 (i+1)) /3 width=8/
 125   ]
 126 | #a #I #G #L #V #T #_ #_ #_ * /3 width=3/
 127 | #a #G #L #V #W #W1 #T0 #T1 #l #_ #_ #_ #_ #_ #_ * /3 width=3/
 128 | #G #L #W #T #U #l #_ #_ #HTU #_ #_ #_ /3 width=3/ (**) (* auto fails without the last #_ *)
 129 ]
 130 qed-.