matita/matita/contribs/lambdadelta/basic_2/dynamic/snv.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/nativevalid_5.ma".
  16 include "basic_2/computation/cpds.ma".
  17 include "basic_2/equivalence/cpcs.ma".
  18
  19 (* STRATIFIED NATIVE VALIDITY FOR TERMS *************************************)
  20
  21 definition scast: ∀h. sd h → nat → relation4 genv lenv term term ≝
  22                   λh,g,l,G,L,V,W. ∀V0,W0,l0.
  23                   l0 ≤ l → ⦃G, L⦄ ⊢ V •*[h, g, l0+1] V0 → ⦃G, L⦄ ⊢ W •*[h, g, l0] W0 → ⦃G, L⦄ ⊢ V0 ⬌* W0.
  24
  25 (* activate genv *)
  26 inductive snv (h:sh) (g:sd h): relation3 genv lenv term ≝
  27 | snv_sort: ∀G,L,k. snv h g G L (⋆k)
  28 | snv_lref: ∀I,G,L,K,V,i. ⇩[i] L ≡ K.ⓑ{I}V → snv h g G K V → snv h g G L (#i)
  29 | snv_bind: ∀a,I,G,L,V,T. snv h g G L V → snv h g G (L.ⓑ{I}V) T → snv h g G L (ⓑ{a,I}V.T)
  30 | snv_appl: ∀a,G,L,V,W,W0,T,U,l. snv h g G L V → snv h g G L T →
  31             ⦃G, L⦄ ⊢ V ▪[h, g] l+1 → ⦃G, L⦄ ⊢ V •[h, g] W → ⦃G, L⦄ ⊢ W ➡* W0 →
  32             ⦃G, L⦄ ⊢ T •*➡*[h, g] ⓛ{a}W0.U → snv h g G L (ⓐV.T)
  33 | snv_cast: ∀G,L,W,T,U,l. snv h g G L W → snv h g G L T →
  34             ⦃G, L⦄ ⊢ T ▪[h, g] l+1 → ⦃G, L⦄ ⊢ T •[h, g] U → ⦃G, L⦄ ⊢ U ⬌* W → snv h g G L (ⓝW.T)
  35 .
  36
  37 interpretation "stratified native validity (term)"
  38    'NativeValid h g G L T = (snv h g G L T).
  39
  40 (* Basic inversion lemmas ***************************************************)
  41
  42 fact snv_inv_lref_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀i. X = #i →
  43                        ∃∃I,K,V. ⇩[i] L ≡ K.ⓑ{I}V & ⦃G, K⦄ ⊢ V ¡[h, g].
  44 #h #g #G #L #X * -G -L -X
  45 [ #G #L #k #i #H destruct
  46 | #I #G #L #K #V #i0 #HLK #HV #i #H destruct /2 width=5 by ex2_3_intro/
  47 | #a #I #G #L #V #T #_ #_ #i #H destruct
  48 | #a #G #L #V #W #W0 #T #U #l #_ #_ #_ #_ #_ #_ #i #H destruct
  49 | #G #L #W #T #U #l #_ #_ #_ #_ #_ #i #H destruct
  50 ]
  51 qed-.
  52
  53 lemma snv_inv_lref: ∀h,g,G,L,i. ⦃G, L⦄ ⊢ #i ¡[h, g] →
  54                     ∃∃I,K,V. ⇩[i] L ≡ K.ⓑ{I}V & ⦃G, K⦄ ⊢ V ¡[h, g].
  55 /2 width=3 by snv_inv_lref_aux/ qed-.
  56
  57 fact snv_inv_gref_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀p. X = §p → ⊥.
  58 #h #g #G #L #X * -G -L -X
  59 [ #G #L #k #p #H destruct
  60 | #I #G #L #K #V #i #_ #_ #p #H destruct
  61 | #a #I #G #L #V #T #_ #_ #p #H destruct
  62 | #a #G #L #V #W #W0 #T #U #l #_ #_ #_ #_ #_ #_ #p #H destruct
  63 | #G #L #W #T #U #l #_ #_ #_ #_ #_ #p #H destruct
  64 ]
  65 qed-.
  66
  67 lemma snv_inv_gref: ∀h,g,G,L,p. ⦃G, L⦄ ⊢ §p ¡[h, g] → ⊥.
  68 /2 width=8 by snv_inv_gref_aux/ qed-.
  69
  70 fact snv_inv_bind_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀a,I,V,T. X = ⓑ{a,I}V.T →
  71                        ⦃G, L⦄ ⊢ V ¡[h, g] ∧ ⦃G, L.ⓑ{I}V⦄ ⊢ T ¡[h, g].
  72 #h #g #G #L #X * -G -L -X
  73 [ #G #L #k #a #I #V #T #H destruct
  74 | #I0 #G #L #K #V0 #i #_ #_ #a #I #V #T #H destruct
  75 | #b #I0 #G #L #V0 #T0 #HV0 #HT0 #a #I #V #T #H destruct /2 width=1 by conj/
  76 | #b #G #L #V0 #W0 #W00 #T0 #U0 #l #_ #_ #_ #_#_ #_ #a #I #V #T #H destruct
  77 | #G #L #W0 #T0 #U0 #l #_ #_ #_ #_ #_ #a #I #V #T #H destruct
  78 ]
  79 qed-.
  80
  81 lemma snv_inv_bind: ∀h,g,a,I,G,L,V,T. ⦃G, L⦄ ⊢ ⓑ{a,I}V.T ¡[h, g] →
  82                     ⦃G, L⦄ ⊢ V ¡[h, g] ∧ ⦃G, L.ⓑ{I}V⦄ ⊢ T ¡[h, g].
  83 /2 width=4 by snv_inv_bind_aux/ qed-.
  84
  85 fact snv_inv_appl_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀V,T. X = ⓐV.T →
  86                        ∃∃a,W,W0,U,l. ⦃G, L⦄ ⊢ V ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
  87                                      ⦃G, L⦄ ⊢ V ▪[h, g] l+1 & ⦃G, L⦄ ⊢ V •[h, g] W & ⦃G, L⦄ ⊢ W ➡* W0 &
  88                                      ⦃G, L⦄ ⊢ T •*➡*[h, g] ⓛ{a}W0.U.
  89 #h #g #G #L #X * -L -X
  90 [ #G #L #k #V #T #H destruct
  91 | #I #G #L #K #V0 #i #_ #_ #V #T #H destruct
  92 | #a #I #G #L #V0 #T0 #_ #_ #V #T #H destruct
  93 | #a #G #L #V0 #W0 #W00 #T0 #U0 #l #HV0 #HT0 #Hl #HVW0 #HW00 #HTU0 #V #T #H destruct /2 width=8 by ex6_5_intro/
  94 | #G #L #W0 #T0 #U0 #l #_ #_ #_ #_ #_ #V #T #H destruct
  95 ]
  96 qed-.
  97
  98 lemma snv_inv_appl: ∀h,g,G,L,V,T. ⦃G, L⦄ ⊢ ⓐV.T ¡[h, g] →
  99                     ∃∃a,W,W0,U,l. ⦃G, L⦄ ⊢ V ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
 100                                   ⦃G, L⦄ ⊢ V ▪[h, g] l+1 & ⦃G, L⦄ ⊢ V •[h, g] W & ⦃G, L⦄ ⊢ W ➡* W0 &
 101                                   ⦃G, L⦄ ⊢ T •*➡*[h, g] ⓛ{a}W0.U.
 102 /2 width=3 by snv_inv_appl_aux/ qed-.
 103
 104 fact snv_inv_cast_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀W,T. X = ⓝW.T →
 105                        ∃∃U,l. ⦃G, L⦄ ⊢ W ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
 106                               ⦃G, L⦄ ⊢ T ▪[h, g] l+1 & ⦃G, L⦄ ⊢ T •[h, g] U & ⦃G, L⦄ ⊢ U ⬌* W.
 107 #h #g #G #L #X * -G -L -X
 108 [ #G #L #k #W #T #H destruct
 109 | #I #G #L #K #V #i #_ #_ #W #T #H destruct
 110 | #a #I #G #L #V #T0 #_ #_ #W #T #H destruct
 111 | #a #G #L #V #W0 #W00 #T0 #U #l #_ #_ #_ #_ #_ #_ #W #T #H destruct
 112 | #G #L #W0 #T0 #U0 #l #HW0 #HT0 #Hl #HTU0 #HUW0 #W #T #H destruct /2 width=4 by ex5_2_intro/
 113 ]
 114 qed-.
 115
 116 lemma snv_inv_cast: ∀h,g,G,L,W,T. ⦃G, L⦄ ⊢ ⓝW.T ¡[h, g] →
 117                     ∃∃U,l. ⦃G, L⦄ ⊢ W ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
 118                            ⦃G, L⦄ ⊢ T ▪[h, g] l+1 & ⦃G, L⦄ ⊢ T •[h, g] U & ⦃G, L⦄ ⊢ U ⬌* W.
 119 /2 width=3 by snv_inv_cast_aux/ qed-.