matita/matita/contribs/lambdadelta/basic_2/dynamic/snv_aaa.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/da_aaa.ma".
  16 include "basic_2/unfold/lstas_lift.ma".
  17 include "basic_2/computation/csx_aaa.ma".
  18 include "basic_2/computation/scpds_aaa.ma".
  19 include "basic_2/dynamic/snv.ma".
  20
  21 (* STRATIFIED NATIVE VALIDITY FOR TERMS *************************************)
  22
  23 (* Forward lemmas on atomic arity assignment for terms **********************)
  24
  25 lemma snv_fwd_aaa: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ T ¡[h, g] → ∃A. ⦃G, L⦄ ⊢ T ⁝ A.
  26 #h #g #G #L #T #H elim H -G -L -T
  27 [ /2 width=2 by aaa_sort, ex_intro/
  28 | #I #G #L #K #V #i #HLK #_ * /3 width=6 by aaa_lref, ex_intro/
  29 | #a * #G #L #V #T #_ #_ * #B #HV * #A #HA /3 width=2 by aaa_abbr, aaa_abst, ex_intro/
  30 | #a #G #L #V #W0 #T #U0 #l #_ #_ #HVW0 #HTU0 * #B #HV * #X #HT
  31   lapply (scpds_aaa_conf … HV … HVW0) -HVW0 #HW0
  32   lapply (scpds_aaa_conf … HT … HTU0) -HTU0 #H
  33   elim (aaa_inv_abst … H) -H #B0 #A #H1 #HU #H2 destruct
  34   lapply (aaa_mono … H1 … HW0) -W0 #H destruct /3 width=4 by aaa_appl, ex_intro/
  35 | #G #L #U #T #U0 #_ #_ #HU0 #HTU0 * #B #HU * #A #HT
  36   lapply (cprs_aaa_conf … HU … HU0) -HU0 #HU0
  37   lapply (scpds_aaa_conf … HT … HTU0) -HTU0 #H
  38   lapply (aaa_mono … H … HU0) -U0 #H destruct /3 width=3 by aaa_cast, ex_intro/
  39 ]
  40 qed-.
  41
  42 lemma snv_fwd_csx: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ T ¡[h, g] → ⦃G, L⦄ ⊢ ⬊*[h, g] T.
  43 #h #g #G #L #T #H elim (snv_fwd_aaa … H) -H /2 width=2 by aaa_csx/
  44 qed-.
  45
  46 (* Advanced forward lemmas **************************************************)
  47
  48 lemma snv_fwd_da: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ T ¡[h, g] → ∃l. ⦃G, L⦄ ⊢ T ▪[h, g] l.
  49 #h #g #G #L #T #H elim (snv_fwd_aaa … H) -H /2 width=2 by aaa_da/
  50 qed-.
  51
  52 lemma snv_fwd_sta: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ T ¡[h, g] → ∃U. ⦃G, L⦄ ⊢ T •[h] U.
  53 #h #g #G #L #T #H elim (snv_fwd_aaa … H) -H /2 width=2 by aaa_sta/
  54 qed-.
  55
  56 lemma snv_lstas_fwd_correct: ∀h,g,G,L,T1,T2,l. ⦃G, L⦄ ⊢ T1 ¡[h, g] → ⦃G, L⦄ ⊢ T1 •* [h, l] T2 →
  57                              ∃U2. ⦃G, L⦄ ⊢ T2 •[h] U2.
  58 #h #g #G #L #T1 #T2 #l #HT1 #HT12
  59 elim (snv_fwd_sta … HT1) -HT1 /2 width=5 by lstas_fwd_correct/
  60 qed-.