matita/matita/contribs/lambdadelta/basic_2/dynamic/ygt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/dynamic/ysc.ma".
  16 include "basic_2/dynamic/yprs.ma".
  17
  18 (* "BIG TREE" PROPER PARALLEL COMPUTATION FOR CLOSURES **********************)
  19
  20 inductive ygt (h) (g) (L1) (T1): relation2 lenv term ≝
  21 | ygt_inj : ∀L,L2,T,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ ≻[g] ⦃L2, T2⦄ →
  22             ygt h g L1 T1 L2 T2
  23 | ygt_step: ∀L,L2,T. ygt h g L1 T1 L T → L ⊢ ➡ L2 → ygt h g L1 T1 L2 T
  24 .
  25
  26 interpretation "'big tree' proper parallel computation (closure)"
  27    'BTPRedStarProper h g L1 T1 L2 T2 = (ygt h g L1 T1 L2 T2).
  28
  29 (* Basic forvard lemmas *****************************************************)
  30
  31 lemma ygt_fwd_yprs: ∀h,g,L1,L2,T1,T2. h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄ →
  32                     h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  33 #h #g #L1 #L2 #T1 #T2 #H elim H -L2 -T2
  34 /3 width=4 by yprs_strap1, ysc_ypr, ypr_lpr/
  35 qed-.
  36
  37 (* Basic properties *********************************************************)
  38
  39 lemma ysc_ygt: ∀h,g,L1,L2,T1,T2. h ⊢ ⦃L1, T1⦄ ≻[g] ⦃L2, T2⦄ →
  40                h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄.
  41 /3 width=4/ qed.
  42
  43 lemma ygt_strap1: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ >[g] ⦃L, T⦄ →
  44                   h ⊢ ⦃L, T⦄ ≽[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄.
  45 #h #g #L1 #L #L2 #T1 #T #T2 #H1 #H2
  46 lapply (ygt_fwd_yprs … H1) #H0
  47 elim (ypr_inv_ysc … H2) -H2 [| * #HL2 #H destruct ] /2 width=4/
  48 qed-.
  49
  50 lemma ygt_strap2: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L, T⦄ →
  51                   h ⊢ ⦃L, T⦄ >[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄.
  52 #h #g #L1 #L #L2 #T1 #T #T2 #H1 #H2 elim H2 -L2 -T2
  53 [ /3 width=4 by ygt_inj, yprs_strap2/ | /2 width=3/ ]
  54 qed-.
  55
  56 lemma ygt_yprs_trans: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ >[g] ⦃L, T⦄ →
  57                       h ⊢ ⦃L, T⦄ ≥[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄.
  58 #h #g #L1 #L #L2 #T1 #T #T2 #HT1 #HT2 @(yprs_ind … HT2) -L2 -T2 //
  59 /2 width=4 by ygt_strap1/
  60 qed-.
  61
  62 lemma yprs_ygt_trans: ∀h,g,L1,L,T1,T. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L, T⦄ →
  63                       ∀L2,T2. h ⊢ ⦃L, T⦄ >[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄.
  64 #h #g #L1 #L #T1 #T #HT1 @(yprs_ind … HT1) -L -T //
  65 /3 width=4 by ygt_strap2/
  66 qed-.
  67
  68 lemma fsupp_ygt: ∀h,g,L1,L2,T1,T2. ⦃L1, T1⦄ ⊃+ ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄.
  69 #h #g #L1 #L2 #T1 #T2 #H @(fsupp_ind … L2 T2 H) -L2 -T2 /3 width=1/ /3 width=4/
  70 qed.
  71
  72 lemma cprs_ygt: ∀h,g,L,T1,T2. L ⊢ T1 ➡* T2 → (T1 = T2 → ⊥) →
  73                 h ⊢ ⦃L, T1⦄ >[g] ⦃L, T2⦄.
  74 #h #g #L #T1 #T2 #H @(cprs_ind … H) -T2
  75 [ #H elim H //
  76 | #T #T2 #_ #HT2 #IHT1 #HT12
  77   elim (term_eq_dec T1 T) #H destruct
  78   [ -IHT1 /4 width=1/
  79   | lapply (IHT1 … H) -IHT1 -H -HT12 #HT1
  80     @(ygt_strap1 … HT1) -HT1 /2 width=1/
  81   ]
  82 ]
  83 qed.
  84
  85 lemma sstas_ygt: ∀h,g,L,T1,T2. ⦃h, L⦄ ⊢ T1 •*[g] T2 → (T1 = T2 → ⊥) →
  86                  h ⊢ ⦃L, T1⦄ >[g] ⦃L, T2⦄.
  87 #h #g #L #T1 #T2 #H @(sstas_ind … H) -T2
  88 [ #H elim H //
  89 | #T #T2 #l #_ #HT2 #IHT1 #HT12 -HT12
  90   elim (term_eq_dec T1 T) #H destruct
  91   [ -IHT1 /3 width=2/
  92   | lapply (IHT1 … H) -IHT1 -H #HT1
  93     @(ygt_strap1 … HT1) -HT1 /2 width=2/
  94   ]
  95 ]
  96 qed.
  97
  98 lemma lsubsv_ygt: ∀h,g,L1,L2,T. h ⊢ L2 ¡⊑[g] L1 → (L1 = L2 → ⊥) →
  99                   h ⊢ ⦃L1, T⦄ >[g] ⦃L2, T⦄.
 100 /4 width=1/ qed.