matita/matita/contribs/lambdadelta/basic_2/dynamic/ygt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/btpredstarproper_8.ma".
  16 include "basic_2/dynamic/ysc.ma".
  17 include "basic_2/dynamic/yprs.ma".
  18
  19 (* "BIG TREE" PROPER PARALLEL COMPUTATION FOR CLOSURES **********************)
  20
  21 inductive ygt (h) (g) (G1) (L1) (T1): relation3 genv lenv term ≝
  22 | ygt_inj : ∀G,G2,L,L2,T,T2. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G, L, T⦄ → ⦃G, L, T⦄ ≻[h, g] ⦃G2, L2, T2⦄ →
  23             ygt h g G1 L1 T1 G2 L2 T2
  24 | ygt_step: ∀G,L,L2,T. ygt h g G1 L1 T1 G L T → ⦃G, L⦄ ⊢ ➡ L2 → ygt h g G1 L1 T1 G L2 T
  25 .
  26
  27 interpretation "'big tree' proper parallel computation (closure)"
  28    'BTPRedStarProper h g G1 L1 T1 G2 L2 T2 = (ygt h g G1 L1 T1 G2 L2 T2).
  29
  30 (* Basic forvard lemmas *****************************************************)
  31
  32 lemma ygt_fwd_yprs: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄ →
  33                     ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄.
  34 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G2 -L2 -T2
  35 /3 width=5 by yprs_strap1, ysc_ypr, ypr_lpr/
  36 qed-.
  37
  38 (* Basic properties *********************************************************)
  39
  40 lemma ysc_ygt: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻[h, g] ⦃G2, L2, T2⦄ →
  41                ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  42 /3 width=5/ qed.
  43
  44 lemma ygt_strap1: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G, L, T⦄ →
  45                   ⦃G, L, T⦄ ≽[h, g] ⦃G2, L2, T2⦄ →  ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  46 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2
  47 lapply (ygt_fwd_yprs … H1) #H0
  48 elim (ypr_inv_ysc … H2) -H2 [| * #HG2 #HL2 #HT2 destruct ] /2 width=5/
  49 qed-.
  50
  51 lemma ygt_strap2: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ≽[h, g] ⦃G, L, T⦄ →
  52                   ⦃G, L, T⦄ >[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  53 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2 elim H2 -G2 -L2 -T2
  54 [ /3 width=5 by ygt_inj, yprs_strap2/ | /2 width=3/ ]
  55 qed-.
  56
  57 lemma ygt_yprs_trans: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G, L, T⦄ →
  58                       ⦃G, L, T⦄ ≥[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  59 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #HT1 #HT2 @(yprs_ind … HT2) -G2 -L2 -T2 //
  60 /2 width=5 by ygt_strap1/
  61 qed-.
  62
  63 lemma yprs_ygt_trans: ∀h,g,G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G, L, T⦄ →
  64                       ∀G2,L2,T2. ⦃G, L, T⦄ >[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  65 #h #g #G1 #G #L1 #L #T1 #T #HT1 @(yprs_ind … HT1) -G -L -T //
  66 /3 width=5 by ygt_strap2/
  67 qed-.
  68
  69 lemma fsupp_ygt: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  70 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fsupp_ind … L2 T2 H) -G2 -L2 -T2 /3 width=1/ /3 width=5/
  71 qed.
  72
  73 lemma cprs_ygt: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡* T2 → (T1 = T2 → ⊥) →
  74                 ⦃G, L, T1⦄ >[h, g] ⦃G, L, T2⦄.
  75 #h #g #G #L #T1 #T2 #H @(cprs_ind … H) -T2
  76 [ #H elim H //
  77 | #T #T2 #_ #HT2 #IHT1 #HT12
  78   elim (term_eq_dec T1 T) #H destruct
  79   [ -IHT1 /4 width=1/
  80   | lapply (IHT1 … H) -IHT1 -H -HT12 #HT1
  81     @(ygt_strap1 … HT1) -HT1 /2 width=1/
  82   ]
  83 ]
  84 qed.
  85
  86 lemma lsubsv_ygt: ∀h,g,G,L1,L2,T. G ⊢ L2 ¡⊑[h, g] L1 → (L1 = L2 → ⊥) →
  87                   ⦃G, L1, T⦄ >[h, g] ⦃G, L2, T⦄.
  88 /4 width=1/ qed.