matita/matita/contribs/lambdadelta/basic_2/dynamic/yprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/btpredstar_6.ma".
  16 include "basic_2/substitution/fsupp.ma".
  17 include "basic_2/computation/lprs.ma".
  18 include "basic_2/dynamic/ypr.ma".
  19
  20 (* "BIG TREE" PARALLEL COMPUTATION FOR CLOSURES *****************************)
  21
  22 definition yprs: ∀h. sd h → bi_relation lenv term ≝
  23                  λh,g. bi_TC … (ypr h g).
  24
  25 interpretation "'big tree' parallel computation (closure)"
  26    'BTPRedStar h g L1 T1 L2 T2 = (yprs h g L1 T1 L2 T2).
  27
  28 (* Basic eliminators ********************************************************)
  29
  30 lemma yprs_ind: ∀h,g,L1,T1. ∀R:relation2 lenv term. R L1 T1 →
  31                 (∀L,L2,T,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ ≽[g] ⦃L2, T2⦄ → R L T → R L2 T2) →
  32                 ∀L2,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄ → R L2 T2.
  33 /3 width=7 by bi_TC_star_ind/ qed-.
  34
  35 lemma yprs_ind_dx: ∀h,g,L2,T2. ∀R:relation2 lenv term. R L2 T2 →
  36                    (∀L1,L,T1,T. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ ≥[g] ⦃L2, T2⦄ → R L T → R L1 T1) →
  37                    ∀L1,T1. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄ → R L1 T1.
  38 /3 width=7 by bi_TC_star_ind_dx/ qed-.
  39
  40 (* Basic properties *********************************************************)
  41
  42 lemma yprs_refl: ∀h,g. bi_reflexive … (yprs h g).
  43 /2 width=1/ qed.
  44
  45 lemma ypr_yprs: ∀h,g,L1,L2,T1,T2. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L2, T2⦄ →
  46                 h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  47 /2 width=1/ qed.
  48
  49 lemma yprs_strap1: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L, T⦄ →
  50                    h ⊢ ⦃L, T⦄ ≽[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  51 /2 width=4/ qed-.
  52
  53 lemma yprs_strap2: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L, T⦄ →
  54                    h ⊢ ⦃L, T⦄ ≥[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  55 /2 width=4/ qed-.
  56
  57 (* Note: this is a general property of bi_TC *)
  58 lemma fsupp_yprs: ∀h,g,L1,L2,T1,T2. ⦃L1, T1⦄ ⊃+ ⦃L2, T2⦄ →
  59                   h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  60 #h #g #L1 #L2 #T1 #T2 #H @(fsupp_ind … L2 T2 H) -L2 -T2 /3 width=1/ /3 width=4/
  61 qed.
  62
  63 lemma cprs_yprs: ∀h,g,L,T1,T2. L ⊢ T1 ➡* T2 → h ⊢ ⦃L, T1⦄ ≥[g] ⦃L, T2⦄.
  64 #h #g #L #T1 #T2 #H @(cprs_ind … H) -T2 // /3 width=4 by ypr_cpr, yprs_strap1/
  65 qed.
  66
  67 lemma lprs_yprs: ∀h,g,L1,L2,T. L1 ⊢ ➡* L2 → h ⊢ ⦃L1, T⦄ ≥[g] ⦃L2, T⦄.
  68 #h #g #L1 #L2 #T #H @(lprs_ind … H) -L2 // /3 width=4 by ypr_lpr, yprs_strap1/
  69 qed.
  70
  71 lemma sstas_yprs: ∀h,g,L,T1,T2. ⦃h, L⦄ ⊢ T1 •*[g] T2 →
  72                   h ⊢ ⦃L, T1⦄ ≥[g] ⦃L, T2⦄.
  73 #h #g #L #T1 #T2 #H @(sstas_ind … H) -T2 // /3 width=4 by ypr_ssta, yprs_strap1/
  74 qed.
  75
  76 lemma lsubsv_yprs: ∀h,g,L1,L2,T. h ⊢ L2 ¡⊑[g] L1 → h ⊢ ⦃L1, T⦄ ≥[g] ⦃L2, T⦄.
  77 /3 width=1/ qed.
  78
  79 lemma cprs_lpr_yprs: ∀h,g,L1,L2,T1,T2. L1 ⊢ T1 ➡* T2 → L1 ⊢ ➡ L2 →
  80                      h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  81 /3 width=4 by yprs_strap1, ypr_lpr, cprs_yprs/
  82 qed.