matita/matita/contribs/lambdadelta/basic_2/equivalence/cpcs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/conversion/cpc.ma".
  16
  17 (* CONTEXT-SENSITIVE PARALLEL EQUIVALENCE ON TERMS **************************)
  18
  19 definition cpcs: lenv → relation term ≝
  20                  λL. TC … (cpc L).
  21
  22 interpretation "context-sensitive parallel equivalence (term)"
  23    'PConvStar L T1 T2 = (cpcs L T1 T2).
  24
  25 (* Basic eliminators ********************************************************)
  26
  27 lemma cpcs_ind: ∀L,T1. ∀R:predicate term. R T1 →
  28                 (∀T,T2. L ⊢ T1 ⬌* T → L ⊢ T ⬌ T2 → R T → R T2) →
  29                 ∀T2. L ⊢ T1 ⬌* T2 → R T2.
  30 #L #T1 #R #HT1 #IHT1 #T2 #HT12 @(TC_star_ind … HT1 IHT1 … HT12) //
  31 qed-.
  32
  33 lemma cpcs_ind_dx: ∀L,T2. ∀R:predicate term. R T2 →
  34                    (∀T1,T. L ⊢ T1 ⬌ T → L ⊢ T ⬌* T2 → R T → R T1) →
  35                    ∀T1. L ⊢ T1 ⬌* T2 → R T1.
  36 #L #T2 #R #HT2 #IHT2 #T1 #HT12
  37 @(TC_star_ind_dx … HT2 IHT2 … HT12) //
  38 qed-.
  39
  40 (* Basic properties *********************************************************)
  41
  42 (* Basic_1: was: pc3_refl *)
  43 lemma cpcs_refl: ∀L. reflexive … (cpcs L).
  44 /2 width=1/ qed.
  45
  46 (* Basic_1: was: pc3_s *)
  47 lemma cpcs_sym: ∀L. symmetric … (cpcs L).
  48 /3 width=1/ qed.
  49
  50 lemma cpc_cpcs: ∀L,T1,T2. L ⊢ T1 ⬌ T2 → L ⊢ T2 ⬌* T2.
  51 /2 width=1/ qed.
  52
  53 lemma cpcs_strap1: ∀L,T1,T,T2. L ⊢ T1 ⬌* T → L ⊢ T ⬌ T2 → L ⊢ T1 ⬌* T2.
  54 /2 width=3/ qed.
  55
  56 lemma cpcs_strap2: ∀L,T1,T,T2. L ⊢ T1 ⬌ T → L ⊢ T ⬌* T2 → L ⊢ T1 ⬌* T2.
  57 /2 width=3/ qed.
  58
  59 (* Basic_1: was: pc3_pr2_r *)
  60 lemma cpcs_cpr_dx: ∀L,T1,T2. L ⊢ T1 ➡ T2 → L ⊢ T1 ⬌* T2.
  61 /3 width=1/ qed.
  62
  63 lemma cpcs_tpr_dx: ∀L,T1,T2. T1 ➡ T2 → L ⊢ T1 ⬌* T2.
  64 /3 width=1/ qed.
  65
  66 (* Basic_1: was: pc3_pr2_x *)
  67 lemma cpcs_cpr_sn: ∀L,T1,T2. L ⊢ T2 ➡ T1 → L ⊢ T1 ⬌* T2.
  68 /3 width=1/ qed.
  69
  70 lemma cpcs_tpr_sn: ∀L,T1,T2. T2 ➡ T1 → L ⊢ T1 ⬌* T2.
  71 /3 width=1/ qed.
  72
  73 lemma cpcs_cpr_strap1: ∀L,T1,T. L ⊢ T1 ⬌* T → ∀T2. L ⊢ T ➡ T2 → L ⊢ T1 ⬌* T2.
  74 /3 width=3/ qed.
  75
  76 (* Basic_1: was: pc3_pr2_u *)
  77 lemma cpcs_cpr_strap2: ∀L,T1,T. L ⊢ T1 ➡ T → ∀T2. L ⊢ T ⬌* T2 → L ⊢ T1 ⬌* T2.
  78 /3 width=3/ qed.
  79
  80 lemma cpcs_cpr_div: ∀L,T1,T. L ⊢ T1 ⬌* T → ∀T2. L ⊢ T2 ➡ T → L ⊢ T1 ⬌* T2.
  81 /3 width=3/ qed.
  82
  83 lemma cpr_div: ∀L,T1,T. L ⊢ T1 ➡ T → ∀T2. L ⊢ T2 ➡ T → L ⊢ T1 ⬌* T2.
  84 /3 width=3/ qed-.
  85
  86 (* Basic_1: was: pc3_pr2_u2 *)
  87 lemma cpcs_cpr_conf: ∀L,T1,T. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ⬌* T2 → L ⊢ T1 ⬌* T2.
  88 /3 width=3/ qed.
  89
  90 lemma cpcs_tpss_strap1: ∀L,T1,T. L ⊢ T1 ⬌* T →
  91                         ∀T2,d,e. L ⊢ T ▶* [d, e] T2 → L ⊢ T1 ⬌* T2.
  92 #L #T1 #T #HT1 #T2 #d #e #HT2
  93 @(cpcs_cpr_strap1 … HT1) -T1 /2 width=3/
  94 qed-.
  95
  96 lemma cpcs_tpss_conf: ∀L,T,T1,d,e. L ⊢ T ▶* [d, e] T1 →
  97                       ∀T2. L ⊢ T ⬌* T2 → L ⊢ T1 ⬌* T2.
  98 #L #T #T1 #d #e #HT1 #T2 #HT2
  99 @(cpcs_cpr_conf … HT2) -T2 /2 width=3/
 100 qed-.
 101
 102 (* Basic_1: removed theorems 9:
 103             clear_pc3_trans pc3_ind_left
 104             pc3_head_1 pc3_head_2 pc3_head_12 pc3_head_21
 105             pc3_pr2_fsubst0 pc3_pr2_fsubst0_back pc3_fsubst0
 106 *)
 107 (* Basic_1: removed local theorems 6:
 108             pc3_left_pr3 pc3_left_trans pc3_left_sym pc3_left_pc3 pc3_pc3_left
 109             pc3_wcpr0_t_aux
 110 *)