matita/matita/contribs/lambdadelta/basic_2/equivalence/cpcs_ltpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/reducibility/cpr_ltpr.ma".
  16 include "basic_2/equivalence/cpcs_cpcs.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL EQUIVALENCE ON TERMS **************************)
  19
  20 (* Properties about context-free parallel reduction on local environments ***)
  21
  22 (* Basic_1: was only: pc3_pr0_pr2_t *)
  23 (* Basic_1: note: pc3_pr0_pr2_t should be renamed *)
  24 lemma ltpr_cpr_conf: ∀L1,L2. L1 ➡ L2 → ∀T1,T2. L1 ⊢ T1 ➡ T2 → L2 ⊢ T1 ⬌* T2.
  25 #L1 #L2 #HL12 #T1 #T2 #HT12
  26 elim (cpr_ltpr_conf_eq … HT12 … HL12) -L1 #T #HT1 #HT2
  27 @(cprs_div … T) /2 width=1/ /3 width=1/ (**) (* /4 width=3/ is too long *)
  28 qed.
  29
  30 (* Basic_1: was: pc3_wcpr0_t *)
  31 (* Basic_1: note: pc3_wcpr0_t should be renamed *)
  32 lemma ltpr_cprs_conf: ∀L1,L2. L1 ➡ L2 → ∀T1,T2. L1 ⊢ T1 ➡* T2 → L2 ⊢ T1 ⬌* T2.
  33 #L1 #L2 #HL12 #T1 #T2 #H @(cprs_ind … H) -T2 //
  34 #T #T2 #_ #HT2 #IHT1
  35 @(cpcs_trans … IHT1) -T1 /2 width=3/
  36 qed.
  37
  38 (* Basic_1: was: pc3_wcpr0 *)
  39 lemma ltpr_cpcs_conf: ∀L1,L2. L1 ➡ L2 → ∀T1,T2. L1 ⊢ T1 ⬌* T2 → L2 ⊢ T1 ⬌* T2.
  40 #L1 #L2 #HL12 #T1 #T2 #H
  41 elim (cpcs_inv_cprs … H) -H #T #HT1 #HT2
  42 @(cpcs_canc_dx … T) /2 width=3/
  43 qed.