matita/matita/contribs/lambdadelta/basic_2/etc/cnv/cnv_preserve.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/fsb_aaa.ma".
  16 include "basic_2/dynamic/snv_da_lpr.ma".
  17 include "basic_2/dynamic/snv_lstas.ma".
  18 include "basic_2/dynamic/snv_lstas_lpr.ma".
  19 include "basic_2/dynamic/snv_lpr.ma".
  20
  21 (* STRATIFIED NATIVE VALIDITY FOR TERMS *************************************)
  22
  23 (* Main preservation properties *********************************************)
  24
  25 theorem da_cpr_lpr: ∀h,o,G,L,T. IH_da_cpr_lpr h o G L T.
  26 #h #o #G #L #T #HT elim (snv_preserve … HT) /2 width=1 by/
  27 qed-.
  28
  29 theorem snv_lstas: ∀h,o,G,L,T. IH_snv_lstas h o G L T.
  30 #h #o #G #L #T #HT elim (snv_preserve … HT) /2 width=5 by/
  31 qed-.
  32
  33 theorem lstas_cpr_lpr: ∀h,o,G,L,T. IH_lstas_cpr_lpr h o G L T.
  34 #h #o #G #L #T #HT elim (snv_preserve … HT) /2 width=3 by/
  35 qed-.
  36
  37 (* Advanced preservation properties *****************************************)
  38
  39 lemma da_cprs_lpr: ∀h,o,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, o] →
  40                    ∀d. ⦃G, L1⦄ ⊢ T1 ▪[h, o] d →
  41                    ∀T2. ⦃G, L1⦄ ⊢ T1 ➡* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 → ⦃G, L2⦄ ⊢ T2 ▪[h, o] d.
  42 #h #o #G #L1 #T1 #HT1 #d #Hd #T2 #H
  43 @(cprs_ind … H) -T2 /3 width=6 by snv_cprs_lpr, da_cpr_lpr/
  44 qed-.
  45
  46 lemma lstas_cprs_lpr: ∀h,o,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, o] →
  47                       ∀d1,d2. d2 ≤ d1 → ⦃G, L1⦄ ⊢ T1 ▪[h, o] d1 →
  48                       ∀U1. ⦃G, L1⦄ ⊢ T1 •*[h, d2] U1 →
  49                       ∀T2. ⦃G, L1⦄ ⊢ T1 ➡* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 →
  50                       ∃∃U2. ⦃G, L2⦄ ⊢ T2 •*[h, d2] U2 & ⦃G, L2⦄ ⊢ U1 ⬌* U2.
  51 #h #o #G #L1 #T1 #HT1 #d1 #d2 #Hd21 #Hd1 #U1 #HTU1 #T2 #H
  52 @(cprs_ind … H) -T2 [ /2 width=10 by lstas_cpr_lpr/ ]
  53 #T #T2 #HT1T #HTT2 #IHT1 #L2 #HL12
  54 elim (IHT1 L1) // -IHT1 #U #HTU #HU1
  55 elim (lstas_cpr_lpr … o … Hd21 … HTU … HTT2 … HL12) -HTU -HTT2
  56 [2,3: /2 width=7 by snv_cprs_lpr, da_cprs_lpr/ ] -T1 -T -d1
  57 /4 width=5 by lpr_cpcs_conf, cpcs_trans, ex2_intro/
  58 qed-.
  59
  60 lemma lstas_cpcs_lpr: ∀h,o,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, o] →
  61                       ∀d,d1. d ≤ d1 → ⦃G, L1⦄ ⊢ T1 ▪[h, o] d1 → ∀U1. ⦃G, L1⦄ ⊢ T1 •*[h, d] U1 →
  62                       ∀T2. ⦃G, L1⦄ ⊢ T2 ¡[h, o] →
  63                       ∀d2. d ≤ d2 → ⦃G, L1⦄ ⊢ T2 ▪[h, o] d2 → ∀U2. ⦃G, L1⦄ ⊢ T2 •*[h, d] U2 →
  64                       ⦃G, L1⦄ ⊢ T1 ⬌* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 → ⦃G, L2⦄ ⊢ U1 ⬌* U2.
  65 #h #o #G #L1 #T1 #HT1 #d #d1 #Hd1 #HTd1 #U1 #HTU1 #T2 #HT2 #d2 #Hd2 #HTd2 #U2 #HTU2 #H #L2 #HL12
  66 elim (cpcs_inv_cprs … H) -H #T #H1 #H2
  67 elim (lstas_cprs_lpr … HT1 … Hd1 HTd1 … HTU1 … H1 … HL12) -T1 #W1 #H1 #HUW1
  68 elim (lstas_cprs_lpr … HT2 … Hd2 HTd2 … HTU2 … H2 … HL12) -T2 #W2 #H2 #HUW2
  69 lapply (lstas_mono … H1 … H2) -h -T -d #H destruct /2 width=3 by cpcs_canc_dx/
  70 qed-.