matita/matita/contribs/lambdadelta/basic_2/etc/cpy/cpy_lift.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/drop_drop.ma".
  16 include "basic_2/substitution/cpy.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED ORDINARY SUBSTITUTION FOR TERMS ***************)
  19
  20 (* Properties on relocation *************************************************)
  21
  22 (* Basic_1: was: subst1_lift_lt *)
  23 lemma cpy_lift_le: ∀G,K,T1,T2,lt,mt. ⦃G, K⦄ ⊢ T1 ▶[lt, mt] T2 →
  24                    ∀L,U1,U2,s,l,m. ⬇[s, l, m] L ≡ K →
  25                    ⬆[l, m] T1 ≡ U1 → ⬆[l, m] T2 ≡ U2 →
  26                    lt + mt ≤ l → ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2.
  27 #G #K #T1 #T2 #lt #mt #H elim H -G -K -T1 -T2 -lt -mt
  28 [ #I #G #K #lt #mt #L #U1 #U2 #s #l #m #_ #H1 #H2 #_
  29   >(lift_mono … H1 … H2) -H1 -H2 //
  30 | #I #G #K #KV #V #W #i #lt #mt #Hlti #Hilmt #HKV #HVW #L #U1 #U2 #s #l #m #HLK #H #HWU2 #Hlmtl
  31   lapply (ylt_yle_trans … Hlmtl … Hilmt) -Hlmtl #Hil
  32   lapply (lift_inv_lref1_lt … H … Hil) -H #H destruct
  33   elim (lift_trans_ge … HVW … HWU2) -W /2 width=1 by ylt_fwd_le_succ1/
  34   <yplus_inj >yplus_SO2 >yminus_succ2 #W #HVW #HWU2
  35   elim (drop_trans_le … HLK … HKV) -K /2 width=2 by ylt_fwd_le/ #X #HLK #H
  36   elim (drop_inv_skip2 … H) -H /2 width=1 by ylt_to_minus/ -Hil #K #Y #_ #HVY
  37   >(lift_mono … HVY … HVW) -Y -HVW #H destruct /2 width=5 by cpy_subst/
  38 | #a #I #G #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hlmtl
  39   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  40   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  41   /4 width=7 by cpy_bind, drop_skip, yle_succ/
  42 | #G #I #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hlmtl
  43   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  44   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  45   /3 width=7 by cpy_flat/
  46 ]
  47 qed-.
  48
  49 lemma cpy_lift_be: ∀G,K,T1,T2,lt,mt. ⦃G, K⦄ ⊢ T1 ▶[lt, mt] T2 →
  50                    ∀L,U1,U2,s,l,m. ⬇[s, l, m] L ≡ K →
  51                    ⬆[l, m] T1 ≡ U1 → ⬆[l, m] T2 ≡ U2 →
  52                    lt ≤ l → l ≤ lt + mt → ⦃G, L⦄ ⊢ U1 ▶[lt, mt + m] U2.
  53 #G #K #T1 #T2 #lt #mt #H elim H -G -K -T1 -T2 -lt -mt
  54 [ #I #G #K #lt #mt #L #U1 #U2 #s #l #m #_ #H1 #H2 #_ #_
  55   >(lift_mono … H1 … H2) -H1 -H2 //
  56 | #I #G #K #KV #V #W #i #lt #mt #Hlti #Hilmt #HKV #HVW #L #U1 #U2 #s #l #m #HLK #H #HWU2 #Hltl #_
  57   elim (lift_inv_lref1 … H) -H * #Hil #H destruct
  58   [ -Hltl
  59     lapply (ylt_yle_trans … (lt+mt+m) … Hilmt) // -Hilmt #Hilmtm
  60     elim (lift_trans_ge … HVW … HWU2) -W <yplus_inj >yplus_SO2
  61     [2: >yplus_O1 /2 width=1 by ylt_fwd_le_succ1/ ] >yminus_succ2 #W #HVW #HWU2
  62     elim (drop_trans_le … HLK … HKV) -K /2 width=1 by ylt_fwd_le/ #X #HLK #H
  63     elim (drop_inv_skip2 … H) -H /2 width=1 by ylt_to_minus/ -Hil #K #Y #_ #HVY
  64     >(lift_mono … HVY … HVW) -V #H destruct /2 width=5 by cpy_subst/
  65   | -Hlti
  66     lapply (yle_trans … Hltl … Hil) -Hltl #Hlti
  67     lapply (lift_trans_be … HVW … HWU2 ? ?) -W /2 width=1 by yle_succ_dx/ >plus_plus_comm_23 #HVU2
  68     lapply (drop_trans_ge_comm … HLK … HKV ?) -K // -Hil
  69     /3 width=5 by cpy_subst, drop_inv_gen, monotonic_ylt_plus_dx, yle_plus_dx1_trans/
  70   ]
  71 | #a #I #G #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hltl #Hllmt
  72   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  73   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  74   /4 width=7 by cpy_bind, drop_skip, yle_succ/
  75 | #I #G #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hlmtl
  76   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  77   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  78   /3 width=7 by cpy_flat/
  79 ]
  80 qed-.
  81
  82 (* Basic_1: was: subst1_lift_ge *)
  83 lemma cpy_lift_ge: ∀G,K,T1,T2,lt,mt. ⦃G, K⦄ ⊢ T1 ▶[lt, mt] T2 →
  84                    ∀L,U1,U2,s,l,m. ⬇[s, l, m] L ≡ K →
  85                    ⬆[l, m] T1 ≡ U1 → ⬆[l, m] T2 ≡ U2 →
  86                    l ≤ lt → ⦃G, L⦄ ⊢ U1 ▶[lt+m, mt] U2.
  87 #G #K #T1 #T2 #lt #mt #H elim H -G -K -T1 -T2 -lt -mt
  88 [ #I #G #K #lt #mt #L #U1 #U2 #s #l #m #_ #H1 #H2 #_
  89   >(lift_mono … H1 … H2) -H1 -H2 //
  90 | #I #G #K #KV #V #W #i #lt #mt #Hlti #Hilmt #HKV #HVW #L #U1 #U2 #s #l #m #HLK #H #HWU2 #Hllt
  91   lapply (yle_trans … Hllt … Hlti) -Hllt #Hil
  92   lapply (lift_inv_lref1_ge … H … Hil) -H #H destruct
  93   lapply (lift_trans_be … HVW … HWU2 ? ?) -W /2 width=1 by yle_succ_dx/ >plus_plus_comm_23 #HVU2
  94   lapply (drop_trans_ge_comm … HLK … HKV ?) -K // -Hil
  95   /3 width=5 by cpy_subst, drop_inv_gen, monotonic_ylt_plus_dx, monotonic_yle_plus_dx/
  96 | #a #I #G #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hllt
  97   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  98   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  99   /4 width=6 by cpy_bind, drop_skip, yle_succ/
 100 | #I #G #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hllt
 101   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
 102   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
 103   /3 width=6 by cpy_flat/
 104 ]
 105 qed-.
 106
 107 (* Inversion lemmas on relocation *******************************************)
 108
 109 (* Basic_1: was: subst1_gen_lift_lt *)
 110 lemma cpy_inv_lift1_le: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 111                         ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 112                         lt + mt ≤ l →
 113                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[lt, mt] T2 & ⬆[l, m] T2 ≡ U2.
 114 #G #L #U1 #U2 #lt #mt #H elim H -G -L -U1 -U2 -lt -mt
 115 [ * #i #G #L #lt #mt #K #s #l #m #_ #T1 #H #_
 116   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 117   | elim (lift_inv_lref2 … H) -H * #Hil #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 118   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 119   ]
 120 | #I #G #L #KV #V #W #i #lt #mt #Hlti #Hilmt #HLKV #HVW #K #s #l #m #HLK #T1 #H #Hlmtl
 121   lapply (ylt_yle_trans … Hlmtl … Hilmt) -Hlmtl #Hil
 122   lapply (lift_inv_lref2_lt … H … Hil) -H #H destruct
 123   elim (drop_conf_lt … HLK … HLKV) -L // #L #U #HKL #_ #HUV
 124   elim (lift_trans_le … HUV … HVW) -V // >minus_plus <plus_minus_m_m //
 125   <yminus_succ2 <yplus_inj >yplus_SO2 >ymax_pre_sn /2 width=1 by ylt_fwd_le_succ1/ -Hil
 126   /3 width=5 by cpy_subst, ex2_intro/
 127 | #a #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hlmtl
 128   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 129   elim (IHW12 … HLK … HVW1) -IHW12 // #V2 #HV12 #HVW2
 130   elim (IHU12 … HTU1) -IHU12 -HTU1
 131   /3 width=6 by cpy_bind, yle_succ, drop_skip, lift_bind, ex2_intro/
 132 | #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hlmtl
 133   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 134   elim (IHW12 … HLK … HVW1) -W1 //
 135   elim (IHU12 … HLK … HTU1) -U1 -HLK
 136   /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 137 ]
 138 qed-.
 139
 140 lemma cpy_inv_lift1_be: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 141                         ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 142                         lt ≤ l → l + m ≤ lt + mt →
 143                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[lt, mt-m] T2 & ⬆[l, m] T2 ≡ U2.
 144 #G #L #U1 #U2 #lt #mt #H elim H -G -L -U1 -U2 -lt -mt
 145 [ * #i #G #L #lt #mt #K #s #l #m #_ #T1 #H #_ #_
 146   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 147   | elim (lift_inv_lref2 … H) -H * #Hil #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 148   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 149   ]
 150 | #I #G #L #KV #V #W #i #x #mt #Hlti #Hilmt #HLKV #HVW #K #s #l #m #HLK #T1 #H #Hltl #Hlmlmt
 151   elim (yle_inv_inj2 … Hlti) -Hlti #lt #Hlti #H destruct
 152   lapply (yle_fwd_plus_yge … Hltl Hlmlmt) #Hmmt
 153   elim (lift_inv_lref2 … H) -H * #Hil #H destruct [ -Hltl -Hilmt | -Hlti -Hlmlmt ]
 154   [ lapply (ylt_yle_trans i l (lt+(mt-m)) ? ?) //
 155     [ >yplus_minus_assoc_inj /2 width=1 by yle_plus1_to_minus_inj2/ ] -Hlmlmt #Hilmtm
 156     elim (drop_conf_lt … HLK … HLKV) -L // #L #U #HKL #_ #HUV
 157     elim (lift_trans_le … HUV … HVW) -V //
 158     <yminus_succ2 <yplus_inj >yplus_SO2 >ymax_pre_sn /2 width=1 by ylt_fwd_le_succ1/ -Hil
 159     /4 width=5 by cpy_subst, ex2_intro, yle_inj/
 160   | elim (yle_inv_plus_inj2 … Hil) #Hlim #Hmi
 161     lapply (yle_inv_inj … Hmi) -Hmi #Hmi
 162     lapply (yle_trans … Hltl (i-m) ?) // -Hltl #Hltim
 163     lapply (drop_conf_ge … HLK … HLKV ?) -L // #HKV
 164     elim (lift_split … HVW l (i-m+1)) -HVW [2,3,4: /2 width=1 by yle_succ_dx, le_S_S/ ] -Hil -Hlim
 165     #V1 #HV1 >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O #H
 166     @(ex2_intro … H) @(cpy_subst … HKV HV1) // (**) (* explicit constructor *)
 167     >yplus_minus_assoc_inj /3 width=1 by monotonic_ylt_minus_dx, yle_inj/
 168   ]
 169 | #a #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hltl #Hlmlmt
 170   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 171   elim (IHW12 … HLK … HVW1) -IHW12 // #V2 #HV12 #HVW2
 172   elim (IHU12 … HTU1) -U1
 173   /3 width=6 by cpy_bind, drop_skip, lift_bind, yle_succ, ex2_intro/
 174 | #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hltl #Hlmlmt
 175   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 176   elim (IHW12 … HLK … HVW1) -W1 //
 177   elim (IHU12 … HLK … HTU1) -U1 -HLK //
 178   /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 179 ]
 180 qed-.
 181
 182 (* Basic_1: was: subst1_gen_lift_ge *)
 183 lemma cpy_inv_lift1_ge: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 184                         ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 185                         l + m ≤ lt →
 186                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[lt-m, mt] T2 & ⬆[l, m] T2 ≡ U2.
 187 #G #L #U1 #U2 #lt #mt #H elim H -G -L -U1 -U2 -lt -mt
 188 [ * #i #G #L #lt #mt #K #s #l #m #_ #T1 #H #_
 189   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 190   | elim (lift_inv_lref2 … H) -H * #Hil #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 191   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 192   ]
 193 | #I #G #L #KV #V #W #i #lt #mt #Hlti #Hilmt #HLKV #HVW #K #s #l #m #HLK #T1 #H #Hlmlt
 194   lapply (yle_trans … Hlmlt … Hlti) #Hlmi
 195   elim (yle_inv_plus_inj2 … Hlmlt) -Hlmlt #_ #Hmlt
 196   elim (yle_inv_plus_inj2 … Hlmi) #Hlim #Hmi
 197   lapply (yle_inv_inj … Hmi) -Hmi #Hmi
 198   lapply (lift_inv_lref2_ge  … H ?) -H // #H destruct
 199   lapply (drop_conf_ge … HLK … HLKV ?) -L // #HKV
 200   elim (lift_split … HVW l (i-m+1)) -HVW [2,3,4: /3 width=1 by yle_succ, yle_pred_sn, le_S_S/ ] -Hlmi -Hlim
 201   #V0 #HV10 >plus_minus // <minus_minus /3 width=1 by le_S/ <minus_n_n <plus_n_O #H
 202   @(ex2_intro … H) @(cpy_subst … HKV HV10) (**) (* explicit constructor *)
 203   [ /2 width=1 by monotonic_yle_minus_dx/
 204   | <yminus_inj <yplus_minus_comm_inj // /3 width=1 by monotonic_ylt_minus_dx, yle_inj/
 205   ]
 206 | #a #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hlmtl
 207   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 208   elim (yle_inv_plus_inj2 … Hlmtl) #_ #Hmlt
 209   elim (IHW12 … HLK … HVW1) -IHW12 // #V2 #HV12 #HVW2
 210   elim (IHU12 … HTU1) -U1 [4: @drop_skip // |2,5: skip |3: /2 width=1 by yle_succ/ ]
 211   >yminus_succ1_inj /3 width=5 by cpy_bind, lift_bind, ex2_intro/
 212 | #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hlmtl
 213   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 214   elim (IHW12 … HLK … HVW1) -W1 //
 215   elim (IHU12 … HLK … HTU1) -U1 -HLK /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 216 ]
 217 qed-.
 218
 219 (* Advanced inversion lemmas on relocation ***********************************)
 220
 221 lemma cpy_inv_lift1_ge_up: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 222                            ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 223                            l ≤ lt → lt ≤ l + m → l + m ≤ lt + mt →
 224                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[l, lt + mt - (l + m)] T2 & ⬆[l, m] T2 ≡ U2.
 225 #G #L #U1 #U2 #lt #mt #HU12 #K #s #l #m #HLK #T1 #HTU1 #Hllt #Hltlm #Hlmlmt
 226 elim (cpy_split_up … HU12 (l + m)) -HU12 // -Hlmlmt #U #HU1 #HU2
 227 lapply (cpy_weak … HU1 l m ? ?) -HU1 // [ >ymax_pre_sn_comm // ] -Hllt -Hltlm #HU1
 228 lapply (cpy_inv_lift1_eq … HTU1 … HU1) -HU1 #HU1 destruct
 229 elim (cpy_inv_lift1_ge … HU2 … HLK … HTU1) -U -L /2 width=3 by ex2_intro/
 230 qed-.
 231
 232 lemma cpy_inv_lift1_be_up: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 233                            ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 234                            lt ≤ l → lt + mt ≤ l + m →
 235                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[lt, l-lt] T2 & ⬆[l, m] T2 ≡ U2.
 236 #G #L #U1 #U2 #lt #mt #HU12 #K #s #l #m #HLK #T1 #HTU1 #Hltl #Hlmtlm
 237 lapply (cpy_weak … HU12 lt (l+m-lt) ? ?) -HU12 //
 238 [ >ymax_pre_sn_comm /2 width=1 by yle_plus_dx1_trans/ ] -Hlmtlm #HU12
 239 elim (cpy_inv_lift1_be … HU12 … HLK … HTU1) -U1 -L /2 width=3 by ex2_intro/
 240 qed-.
 241
 242 lemma cpy_inv_lift1_le_up: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 243                            ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 244                            lt ≤ l → l ≤ lt + mt → lt + mt ≤ l + m →
 245                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[lt, l - lt] T2 & ⬆[l, m] T2 ≡ U2.
 246 #G #L #U1 #U2 #lt #mt #HU12 #K #s #l #m #HLK #T1 #HTU1 #Hltl #Hllmt #Hlmtlm
 247 elim (cpy_split_up … HU12 l) -HU12 // #U #HU1 #HU2
 248 elim (cpy_inv_lift1_le … HU1 … HLK … HTU1) -U1
 249 [2: >ymax_pre_sn_comm // ] -Hltl #T #HT1 #HTU
 250 lapply (cpy_weak … HU2 l m ? ?) -HU2 //
 251 [ >ymax_pre_sn_comm // ] -Hllmt -Hlmtlm #HU2
 252 lapply (cpy_inv_lift1_eq … HTU … HU2) -L #H destruct /2 width=3 by ex2_intro/
 253 qed-.