matita/matita/contribs/lambdadelta/basic_2/etc/csup/yprs.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 notation "hvbox( h ⊢ break ⦃ L1, break T1 ⦄ • ⥸  * break [ g ] break ⦃ L2 , break T2 ⦄ )"
  16    non associative with precedence 45
  17    for @{ 'YPRedStar $h $g $L1 $T1 $L2 $T2 }.
  18
  19 include "basic_2/reducibility/ypr.ma".
  20
  21 (* HYPER PARALLEL COMPUTATION ON CLOSURES ***********************************)
  22
  23 definition yprs: ∀h. sd h → bi_relation lenv term ≝
  24                  λh,g. bi_TC … (ypr h g).
  25
  26 interpretation "hyper parallel computation (closure)"
  27    'YPRedStar h g L1 T1 L2 T2 = (yprs h g L1 T1 L2 T2).
  28
  29 (* Basic eliminators ********************************************************)
  30
  31 lemma yprs_ind: ∀h,g,L1,T1. ∀R:relation2 lenv term. R L1 T1 →
  32                 (∀L,L2,T,T2. h ⊢ ⦃L1, T1⦄ •⥸*[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ •⥸[g] ⦃L2, T2⦄ → R L T → R L2 T2) →
  33                 ∀L2,T2. h ⊢ ⦃L1, T1⦄ •⥸*[g] ⦃L2, T2⦄ → R L2 T2.
  34 /3 width=7 by bi_TC_star_ind/ qed-.
  35
  36 lemma yprs_ind_dx: ∀h,g,L2,T2. ∀R:relation2 lenv term. R L2 T2 →
  37                    (∀L1,L,T1,T. h ⊢ ⦃L1, T1⦄ •⥸[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ •⥸*[g] ⦃L2, T2⦄ → R L T → R L1 T1) →
  38                    ∀L1,T1. h ⊢ ⦃L1, T1⦄ •⥸*[g] ⦃L2, T2⦄ → R L1 T1.
  39 /3 width=7 by bi_TC_star_ind_dx/ qed-.
  40
  41 (* Basic properties *********************************************************)
  42
  43 lemma yprs_refl: ∀h,g. bi_reflexive … (yprs h g).
  44 /2 width=1/ qed.
  45
  46 lemma yprs_strap1: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ •⥸*[g] ⦃L, T⦄ →
  47                    h ⊢ ⦃L, T⦄ •⥸[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ •⥸*[g] ⦃L2, T2⦄.
  48 /2 width=4/ qed.
  49
  50 lemma yprs_strap2: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ •⥸[g] ⦃L, T⦄ →
  51                    h ⊢ ⦃L, T⦄ •⥸*[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ •⥸*[g] ⦃L2, T2⦄.
  52 /2 width=4/ qed.