matita/matita/contribs/lambdadelta/basic_2/etc/fpbq/fpbq_alt.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/btpredalt_8.ma".
  16 include "basic_2/reduction/fpb_fleq.ma".
  17 include "basic_2/reduction/fpbq.ma".
  18
  19 (* "QRST" PARALLEL REDUCTION FOR CLOSURES ***********************************)
  20
  21 (* Basic properties *********************************************************)
  22
  23 lemma fleq_fpbq: ∀h,o,G1,G2,L1,L2,T1,T2.
  24                  ⦃G1, L1, T1⦄ ≡[0] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≽[h, o] ⦃G2, L2, T2⦄.
  25 #h #o #G1 #G2 #L1 #L2 #T1 #T2 * /2 width=1 by fpbq_lleq/
  26 qed.
  27
  28 lemma fpb_fpbq: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻[h, o] ⦃G2, L2, T2⦄ →
  29                 ⦃G1, L1, T1⦄ ≽[h, o] ⦃G2, L2, T2⦄.
  30 #h #o #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2
  31 /3 width=1 by fpbq_fquq, fpbq_cpx, fpbq_lpx, fqu_fquq/
  32 qed.
  33
  34 (* Advanced eliminators *****************************************************)
  35
  36 lemma fpbq_ind_alt: ∀h,o,G1,G2,L1,L2,T1,T2. ∀R:Prop.
  37                     (⦃G1, L1, T1⦄ ≡[0] ⦃G2, L2, T2⦄ → R) →
  38                     (⦃G1, L1, T1⦄ ≻[h, o] ⦃G2, L2, T2⦄ → R) →
  39                     ⦃G1, L1, T1⦄ ≽[h, o] ⦃G2, L2, T2⦄ → R.
  40 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #R #HI1 #HI2 #H elim (fpbq_fpbqa … H) /2 width=1 by/
  41 qed-.
  42
  43 (* aternative definition of fpb *********************************************)
  44
  45 lemma fpb_fpbq_alt: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻[h, o] ⦃G2, L2, T2⦄ →
  46                     ⦃G1, L1, T1⦄ ≽[h, o] ⦃G2, L2, T2⦄ ∧ (⦃G1, L1, T1⦄ ≡[0] ⦃G2, L2, T2⦄ → ⊥).
  47 /3 width=10 by fpb_fpbq, fpb_inv_fleq, conj/ qed.
  48
  49 lemma fpbq_inv_fpb_alt: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≽[h, o] ⦃G2, L2, T2⦄ →
  50                         (⦃G1, L1, T1⦄ ≡[0] ⦃G2, L2, T2⦄ → ⊥) → ⦃G1, L1, T1⦄ ≻[h, o] ⦃G2, L2, T2⦄.
  51 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H #H0 @(fpbq_ind_alt … H) -H //
  52 #H elim H0 -H0 //
  53 qed-.