matita/matita/contribs/lambdadelta/basic_2/etc/lenv_px/lenv_px_sn.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lenv_length.ma".
  16
  17 (* SN POINTWISE EXTENSION OF A CONTEXT-SENSITIVE REALTION FOR TERMS **********)
  18
  19 inductive lpx_sn (R:lenv→relation term): relation lenv ≝
  20 | lpx_sn_stom: lpx_sn R (⋆) (⋆)
  21 | lpx_sn_pair: ∀I,K1,K2,V1,V2.
  22                lpx_sn R K1 K2 → R K1 V1 V2 → lpx_sn R (K1. ⓑ{I} V1) (K2. ⓑ{I} V2)
  23 .
  24
  25 (* Basic inversion lemmas ***************************************************)
  26
  27 fact lpx_sn_inv_atom1_aux: ∀R,L1,L2. lpx_sn R L1 L2 → L1 = ⋆ → L2 = ⋆.
  28 #R #L1 #L2 * -L1 -L2
  29 [ //
  30 | #I #K1 #K2 #V1 #V2 #_ #_ #H destruct
  31 ]
  32 qed-.
  33
  34 lemma lpx_sn_inv_atom1: ∀R,L2. lpx_sn R (⋆) L2 → L2 = ⋆.
  35 /2 width=4 by lpx_sn_inv_atom1_aux/ qed-.
  36
  37 fact lpx_sn_inv_pair1_aux: ∀R,L1,L2. lpx_sn R L1 L2 → ∀I,K1,V1. L1 = K1. ⓑ{I} V1 →
  38                            ∃∃K2,V2. lpx_sn R K1 K2 & R K1 V1 V2 & L2 = K2. ⓑ{I} V2.
  39 #R #L1 #L2 * -L1 -L2
  40 [ #J #K1 #V1 #H destruct
  41 | #I #K1 #K2 #V1 #V2 #HK12 #HV12 #J #L #W #H destruct /2 width=5/
  42 ]
  43 qed-.
  44
  45 lemma lpx_sn_inv_pair1: ∀R,I,K1,V1,L2. lpx_sn R (K1. ⓑ{I} V1) L2 →
  46                         ∃∃K2,V2. lpx_sn R K1 K2 & R K1 V1 V2 & L2 = K2. ⓑ{I} V2.
  47 /2 width=3 by lpx_sn_inv_pair1_aux/ qed-.
  48
  49 fact lpx_sn_inv_atom2_aux: ∀R,L1,L2. lpx_sn R L1 L2 → L2 = ⋆ → L1 = ⋆.
  50 #R #L1 #L2 * -L1 -L2
  51 [ //
  52 | #I #K1 #K2 #V1 #V2 #_ #_ #H destruct
  53 ]
  54 qed-.
  55
  56 lemma lpx_sn_inv_atom2: ∀R,L1. lpx_sn R L1 (⋆) → L1 = ⋆.
  57 /2 width=4 by lpx_sn_inv_atom2_aux/ qed-.
  58
  59 fact lpx_sn_inv_pair2_aux: ∀R,L1,L2. lpx_sn R L1 L2 → ∀I,K2,V2. L2 = K2. ⓑ{I} V2 →
  60                            ∃∃K1,V1. lpx_sn R K1 K2 & R K1 V1 V2 & L1 = K1. ⓑ{I} V1.
  61 #R #L1 #L2 * -L1 -L2
  62 [ #J #K2 #V2 #H destruct
  63 | #I #K1 #K2 #V1 #V2 #HK12 #HV12 #J #K #W #H destruct /2 width=5/
  64 ]
  65 qed-.
  66
  67 lemma lpx_sn_inv_pair2: ∀R,I,L1,K2,V2. lpx_sn R L1 (K2. ⓑ{I} V2) →
  68                         ∃∃K1,V1. lpx_sn R K1 K2 & R K1 V1 V2 & L1 = K1. ⓑ{I} V1.
  69 /2 width=3 by lpx_sn_inv_pair2_aux/ qed-.
  70
  71 (* Basic forward lemmas *****************************************************)
  72
  73 lemma lpx_sn_fwd_length: ∀R,L1,L2. lpx_sn R L1 L2 → |L1| = |L2|.
  74 #R #L1 #L2 #H elim H -L1 -L2 normalize //
  75 qed-.