matita/matita/contribs/lambdadelta/basic_2/etc/llpx_sn/llpx_sn_drop.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/drop_drop.ma".
  16 include "basic_2/multiple/llpx_sn_lreq.ma".
  17
  18 (* LAZY SN POINTWISE EXTENSION OF A CONTEXT-SENSITIVE REALTION FOR TERMS ****)
  19
  20 (* Advanced forward lemmas **************************************************)
  21
  22 lemma llpx_sn_fwd_lref_dx: ∀R,L1,L2,l,i. llpx_sn R l (#i) L1 L2 →
  23                            ∀I,K2,V2. ⬇[i] L2 ≡ K2.ⓑ{I}V2 →
  24                            i < l ∨
  25                            ∃∃K1,V1. ⬇[i] L1 ≡ K1.ⓑ{I}V1 & llpx_sn R 0 V1 K1 K2 &
  26                                     R K1 V1 V2 & l ≤ i.
  27 #R #L1 #L2 #l #i #H #I #K2 #V2 #HLK2 elim (llpx_sn_fwd_lref … H) -H [ * || * ]
  28 [ #_ #H elim (lt_refl_false i)
  29   lapply (drop_fwd_length_lt2 … HLK2) -HLK2
  30   /2 width=3 by lt_to_le_to_lt/ (**) (* full auto too slow *)
  31 | /2 width=1 by or_introl/
  32 | #I #K11 #K22 #V11 #V22 #HLK11 #HLK22 #HK12 #HV12 #Hli
  33   lapply (drop_mono … HLK22 … HLK2) -L2 #H destruct
  34   /3 width=5 by ex4_2_intro, or_intror/
  35 ]
  36 qed-.
  37
  38 lemma llpx_sn_fwd_lref_sn: ∀R,L1,L2,l,i. llpx_sn R l (#i) L1 L2 →
  39                            ∀I,K1,V1. ⬇[i] L1 ≡ K1.ⓑ{I}V1 →
  40                            i < l ∨
  41                            ∃∃K2,V2. ⬇[i] L2 ≡ K2.ⓑ{I}V2 & llpx_sn R 0 V1 K1 K2 &
  42                                     R K1 V1 V2 & l ≤ i.
  43 #R #L1 #L2 #l #i #H #I #K1 #V1 #HLK1 elim (llpx_sn_fwd_lref … H) -H [ * || * ]
  44 [ #H #_ elim (lt_refl_false i)
  45   lapply (drop_fwd_length_lt2 … HLK1) -HLK1
  46   /2 width=3 by lt_to_le_to_lt/ (**) (* full auto too slow *)
  47 | /2 width=1 by or_introl/
  48 | #I #K11 #K22 #V11 #V22 #HLK11 #HLK22 #HK12 #HV12 #Hli
  49   lapply (drop_mono … HLK11 … HLK1) -L1 #H destruct
  50   /3 width=5 by ex4_2_intro, or_intror/
  51 ]
  52 qed-.
  53
  54 (* Advanced inversion lemmas ************************************************)
  55
  56 lemma llpx_sn_inv_lref_ge_dx: ∀R,L1,L2,l,i. llpx_sn R l (#i) L1 L2 → l ≤ i →
  57                               ∀I,K2,V2. ⬇[i] L2 ≡ K2.ⓑ{I}V2 →
  58                               ∃∃K1,V1. ⬇[i] L1 ≡ K1.ⓑ{I}V1 &
  59                                        llpx_sn R 0 V1 K1 K2 & R K1 V1 V2.
  60 #R #L1 #L2 #l #i #H #Hli #I #K2 #V2 #HLK2 elim (llpx_sn_fwd_lref_dx … H … HLK2) -L2
  61 [ #H elim (ylt_yle_false … H Hli)
  62 | * /2 width=5 by ex3_2_intro/
  63 ]
  64 qed-.
  65
  66 lemma llpx_sn_inv_lref_ge_sn: ∀R,L1,L2,l,i. llpx_sn R l (#i) L1 L2 → l ≤ i →
  67                               ∀I,K1,V1. ⬇[i] L1 ≡ K1.ⓑ{I}V1 →
  68                               ∃∃K2,V2. ⬇[i] L2 ≡ K2.ⓑ{I}V2 &
  69                                        llpx_sn R 0 V1 K1 K2 & R K1 V1 V2.
  70 #R #L1 #L2 #l #i #H #Hli #I #K1 #V1 #HLK1 elim (llpx_sn_fwd_lref_sn … H … HLK1) -L1
  71 [ #H elim (ylt_yle_false … H Hli)
  72 | * /2 width=5 by ex3_2_intro/
  73 ]
  74 qed-.
  75
  76 lemma llpx_sn_inv_lref_ge_bi: ∀R,L1,L2,l,i. llpx_sn R l (#i) L1 L2 → l ≤ i →
  77                               ∀I1,I2,K1,K2,V1,V2.
  78                               ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
  79                               ∧∧ I1 = I2 & llpx_sn R 0 V1 K1 K2 & R K1 V1 V2.
  80 #R #L1 #L2 #l #i #HL12 #Hli #I1 #I2 #K1 #K2 #V1 #V2 #HLK1 #HLK2
  81 elim (llpx_sn_inv_lref_ge_sn … HL12 … HLK1) // -L1 -l
  82 #J #Y #HY lapply (drop_mono … HY … HLK2) -L2 -i #H destruct /2 width=1 by and3_intro/
  83 qed-.
  84
  85 fact llpx_sn_inv_S_aux: ∀R,L1,L2,T,l0. llpx_sn R l0 T L1 L2 → ∀l. l0 = l + 1 →
  86                         ∀K1,K2,I,V1,V2. ⬇[l] L1 ≡ K1.ⓑ{I}V1 → ⬇[l] L2 ≡ K2.ⓑ{I}V2 →
  87                         llpx_sn R 0 V1 K1 K2 → R K1 V1 V2 → llpx_sn R l T L1 L2.
  88 #R #L1 #L2 #T #l0 #H elim H -L1 -L2 -T -l0
  89 /2 width=1 by llpx_sn_gref, llpx_sn_free, llpx_sn_sort/
  90 [ #L1 #L2 #l0 #i #HL12 #Hil #l #H #K1 #K2 #I #V1 #V2 #HLK1 #HLK2 #HK12 #HV12 destruct
  91   elim (yle_split_eq i l) /2 width=1 by llpx_sn_skip, ylt_fwd_succ2/ -HL12 -Hil
  92   #H destruct /2 width=9 by llpx_sn_lref/
  93 | #I #L1 #L2 #K11 #K22 #V1 #V2 #l0 #i #Hl0i #HLK11 #HLK22 #HK12 #HV12 #_ #l #H #K1 #K2 #J #W1 #W2 #_ #_ #_ #_ destruct
  94   /3 width=9 by llpx_sn_lref, yle_pred_sn/
  95 | #a #I #L1 #L2 #V #T #l0 #_ #_ #IHV #IHT #l #H #K1 #K2 #J #W1 #W2 #HLK1 #HLK2 #HK12 #HW12 destruct
  96   /4 width=9 by llpx_sn_bind, drop_drop/
  97 | #I #L1 #L2 #V #T #l0 #_ #_ #IHV #IHT #l #H #K1 #K2 #J #W1 #W2 #HLK1 #HLK2 #HK12 #HW12 destruct
  98   /3 width=9 by llpx_sn_flat/
  99 ]
 100 qed-.
 101
 102 lemma llpx_sn_inv_S: ∀R,L1,L2,T,l. llpx_sn R (l + 1) T L1 L2 →
 103                      ∀K1,K2,I,V1,V2. ⬇[l] L1 ≡ K1.ⓑ{I}V1 → ⬇[l] L2 ≡ K2.ⓑ{I}V2 →
 104                      llpx_sn R 0 V1 K1 K2 → R K1 V1 V2 → llpx_sn R l T L1 L2.
 105 /2 width=9 by llpx_sn_inv_S_aux/ qed-.
 106
 107 lemma llpx_sn_inv_bind_O: ∀R. (∀L. reflexive … (R L)) →
 108                           ∀a,I,L1,L2,V,T. llpx_sn R 0 (ⓑ{a,I}V.T) L1 L2 →
 109                           llpx_sn R 0 V L1 L2 ∧ llpx_sn R 0 T (L1.ⓑ{I}V) (L2.ⓑ{I}V).
 110 #R #HR #a #I #L1 #L2 #V #T #H elim (llpx_sn_inv_bind … H) -H
 111 /3 width=9 by drop_pair, conj, llpx_sn_inv_S/
 112 qed-.
 113
 114 (* More advanced forward lemmas *********************************************)
 115
 116 lemma llpx_sn_fwd_bind_O_dx: ∀R. (∀L. reflexive … (R L)) →
 117                              ∀a,I,L1,L2,V,T. llpx_sn R 0 (ⓑ{a,I}V.T) L1 L2 →
 118                              llpx_sn R 0 T (L1.ⓑ{I}V) (L2.ⓑ{I}V).
 119 #R #HR #a #I #L1 #L2 #V #T #H elim (llpx_sn_inv_bind_O … H) -H //
 120 qed-.
 121
 122 (* Advanced properties ******************************************************)
 123
 124 lemma llpx_sn_bind_repl_O: ∀R,I,L1,L2,V1,V2,T. llpx_sn R 0 T (L1.ⓑ{I}V1) (L2.ⓑ{I}V2) →
 125                            ∀J,W1,W2. llpx_sn R 0 W1 L1 L2 → R L1 W1 W2 → llpx_sn R 0 T (L1.ⓑ{J}W1) (L2.ⓑ{J}W2).
 126 /3 width=9 by llpx_sn_bind_repl_SO, llpx_sn_inv_S/ qed-.
 127
 128 (* Inversion lemmas on negated lazy pointwise extension *********************)
 129
 130 lemma nllpx_sn_inv_bind: ∀R. (∀L,T1,T2. Decidable (R L T1 T2)) →
 131                          ∀a,I,L1,L2,V,T,l. (llpx_sn R l (ⓑ{a,I}V.T) L1 L2 → ⊥) →
 132                          (llpx_sn R l V L1 L2 → ⊥) ∨ (llpx_sn R (⫯l) T (L1.ⓑ{I}V) (L2.ⓑ{I}V) → ⊥).
 133 #R #HR #a #I #L1 #L2 #V #T #l #H elim (llpx_sn_dec … HR V L1 L2 l)
 134 /4 width=1 by llpx_sn_bind, or_intror, or_introl/
 135 qed-.
 136
 137 lemma nllpx_sn_inv_flat: ∀R. (∀L,T1,T2. Decidable (R L T1 T2)) →
 138                          ∀I,L1,L2,V,T,l. (llpx_sn R l (ⓕ{I}V.T) L1 L2 → ⊥) →
 139                          (llpx_sn R l V L1 L2 → ⊥) ∨ (llpx_sn R l T L1 L2 → ⊥).
 140 #R #HR #I #L1 #L2 #V #T #l #H elim (llpx_sn_dec … HR V L1 L2 l)
 141 /4 width=1 by llpx_sn_flat, or_intror, or_introl/
 142 qed-.
 143
 144 lemma nllpx_sn_inv_bind_O: ∀R. (∀L,T1,T2. Decidable (R L T1 T2)) →
 145                            ∀a,I,L1,L2,V,T. (llpx_sn R 0 (ⓑ{a,I}V.T) L1 L2 → ⊥) →
 146                            (llpx_sn R 0 V L1 L2 → ⊥) ∨ (llpx_sn R 0 T (L1.ⓑ{I}V) (L2.ⓑ{I}V) → ⊥).
 147 #R #HR #a #I #L1 #L2 #V #T #H elim (llpx_sn_dec … HR V L1 L2 0)
 148 /4 width=1 by llpx_sn_bind_O, or_intror, or_introl/
 149 qed-.