matita/matita/contribs/lambdadelta/basic_2/etc/lpx_sn/llor.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/xoa2.ma".
  16 include "basic_2/notation/relations/lazyor_4.ma".
  17 include "basic_2/relocation/lpx_sn_alt.ma".
  18
  19 (* POINTWISE UNION FOR LOCAL ENVIRONMENTS ***********************************)
  20
  21 inductive clor (T) (L2) (K1) (V1): predicate term ≝
  22 | clor_sn: ∀U. |K1| < |L2| → ⇧[|L2|-|K1|-1, 1] U ≡ T → clor T L2 K1 V1 V1
  23 | clor_dx: ∀I,K2,V2. |K1| < |L2| → (∀U. ⇧[|L2|-|K1|-1, 1] U ≡ T → ⊥) →
  24            ⇩[|L2|-|K1|-1] L2 ≡ K2.ⓑ{I}V2 → clor T L2 K1 V1 V2
  25 .
  26
  27 definition llor: relation4 term lenv lenv lenv ≝
  28                  λT,L2. lpx_sn (clor T L2).
  29
  30 interpretation
  31    "lazy union (local environment)"
  32    'LazyOr L1 T L2 L = (llor T L2 L1 L).
  33
  34 (* Basic properties *********************************************************)
  35
  36 lemma llor_pair_sn: ∀I,L1,L2,L,V,T,U. L1 ⩖[T] L2 ≡ L →
  37                     |L1| < |L2| → ⇧[|L2|-|L1|-1, 1] U ≡ T →
  38                     L1.ⓑ{I}V ⩖[T] L2 ≡ L.ⓑ{I}V.
  39 /3 width=2 by clor_sn, lpx_sn_pair/ qed.
  40
  41 lemma llor_pair_dx: ∀I,J,L1,L2,L,K2,V1,V2,T. L1 ⩖[T] L2 ≡ L →
  42                     |L1| < |L2| → (∀U. ⇧[|L2|-|L1|-1, 1] U ≡ T → ⊥) →
  43                     ⇩[|L2|-|L1|-1] L2 ≡ K2.ⓑ{J}V2 →
  44                     L1.ⓑ{I}V1 ⩖[T] L2 ≡ L.ⓑ{I}V2.
  45 /4 width=3 by clor_dx, lpx_sn_pair/ qed.
  46
  47 lemma llor_total: ∀T,L2,L1. |L1| ≤ |L2| → ∃L. L1 ⩖[T] L2 ≡ L.
  48 #T #L2 #L1 elim L1 -L1 /2 width=2 by ex_intro/
  49 #L1 #I1 #V1 #IHL1 normalize
  50 #H elim IHL1 -IHL1 /2 width=3 by transitive_le/
  51 #L #HT elim (is_lift_dec T (|L2|-|L1|-1) 1)
  52 [ * /3 width=2 by llor_pair_sn, ex_intro/
  53 | elim (ldrop_O1_lt L2 (|L2|-|L1|-1))
  54   /5 width=4 by llor_pair_dx, monotonic_lt_minus_l, ex_intro/
  55 ]
  56 qed-.
  57
  58 (* Alternative definition ***************************************************)
  59
  60 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  61 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  62 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  63 qed-.
  64
  65 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  66 /2 width=1 by plus_minus_minus_be/ qed-.
  67
  68 lemma llor_intro_alt: ∀T,L2,L1,L. |L1| ≤ |L2| → |L1| = |L| →
  69                       (∀I1,I,K1,K,V1,V,i. ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L ≡ K.ⓑ{I}V →
  70                          (∀U. ⇧[|L2|-|L1|+i, 1] U ≡ T →
  71                               ∧∧ I1 = I & V1 = V & K1 ⩖[T] L2 ≡ K
  72                          ) ∧
  73                          (∀I2,K2,V2. (∀U. ⇧[|L2|-|L1|+i, 1] U ≡ T → ⊥) →
  74                                      ⇩[|L2|-|L1|+i] L2 ≡ K2.ⓑ{I2}V2 →
  75                                      ∧∧ I1 = I & V2 = V & K1 ⩖[T] L2 ≡ K
  76                          )
  77                       ) → L1 ⩖[T] L2 ≡ L.
  78 #T #L2 #L1 #L #HL12 #HL1 #IH @lpx_sn_intro_alt // -HL1
  79 #I1 #I #K1 #K #V1 #V #i #HLK1 #HLK
  80 lapply (ldrop_fwd_length_minus4 … HLK1)
  81 lapply (ldrop_fwd_length_le4 … HLK1)
  82 normalize #HKL1 #H1i lapply (plus_minus_minus_be_aux … HL12 H1i) // #H2i
  83 lapply (transitive_le … HKL1 HL12) -HKL1 -HL12 #HKL1
  84 elim (IH … HLK1 HLK) -IH -HLK1 -HLK #IH1 #IH2
  85 elim (is_lift_dec T (|L2|-|L1|+i) 1)
  86 [ -IH2 * #U #HUT elim (IH1 … HUT) -IH1
  87   /3 width=2 by clor_sn, and3_intro/
  88 | -IH1 #H elim (ldrop_O1_lt L2 (|L2|-|L1|+i)) /2 width=1 by monotonic_lt_minus_l/
  89   #I2 #K2 #V2 #HLK2 elim (IH2 … HLK2) -IH2
  90   /5 width=3 by clor_dx, ex_intro, and3_intro/
  91 ]
  92 qed.
  93
  94 lemma llor_ind_alt: ∀T,L2. ∀S:relation lenv. (
  95                        ∀L1,L. |L1| = |L| → (
  96                           ∀I1,I,K1,K,V1,V,i.
  97                           ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L ≡ K.ⓑ{I}V →
  98                           (∃∃U. ⇧[|L2|-|L1|+i, 1] U ≡ T &
  99                                 I1 = I & V1 = V & K1 ⩖[T] L2 ≡ K & S K1 K
 100                           ) ∨
 101                           (∃∃I2,K2,V2. (∀U. ⇧[|L2|-|L1|+i, 1] U ≡ T → ⊥) &
 102                                        ⇩[|L2|-|L1|+i] L2 ≡ K2.ⓑ{I2}V2 &
 103                                        I1 = I & V2 = V & K1 ⩖[T] L2 ≡ K & S K1 K
 104                           )
 105                        ) → |L1| ≤ |L2| → S L1 L
 106                     ) →
 107                     ∀L1,L. L1 ⩖[T] L2 ≡ L → |L1| ≤ |L2| → S L1 L.
 108 #T #L2 #S #IH1 #L1 #L #H @(lpx_sn_ind_alt … H) -L1 -L
 109 #L1 #L #HL1 #IH2 #HL12 @IH1 // -IH1 -HL1
 110 #I1 #I #K1 #K #V1 #V #i #HLK1 #HLK
 111 lapply (ldrop_fwd_length_minus4 … HLK1)
 112 lapply (ldrop_fwd_length_le4 … HLK1)
 113 normalize #HKL1 #H1i lapply (plus_minus_minus_be_aux … HL12 H1i) //
 114 lapply (transitive_le … HKL1 HL12) -HKL1 -HL12
 115 elim (IH2 … HLK1 HLK) -IH2 #H *
 116 /5 width=5 by lt_to_le, ex6_3_intro, ex5_intro, or_intror, or_introl/
 117 qed-.
 118
 119 lemma llor_inv_alt: ∀T,L2,L1,L. L1 ⩖[T] L2 ≡ L → |L1| ≤ |L2| →
 120                     |L1| = |L| ∧
 121                     (∀I1,I,K1,K,V1,V,i.
 122                        ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L ≡ K.ⓑ{I}V →
 123                        (∃∃U. ⇧[|L2|-|L1|+i, 1] U ≡ T &
 124                              I1 = I & V1 = V & K1 ⩖[T] L2 ≡ K
 125                        ) ∨
 126                        (∃∃I2,K2,V2. (∀U. ⇧[|L2|-|L1|+i, 1] U ≡ T → ⊥) &
 127                                     ⇩[|L2|-|L1|+i] L2 ≡ K2.ⓑ{I2}V2 &
 128                                     I1 = I & V2 = V & K1 ⩖[T] L2 ≡ K
 129                        )
 130                     ).
 131 #T #L2 #L1 #L #H #HL12 elim (lpx_sn_inv_alt … H) -H
 132 #HL1 #IH @conj // -HL1
 133 #I1 #I #K1 #K #V1 #V #i #HLK1 #HLK
 134 lapply (ldrop_fwd_length_minus4 … HLK1)
 135 lapply (ldrop_fwd_length_le4 … HLK1)
 136 normalize #HKL1 #H1i lapply (plus_minus_minus_be_aux … HL12 H1i) //
 137 lapply (transitive_le … HKL1 HL12) -HKL1 -HL12
 138 elim (IH … HLK1 HLK) -IH #H *
 139 /4 width=5 by ex5_3_intro, ex4_intro, or_intror, or_introl/
 140 qed-.