matita/matita/contribs/lambdadelta/basic_2/etc/lpxs/lpxs_fqus.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/lfpx.ma".
  16
  17 (* UNCOUNTED PARALLEL RT-COMPUTATION FOR LOCAL ENV.S ON REFERRED ENTRIES ****)
  18
  19
  20
  21 (* Properties on supclosure *************************************************)
  22
  23 lemma lpx_fqup_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
  24                       ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, o] L1 →
  25                       ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, o] T & ⦃G1, K1, T⦄ ⊐+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, o] L2.
  26 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  27 [ #G2 #L2 #T2 #H12 #K1 #HKL1 elim (lpx_fqu_trans … H12 … HKL1) -L1
  28   /3 width=5 by cpx_cpxs, fqu_fqup, ex3_2_intro/
  29 | #G #G2 #L #L2 #T #T2 #_ #H2 #IH1 #K1 #HLK1 elim (IH1 … HLK1) -L1
  30   #L0 #T0 #HT10 #HT0 #HL0 elim (lpx_fqu_trans … H2 … HL0) -L
  31   #L #T3 #HT3 #HT32 #HL2 elim (fqup_cpx_trans … HT0 … HT3) -T
  32   /3 width=7 by cpxs_strap1, fqup_strap1, ex3_2_intro/
  33 ]
  34 qed-.
  35
  36 lemma lpx_fqus_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
  37                       ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, o] L1 →
  38                       ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, o] T & ⦃G1, K1, T⦄ ⊐* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, o] L2.
  39 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqus_ind … H) -G2 -L2 -T2 [ /2 width=5 by ex3_2_intro/ ]
  40 #G #G2 #L #L2 #T #T2 #_ #H2 #IH1 #K1 #HLK1 elim (IH1 … HLK1) -L1
  41 #L0 #T0 #HT10 #HT0 #HL0 elim (lpx_fquq_trans … H2 … HL0) -L
  42 #L #T3 #HT3 #HT32 #HL2 elim (fqus_cpx_trans … HT0 … HT3) -T
  43 /3 width=7 by cpxs_strap1, fqus_strap1, ex3_2_intro/
  44 qed-.
  45
  46 lemma lpxs_fquq_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  47                        ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, o] L1 →
  48                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, o] T & ⦃G1, K1, T⦄ ⊐⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, o] L2.
  49 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #HT12 #K1 #H @(lpxs_ind_dx … H) -K1
  50 [ /2 width=5 by ex3_2_intro/
  51 | #K1 #K #HK1 #_ * #L #T #HT1 #HT2 #HL2 -HT12
  52   lapply (lpx_cpxs_trans … HT1 … HK1) -HT1
  53   elim (lpx_fquq_trans … HT2 … HK1) -K
  54   /3 width=7 by lpxs_strap2, cpxs_strap1, ex3_2_intro/
  55 ]
  56 qed-.
  57
  58 lemma lpxs_fqup_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
  59                        ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, o] L1 →
  60                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, o] T & ⦃G1, K1, T⦄ ⊐+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, o] L2.
  61 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #HT12 #K1 #H @(lpxs_ind_dx … H) -K1
  62 [ /2 width=5 by ex3_2_intro/
  63 | #K1 #K #HK1 #_ * #L #T #HT1 #HT2 #HL2 -HT12
  64   lapply (lpx_cpxs_trans … HT1 … HK1) -HT1
  65   elim (lpx_fqup_trans … HT2 … HK1) -K
  66   /3 width=7 by lpxs_strap2, cpxs_trans, ex3_2_intro/
  67 ]
  68 qed-.
  69
  70 lemma lpxs_fqus_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
  71                        ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, o] L1 →
  72                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, o] T & ⦃G1, K1, T⦄ ⊐* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, o] L2.
  73 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqus_ind … H) -G2 -L2 -T2 /2 width=5 by ex3_2_intro/
  74 #G #G2 #L #L2 #T #T2 #_ #H2 #IH1 #K1 #HLK1 elim (IH1 … HLK1) -L1
  75 #L0 #T0 #HT10 #HT0 #HL0 elim (lpxs_fquq_trans … H2 … HL0) -L
  76 #L #T3 #HT3 #HT32 #HL2 elim (fqus_cpxs_trans … HT3 … HT0) -T
  77 /3 width=7 by cpxs_trans, fqus_strap1, ex3_2_intro/
  78 qed-.
  79
  80 lemma lpxs_lleq_fqu_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  81                            ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, o] L1 → K1 ≡[T1, 0] L1 →
  82                            ∃∃K2. ⦃G1, K1, T1⦄ ⊐ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, o] L2 & K2 ≡[T2, 0] L2.
  83 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  84 [ #I #G1 #L1 #V1 #X #H1 #H2 elim (lpxs_inv_pair2 … H1) -H1
  85   #K0 #V0 #H1KL1 #_ #H destruct
  86   elim (lleq_inv_lref_ge_dx … H2 ? I L1 V1) -H2 //
  87   #K1 #H #H2KL1 lapply (drop_inv_O2 … H) -H #H destruct
  88   /2 width=4 by fqu_lref_O, ex3_intro/
  89 | * [ #a ] #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H
  90   [ elim (lleq_inv_bind … H)
  91   | elim (lleq_inv_flat … H)
  92   ] -H /2 width=4 by fqu_pair_sn, ex3_intro/
  93 | #a #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_bind_O … H) -H
  94   /3 width=4 by lpxs_pair, fqu_bind_dx, ex3_intro/
  95 | #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_flat … H) -H
  96   /2 width=4 by fqu_flat_dx, ex3_intro/
  97 | #G1 #L1 #L #T1 #U1 #k #HL1 #HTU1 #K1 #H1KL1 #H2KL1
  98   elim (drop_O1_le (Ⓕ) (k+1) K1)
  99   [ #K #HK1 lapply (lleq_inv_lift_le … H2KL1 … HK1 HL1 … HTU1 ?) -H2KL1 //
 100     #H2KL elim (lpxs_drop_trans_O1 … H1KL1 … HL1) -L1
 101     #K0 #HK10 #H1KL lapply (drop_mono … HK10 … HK1) -HK10 #H destruct
 102     /3 width=4 by fqu_drop, ex3_intro/
 103   | lapply (drop_fwd_length_le2 … HL1) -L -T1 -o
 104     lapply (lleq_fwd_length … H2KL1) //
 105   ]
 106 ]
 107 qed-.
 108
 109 lemma lpxs_lleq_fquq_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
 110                             ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, o] L1 → K1 ≡[T1, 0] L1 →
 111                             ∃∃K2. ⦃G1, K1, T1⦄ ⊐⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, o] L2 & K2 ≡[T2, 0] L2.
 112 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
 113 elim (fquq_inv_gen … H) -H
 114 [ #H elim (lpxs_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
 115   /3 width=4 by fqu_fquq, ex3_intro/
 116 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
 117 ]
 118 qed-.
 119
 120 lemma lpxs_lleq_fqup_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
 121                             ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, o] L1 → K1 ≡[T1, 0] L1 →
 122                             ∃∃K2. ⦃G1, K1, T1⦄ ⊐+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, o] L2 & K2 ≡[T2, 0] L2.
 123 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
 124 [ #G2 #L2 #T2 #H #K1 #H1KL1 #H2KL1 elim (lpxs_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
 125   /3 width=4 by fqu_fqup, ex3_intro/
 126 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #K1 #H1KL1 #H2KL1 elim (IHT1 … H2KL1) // -L1
 127   #K #HT1 #H1KL #H2KL elim (lpxs_lleq_fqu_trans … HT2 … H1KL H2KL) -L
 128   /3 width=5 by fqup_strap1, ex3_intro/
 129 ]
 130 qed-.
 131
 132 lemma lpxs_lleq_fqus_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
 133                             ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, o] L1 → K1 ≡[T1, 0] L1 →
 134                             ∃∃K2. ⦃G1, K1, T1⦄ ⊐* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, o] L2 & K2 ≡[T2, 0] L2.
 135 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
 136 elim (fqus_inv_gen … H) -H
 137 [ #H elim (lpxs_lleq_fqup_trans … H … H1KL1 H2KL1) -L1
 138   /3 width=4 by fqup_fqus, ex3_intro/
 139 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
 140 ]
 141 qed-.