matita/matita/contribs/lambdadelta/basic_2/etc/snv_preserve.etc

   1 lemma snv_cprs_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
   2                     ∀T2. ⦃G, L1⦄ ⊢ T1 ➡* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 → ⦃G, L2⦄ ⊢ T2 ¡[h, g].
   3 #h #g #G #L1 #T1 #HT1 #T2 #H
   4 @(cprs_ind … H) -T2 /3 width=5 by snv_cpr_lpr/
   5 qed-.
   6
   7 lemma da_cprs_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
   8                    ∀l. ⦃G, L1⦄ ⊢ T1 ▪[h, g] l →
   9                    ∀T2. ⦃G, L1⦄ ⊢ T1 ➡* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 → ⦃G, L2⦄ ⊢ T2 ▪[h, g] l.
  10 #h #g #G #L1 #T1 #HT1 #l #Hl #T2 #H
  11 @(cprs_ind … H) -T2 /3 width=6 by snv_cprs_lpr, da_cpr_lpr/
  12 qed-.
  13
  14 lemma da_cpcs: ∀h,g,G,L,T1. ⦃G, L⦄ ⊢ T1 ¡[h, g] →
  15                ∀T2. ⦃G, L⦄ ⊢ T2 ¡[h, g] →
  16                ∀l1. ⦃G, L⦄ ⊢ T1 ▪[h, g] l1 → ∀l2. ⦃G, L⦄ ⊢ T2 ▪[h, g] l2 →
  17                ⦃G, L⦄ ⊢ T1 ⬌* T2 → l1 = l2.
  18 #h #g #G #L #T1 #HT1 #T2 #HT2 #l1 #Hl1 #l2 #Hl2 #H
  19 elim (cpcs_inv_cprs … H) -H /3 width=12 by da_cprs_lpr, da_mono/
  20 qed-.
  21
  22 lemma sta_cpr_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
  23                    ∀l. ⦃G, L1⦄ ⊢ T1 ▪[h, g] l+1 →
  24                    ∀U1. ⦃G, L1⦄ ⊢ T1 •[h] U1 →
  25                    ∀T2. ⦃G, L1⦄ ⊢ T1 ➡ T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 →
  26                    ∃∃U2. ⦃G, L2⦄ ⊢ T2 •[h] U2 & ⦃G, L2⦄ ⊢ U1 ⬌* U2.
  27 #h #g #G #L1 #T1 #HT1 #l #Hl #U1 #HTU1 #T2 #HT12 #L2 #HL12
  28 elim (lstas_cpr_lpr  … 1 … Hl U1 … HT12 … HL12) -Hl -HT12 -HL12
  29 /3 width=3 by lstas_inv_SO, sta_lstas, ex2_intro/
  30 qed-.
  31
  32 lemma lstas_cprs_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
  33                       ∀l1,l2. l2 ≤ l1 → ⦃G, L1⦄ ⊢ T1 ▪[h, g] l1 →
  34                       ∀U1. ⦃G, L1⦄ ⊢ T1 •*[h, l2] U1 →
  35                       ∀T2. ⦃G, L1⦄ ⊢ T1 ➡* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 →
  36                       ∃∃U2. ⦃G, L2⦄ ⊢ T2 •*[h, l2] U2 & ⦃G, L2⦄ ⊢ U1 ⬌* U2.
  37 #h #g #G #L1 #T1 #HT1 #l1 #l2 #Hl21 #Hl1 #U1 #HTU1 #T2 #H
  38 @(cprs_ind … H) -T2 [ /2 width=10 by lstas_cpr_lpr/ ]
  39 #T #T2 #HT1T #HTT2 #IHT1 #L2 #HL12
  40 elim (IHT1 L1) // -IHT1 #U #HTU #HU1
  41 elim (lstas_cpr_lpr … g … Hl21 … HTU … HTT2 … HL12) -HTU -HTT2
  42 [2,3: /2 width=7 by snv_cprs_lpr, da_cprs_lpr/ ] -T1 -T -l1
  43 /4 width=5 by lpr_cpcs_conf, cpcs_trans, ex2_intro/
  44 qed-.
  45
  46 lemma lstas_cpcs_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
  47                       ∀l,l1. l ≤ l1 → ⦃G, L1⦄ ⊢ T1 ▪[h, g] l1 → ∀U1. ⦃G, L1⦄ ⊢ T1 •*[h, l] U1 →
  48                       ∀T2. ⦃G, L1⦄ ⊢ T2 ¡[h, g] →
  49                       ∀l2. l ≤ l2 → ⦃G, L1⦄ ⊢ T2 ▪[h, g] l2 → ∀U2. ⦃G, L1⦄ ⊢ T2 •*[h, l] U2 →
  50                       ⦃G, L1⦄ ⊢ T1 ⬌* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 → ⦃G, L2⦄ ⊢ U1 ⬌* U2.
  51 #h #g #G #L1 #T1 #HT1 #l #l1 #Hl1 #HTl1 #U1 #HTU1 #T2 #HT2 #l2 #Hl2 #HTl2 #U2 #HTU2 #H #L2 #HL12
  52 elim (cpcs_inv_cprs … H) -H #T #H1 #H2
  53 elim (lstas_cprs_lpr … HT1 … Hl1 HTl1 … HTU1 … H1 … HL12) -T1 #W1 #H1 #HUW1
  54 elim (lstas_cprs_lpr … HT2 … Hl2 HTl2 … HTU2 … H2 … HL12) -T2 #W2 #H2 #HUW2
  55 lapply (lstas_mono … H1 … H2) -h -T -l #H destruct /2 width=3 by cpcs_canc_dx/
  56 qed-.
  57
  58 lemma snv_sta: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ T ¡[h, g] →
  59                ∀l. ⦃G, L⦄ ⊢ T ▪[h, g] l+1 →
  60                ∀U. ⦃G, L⦄ ⊢ T •[h] U → ⦃G, L⦄ ⊢ U ¡[h, g].
  61 /3 width=7 by lstas_inv_SO, sta_lstas, snv_lstas/ qed-.
  62
  63 lemma lstas_cpds: ∀h,g,G,L,T1. ⦃G, L⦄ ⊢ T1 ¡[h, g] →
  64                   ∀l1,l2. l2 ≤ l1 → ⦃G, L⦄ ⊢ T1 ▪[h, g] l1 →
  65                   ∀U1. ⦃G, L⦄ ⊢ T1 •*[h, l2] U1 → ∀T2. ⦃G, L⦄ ⊢ T1 •*➡*[h, g] T2 →
  66                   ∃∃U2,l. l ≤ l2 & ⦃G, L⦄ ⊢ T2 •*[h, l] U2 & ⦃G, L⦄ ⊢ U1 •*⬌*[h, g] U2.
  67 #h #g #G #L #T1 #HT1 #l1 #l2 #Hl21 #Hl1 #U1 #HTU1 #T2 * #T #l0 #l #Hl0 #H #HT1T #HTT2
  68 lapply (da_mono … H … Hl1) -H #H destruct
  69 lapply (lstas_da_conf … HTU1 … Hl1) #Hl12
  70 elim (le_or_ge l2 l) #Hl2
  71 [ lapply (lstas_conf_le … HTU1 … HT1T) -HT1T //
  72   /5 width=11 by cpds_cpes_dx, monotonic_le_minus_l, ex3_2_intro, ex4_3_intro/
  73 | lapply (lstas_da_conf … HT1T … Hl1) #Hl1l
  74   lapply (lstas_conf_le … HT1T … HTU1) -HTU1 // #HTU1
  75   elim (lstas_cprs_lpr … Hl1l … HTU1 … HTT2 L) -Hl1l -HTU1 -HTT2
  76   /3 width=7 by snv_lstas, cpcs_cpes, monotonic_le_minus_l, ex3_2_intro/
  77 ]
  78 qed-.
  79
  80 lemma cpds_cpr_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
  81                     ∀U1. ⦃G, L1⦄ ⊢ T1 •*➡*[h, g] U1 →
  82                     ∀T2. ⦃G, L1⦄ ⊢ T1 ➡ T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 →
  83                     ∃∃U2. ⦃G, L2⦄ ⊢ T2 •*➡*[h, g] U2 & ⦃G, L2⦄ ⊢ U1 ➡* U2.
  84 #h #g #G #L1 #T1 #HT1 #U1 * #W1 #l1 #l2 #Hl21 #Hl1 #HTW1 #HWU1 #T2 #HT12 #L2 #HL12
  85 elim (lstas_cpr_lpr … Hl1 … HTW1 … HT12 … HL12) // #W2 #HTW2 #HW12
  86 lapply (da_cpr_lpr … Hl1 … HT12 … HL12) // -T1
  87 lapply (lpr_cprs_conf … HL12 … HWU1) -L1 #HWU1
  88 lapply (cpcs_canc_sn … HW12 HWU1) -W1 #H
  89 elim (cpcs_inv_cprs … H) -H /3 width=7 by ex4_3_intro, ex2_intro/
  90 qed-.