matita/matita/contribs/lambdadelta/basic_2/etc/ssta1/cpds_cpds.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/lsstas_lsstas.ma".
  16 include "basic_2/computation/lprs_cprs.ma".
  17 include "basic_2/computation/cpxs_cpxs.ma".
  18 include "basic_2/computation/cpds.ma".
  19
  20 (* DECOMPOSED EXTENDED PARALLEL COMPUTATION ON TERMS ************************)
  21
  22 (* Advanced properties ******************************************************)
  23
  24 lemma cpds_strap2: ∀h,g,G,L,T1,T,T2,l. ⦃G, L⦄ ⊢ T1 ▪[h, g] l+1 →
  25                    ⦃G, L⦄ ⊢ T1 •[h, g] T → ⦃G, L⦄ ⊢ T •*➡*[h, g] T2 → ⦃G, L⦄ ⊢ T1 •*➡*[h, g] T2.
  26 #h #g #G #L #T1 #T #T2 #l #Hl #HT1 *
  27 #T0 #l0 #l1 #Hl10 #HT #HT0 #HT02
  28 lapply (ssta_da_conf … HT1 … Hl) <minus_plus_m_m #H0T
  29 lapply (da_mono … H0T … HT) -HT -H0T #H destruct
  30 /3 width=7 by lsstas_step_sn, le_S_S, ex4_3_intro/
  31 qed.
  32
  33 lemma cpds_cprs_trans: ∀h,g,G,L,T1,T,T2.
  34                        ⦃G, L⦄ ⊢ T1 •*➡*[h, g] T → ⦃G, L⦄ ⊢ T ➡* T2 → ⦃G, L⦄ ⊢ T1 •*➡*[h, g] T2.
  35 #h #g #G #L #T1 #T #T2 * /3 width=9 by cprs_trans, ex4_3_intro/
  36 qed-.
  37
  38 lemma lsstas_cpds_trans: ∀h,g,G,L,T1,T,T2,l1,l2.
  39                          l2 ≤ l1 → ⦃G, L⦄ ⊢ T1 ▪[h, g] l1 →
  40                          ⦃G, L⦄ ⊢ T1 •*[h, g, l2] T → ⦃G, L⦄ ⊢ T •*➡*[h, g] T2 → ⦃G, L⦄ ⊢ T1 •*➡*[h, g] T2.
  41 #h #g #G #L #T1 #T #T2 #l1 #l2 #Hl21 #Hl1 #HT1 * #T0 #l3 #l4 #Hl43 #Hl3 #HT0 #HT02
  42 lapply (lsstas_da_conf … HT1 … Hl1) #H0T
  43 lapply (da_mono … H0T … Hl3) -H0T -Hl3 #H destruct
  44 lapply (le_minus_to_plus_r … Hl21 Hl43) -Hl21 -Hl43
  45 /3 width=8 by lsstas_trans, ex4_3_intro/
  46 qed-.
  47
  48 (* Advanced inversion lemmas ************************************************)
  49
  50 lemma cpds_inv_abst1: ∀h,g,a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{a}V1.T1 •*➡*[h, g] U2 →
  51                       ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡* V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 •*➡*[h, g] T2 &
  52                                U2 = ⓛ{a}V2.T2.
  53 #h #g #a #G #L #V1 #T1 #U2 * #X #l1 #l2 #Hl21 #Hl1 #H1 #H2
  54 lapply (da_inv_bind … Hl1) -Hl1 #Hl1
  55 elim (lsstas_inv_bind1 … H1) -H1 #U #HTU1 #H destruct
  56 elim (cprs_inv_abst1 … H2) -H2 #V2 #T2 #HV12 #HUT2 #H destruct
  57 /3 width=7 by ex4_3_intro, ex3_2_intro/
  58 qed-.
  59
  60 lemma cpds_inv_abbr_abst: ∀h,g,a1,a2,G,L,V1,W2,T1,T2. ⦃G, L⦄ ⊢ ⓓ{a1}V1.T1 •*➡*[h, g] ⓛ{a2}W2.T2 →
  61                           ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 •*➡*[h, g] T & ⇧[0, 1] ⓛ{a2}W2.T2 ≡ T & a1 = true.
  62 #h #g #a1 #a2 #G #L #V1 #W2 #T1 #T2 * #X #l1 #l2 #Hl21 #Hl1 #H1 #H2
  63 lapply (da_inv_bind … Hl1) -Hl1 #Hl1
  64 elim (lsstas_inv_bind1 … H1) -H1 #U1 #HTU1 #H destruct
  65 elim (cprs_inv_abbr1 … H2) -H2 *
  66 [ #V2 #U2 #HV12 #HU12 #H destruct
  67 | /3 width=7 by ex4_3_intro, ex3_intro/
  68 ]
  69 qed-.
  70
  71 (* Advanced forward lemmas **************************************************)
  72
  73 lemma cpds_fwd_cpxs: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 •*➡*[h, g] T2 → ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2.
  74 #h #g #G #L #T1 #T2 * /3 width=5 by cpxs_trans, lsstas_cpxs, cprs_cpxs/
  75 qed-.