matita/matita/contribs/lambdadelta/basic_2/etc/ssta1/snv_preserve.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/fsb_aaa.ma".
  16 include "basic_2/dynamic/snv_da_lpr.ma".
  17 include "basic_2/dynamic/snv_lsstas.ma".
  18 include "basic_2/dynamic/snv_lsstas_lpr.ma".
  19 include "basic_2/dynamic/snv_lpr.ma".
  20
  21 (* STRATIFIED NATIVE VALIDITY FOR TERMS *************************************)
  22
  23 (* Main preservation properties *********************************************)
  24
  25 lemma snv_preserve: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ T ¡[h, g] →
  26                     ∧∧ IH_da_cpr_lpr h g G L T
  27                      & IH_snv_cpr_lpr h g G L T
  28                      & IH_snv_lsstas h g G L T
  29                      & IH_lsstas_cpr_lpr h g G L T.
  30 #h #g #G #L #T #HT elim (snv_fwd_aaa … HT) -HT
  31 #A #HT @(aaa_ind_fpbg h g … HT) -G -L -T -A
  32 #G #L #T #A #_ #IH -A @and4_intro
  33 [ letin aux ≝ da_cpr_lpr_aux | letin aux ≝ snv_cpr_lpr_aux
  34 | letin aux ≝ snv_lsstas_aux | letin aux ≝ lsstas_cpr_lpr_aux
  35 ]
  36 @(aux … G L T) // #G0 #L0 #T0 #H elim (IH … H) -IH -H //
  37 qed-.
  38
  39 theorem da_cpr_lpr: ∀h,g,G,L,T. IH_da_cpr_lpr h g G L T.
  40 #h #g #G #L #T #HT elim (snv_preserve … HT) /2 width=1 by/
  41 qed-.
  42
  43 theorem snv_cpr_lpr: ∀h,g,G,L,T. IH_snv_cpr_lpr h g G L T.
  44 #h #g #G #L #T #HT elim (snv_preserve … HT) /2 width=1 by/
  45 qed-.
  46
  47 theorem snv_lsstas: ∀h,g,G,L,T. IH_snv_lsstas h g G L T.
  48 #h #g #G #L #T #HT elim (snv_preserve … HT) /2 width=5 by/
  49 qed-.
  50
  51 theorem lsstas_cpr_lpr: ∀h,g,G,L,T. IH_lsstas_cpr_lpr h g G L T.
  52 #h #g #G #L #T #HT elim (snv_preserve … HT) /2 width=3 by/
  53 qed-.
  54
  55 (* Advanced preservation properties *****************************************)
  56
  57 lemma snv_cprs_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
  58                     ∀T2. ⦃G, L1⦄ ⊢ T1 ➡* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 → ⦃G, L2⦄ ⊢ T2 ¡[h, g].
  59 #h #g #G #L1 #T1 #HT1 #T2 #H
  60 @(cprs_ind … H) -T2 /3 width=5 by snv_cpr_lpr/
  61 qed-.
  62
  63 lemma da_cprs_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
  64                    ∀l. ⦃G, L1⦄ ⊢ T1 ▪[h, g] l →
  65                    ∀T2. ⦃G, L1⦄ ⊢ T1 ➡* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 → ⦃G, L2⦄ ⊢ T2 ▪[h, g] l.
  66 #h #g #G #L1 #T1 #HT1 #l #Hl #T2 #H
  67 @(cprs_ind … H) -T2 /3 width=6 by snv_cprs_lpr, da_cpr_lpr/
  68 qed-.
  69
  70 lemma da_cpcs: ∀h,g,G,L,T1. ⦃G, L⦄ ⊢ T1 ¡[h, g] →
  71                ∀T2. ⦃G, L⦄ ⊢ T2 ¡[h, g] →
  72                ∀l1. ⦃G, L⦄ ⊢ T1 ▪[h, g] l1 → ∀l2. ⦃G, L⦄ ⊢ T2 ▪[h, g] l2 →
  73                ⦃G, L⦄ ⊢ T1 ⬌* T2 → l1 = l2.
  74 #h #g #G #L #T1 #HT1 #T2 #HT2 #l1 #Hl1 #l2 #Hl2 #H
  75 elim (cpcs_inv_cprs … H) -H /3 width=12 by da_cprs_lpr, da_mono/
  76 qed-.
  77
  78 lemma ssta_cpr_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
  79                     ∀l. ⦃G, L1⦄ ⊢ T1 ▪[h, g] l+1 →
  80                     ∀U1. ⦃G, L1⦄ ⊢ T1 •[h, g] U1 →
  81                     ∀T2. ⦃G, L1⦄ ⊢ T1 ➡ T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 →
  82                     ∃∃U2. ⦃G, L2⦄ ⊢ T2 •[h, g] U2 & ⦃G, L2⦄ ⊢ U1 ⬌* U2.
  83 #h #g #G #L1 #T1 #HT1 #l #Hl #U1 #HTU1 #T2 #HT12 #L2 #HL12
  84 elim (lsstas_cpr_lpr  … 1 … Hl U1 … HT12 … HL12) -Hl -HT12 -HL12
  85 /3 width=3 by lsstas_inv_SO, ssta_lsstas, ex2_intro/
  86 qed-.
  87
  88 lemma lsstas_cprs_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
  89                        ∀l1,l2. l2 ≤ l1 → ⦃G, L1⦄ ⊢ T1 ▪[h, g] l1 →
  90                        ∀U1. ⦃G, L1⦄ ⊢ T1 •*[h, g, l2] U1 →
  91                        ∀T2. ⦃G, L1⦄ ⊢ T1 ➡* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 →
  92                        ∃∃U2. ⦃G, L2⦄ ⊢ T2 •*[h, g, l2] U2 & ⦃G, L2⦄ ⊢ U1 ⬌* U2.
  93 #h #g #G #L1 #T1 #HT1 #l1 #l2 #Hl21 #Hl1 #U1 #HTU1 #T2 #H
  94 @(cprs_ind … H) -T2 [ /2 width=9 by lsstas_cpr_lpr/ ]
  95 #T #T2 #HT1T #HTT2 #IHT1 #L2 #HL12
  96 elim (IHT1 L1) // -IHT1 #U #HTU #HU1
  97 elim (lsstas_cpr_lpr … Hl21 … HTU … HTT2 … HL12) -HTU -HTT2
  98 [2,3: /2 width=6 by snv_cprs_lpr, da_cprs_lpr/ ] -T1 -T -l1
  99 /4 width=5 by lpr_cpcs_conf, cpcs_trans, ex2_intro/
 100 qed-.
 101
 102 lemma lsstas_cpcs_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
 103                        ∀l,l1. l ≤ l1 → ⦃G, L1⦄ ⊢ T1 ▪[h, g] l1 → ∀U1. ⦃G, L1⦄ ⊢ T1 •*[h, g, l] U1 →
 104                        ∀T2. ⦃G, L1⦄ ⊢ T2 ¡[h, g] →
 105                        ∀l2. l ≤ l2 → ⦃G, L1⦄ ⊢ T2 ▪[h, g] l2 → ∀U2. ⦃G, L1⦄ ⊢ T2 •*[h, g, l] U2 →
 106                        ⦃G, L1⦄ ⊢ T1 ⬌* T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 → ⦃G, L2⦄ ⊢ U1 ⬌* U2.
 107 #h #g #G #L1 #T1 #HT1 #l #l1 #Hl1 #HTl1 #U1 #HTU1 #T2 #HT2 #l2 #Hl2 #HTl2 #U2 #HTU2 #H #L2 #HL12
 108 elim (cpcs_inv_cprs … H) -H #T #H1 #H2
 109 elim (lsstas_cprs_lpr … HT1 … Hl1 HTl1 … HTU1 … H1 … HL12) -T1 #W1 #H1 #HUW1
 110 elim (lsstas_cprs_lpr … HT2 … Hl2 HTl2 … HTU2 … H2 … HL12) -T2 #W2 #H2 #HUW2
 111 lapply (lsstas_mono … H1 … H2) -h -T -l #H destruct /2 width=3 by cpcs_canc_dx/
 112 qed-.
 113
 114 lemma snv_ssta: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ T ¡[h, g] →
 115                 ∀l. ⦃G, L⦄ ⊢ T ▪[h, g] l+1 →
 116                 ∀U. ⦃G, L⦄ ⊢ T •[h, g] U → ⦃G, L⦄ ⊢ U ¡[h, g].
 117 /3 width=7 by lsstas_inv_SO, ssta_lsstas, snv_lsstas/ qed-.
 118
 119 lemma lsstas_cpds: ∀h,g,G,L,T1. ⦃G, L⦄ ⊢ T1 ¡[h, g] →
 120                    ∀l1,l2. l2 ≤ l1 → ⦃G, L⦄ ⊢ T1 ▪[h, g] l1 →
 121                    ∀U1. ⦃G, L⦄ ⊢ T1 •*[h, g, l2] U1 → ∀T2. ⦃G, L⦄ ⊢ T1 •*➡*[h, g] T2 →
 122                    ∃∃U2,l. l ≤ l2 & ⦃G, L⦄ ⊢ T2 •*[h, g, l] U2 & ⦃G, L⦄ ⊢ U1 •*⬌*[h, g] U2.
 123 #h #g #G #L #T1 #HT1 #l1 #l2 #Hl21 #Hl1 #U1 #HTU1 #T2 * #T #l0 #l #Hl0 #H #HT1T #HTT2
 124 lapply (da_mono … H … Hl1) -H #H destruct
 125 lapply (lsstas_da_conf … HTU1 … Hl1) #Hl12
 126 elim (le_or_ge l2 l) #Hl2
 127 [ lapply (lsstas_conf_le … HTU1 … HT1T) -HT1T //
 128   /5 width=11 by cpds_cpes_dx, monotonic_le_minus_l, ex3_2_intro, ex4_3_intro/
 129 | lapply (lsstas_da_conf … HT1T … Hl1) #Hl1l
 130   lapply (lsstas_conf_le … HT1T … HTU1) -HTU1 // #HTU1
 131   elim (lsstas_cprs_lpr … Hl1l … HTU1 … HTT2 L) -Hl1l -HTU1 -HTT2
 132   /3 width=7 by snv_lsstas, cpcs_cpes, monotonic_le_minus_l, ex3_2_intro/
 133 ]
 134 qed-.
 135
 136 lemma cpds_cpr_lpr: ∀h,g,G,L1,T1. ⦃G, L1⦄ ⊢ T1 ¡[h, g] →
 137                     ∀U1. ⦃G, L1⦄ ⊢ T1 •*➡*[h, g] U1 →
 138                     ∀T2. ⦃G, L1⦄ ⊢ T1 ➡ T2 → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 →
 139                     ∃∃U2. ⦃G, L2⦄ ⊢ T2 •*➡*[h, g] U2 & ⦃G, L2⦄ ⊢ U1 ➡* U2.
 140 #h #g #G #L1 #T1 #HT1 #U1 * #W1 #l1 #l2 #Hl21 #Hl1 #HTW1 #HWU1 #T2 #HT12 #L2 #HL12
 141 elim (lsstas_cpr_lpr … HTW1 … HT12 … HL12) // #W2 #HTW2 #HW12
 142 lapply (da_cpr_lpr … Hl1 … HT12 … HL12) // -T1
 143 lapply (lpr_cprs_conf … HL12 … HWU1) -L1 #HWU1
 144 lapply (cpcs_canc_sn … HW12 HWU1) -W1 #H
 145 elim (cpcs_inv_cprs … H) -H /3 width=7 by ex4_3_intro, ex2_intro/
 146 qed-.