matita/matita/contribs/lambdadelta/basic_2/etc/sstas/sstas.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/ssta.ma".
  16
  17 (* ITERATED STRATIFIED STATIC TYPE ASSIGNMENTON TERMS ***********************)
  18
  19 inductive sstas (h:sh) (g:sd h) (L:lenv): relation term ≝
  20 | sstas_refl: ∀T,U. ⦃h, L⦄ ⊢ T •[g, 0] U → sstas h g L T T
  21 | sstas_step: ∀T,U1,U2,l. ⦃h, L⦄ ⊢ T •[g, l+1] U1 → sstas h g L U1 U2 →
  22               sstas h g L T U2.
  23
  24 interpretation "stratified unwind (term)"
  25    'StaticTypeStar h g L T U = (sstas h g L T U).
  26
  27 (* Basic eliminators ********************************************************)
  28
  29 fact sstas_ind_alt_aux: ∀h,g,L,U2. ∀R:predicate term.
  30                         (∀T. ⦃h, L⦄ ⊢ U2 •[g , 0] T → R U2) →
  31                         (∀T,U1,l. ⦃h, L⦄ ⊢ T •[g, l + 1] U1 →
  32                                   ⦃h, L⦄ ⊢ U1 •* [g] U2 → R U1 → R T
  33                         ) →
  34                         ∀T,U. ⦃h, L⦄ ⊢ T •*[g] U → U = U2 → R T.
  35 #h #g #L #U2 #R #H1 #H2 #T #U #H elim H -H -T -U /2 width=2/ /3 width=5/
  36 qed-.
  37
  38 lemma sstas_ind_alt: ∀h,g,L,U2. ∀R:predicate term.
  39                      (∀T. ⦃h, L⦄ ⊢ U2 •[g , 0] T → R U2) →
  40                      (∀T,U1,l. ⦃h, L⦄ ⊢ T •[g, l + 1] U1 →
  41                                ⦃h, L⦄ ⊢ U1 •* [g] U2 → R U1 → R T
  42                      ) →
  43                      ∀T. ⦃h, L⦄ ⊢ T •*[g] U2 → R T.
  44 /3 width=9 by sstas_ind_alt_aux/ qed-.
  45
  46 (* Basic inversion lemmas ***************************************************)
  47
  48 fact sstas_inv_sort1_aux: ∀h,g,L,T,U. ⦃h, L⦄ ⊢ T •*[g] U → ∀k. T = ⋆k →
  49                           ∀l. deg h g k l → U = ⋆((next h)^l k).
  50 #h #g #L #T #U #H @(sstas_ind_alt … H) -T
  51 [ #U0 #HU0 #k #H #l #Hkl destruct
  52   elim (ssta_inv_sort1 … HU0) -L #HkO #_ -U0
  53   >(deg_mono … Hkl HkO) -g -l //
  54 | #T0 #U0 #l0 #HTU0 #_ #IHU0 #k #H #l #Hkl destruct
  55   elim (ssta_inv_sort1 … HTU0) -L #HkS #H destruct
  56   lapply (deg_mono … Hkl HkS) -Hkl #H destruct
  57   >(IHU0 (next h k) ? l0) -IHU0 // /2 width=1/ >iter_SO >iter_n_Sm //
  58 ]
  59 qed.
  60
  61 lemma sstas_inv_sort1: ∀h,g,L,U,k. ⦃h, L⦄ ⊢ ⋆k •*[g] U → ∀l. deg h g k l →
  62                        U = ⋆((next h)^l k).
  63 /2 width=6/ qed-.
  64
  65 fact sstas_inv_bind1_aux: ∀h,g,L,T,U. ⦃h, L⦄ ⊢ T •*[g] U →
  66                           ∀J,X,Y. T = ⓑ{J}Y.X →
  67                           ∃∃Z. ⦃h, L.ⓑ{J}Y⦄ ⊢ X •*[g] Z & U = ⓑ{J}Y.Z.
  68 #h #g #L #T #U #H @(sstas_ind_alt … H) -T
  69 [ #U0 #HU0 #J #X #Y #H destruct
  70   elim (ssta_inv_bind1 … HU0) -HU0 #X0 #HX0 #H destruct /3 width=3/
  71 | #T0 #U0 #l #HTU0 #_ #IHU0 #J #X #Y #H destruct
  72   elim (ssta_inv_bind1 … HTU0) -HTU0 #X0 #HX0 #H destruct
  73   elim (IHU0 J X0 Y ?) -IHU0 // #X1 #HX01 #H destruct /3 width=4/
  74 ]
  75 qed.
  76
  77 lemma sstas_inv_bind1: ∀h,g,J,L,Y,X,U. ⦃h, L⦄ ⊢ ⓑ{J}Y.X •*[g] U →
  78                        ∃∃Z. ⦃h, L.ⓑ{J}Y⦄ ⊢ X •*[g] Z & U = ⓑ{J}Y.Z.
  79 /2 width=3/ qed-.
  80
  81 fact sstas_inv_appl1_aux: ∀h,g,L,T,U. ⦃h, L⦄ ⊢ T •*[g] U → ∀X,Y. T = ⓐY.X →
  82                           ∃∃Z. ⦃h, L⦄ ⊢ X •*[g] Z & U = ⓐY.Z.
  83 #h #g #L #T #U #H @(sstas_ind_alt … H) -T
  84 [ #U0 #HU0 #X #Y #H destruct
  85   elim (ssta_inv_appl1 … HU0) -HU0 #X0 #HX0 #H destruct /3 width=3/
  86 | #T0 #U0 #l #HTU0 #_ #IHU0 #X #Y #H destruct
  87   elim (ssta_inv_appl1 … HTU0) -HTU0 #X0 #HX0 #H destruct
  88   elim (IHU0 X0 Y ?) -IHU0 // #X1 #HX01 #H destruct /3 width=4/
  89 ]
  90 qed.
  91
  92 lemma sstas_inv_appl1: ∀h,g,L,Y,X,U. ⦃h, L⦄ ⊢ ⓐY.X •*[g] U →
  93                        ∃∃Z. ⦃h, L⦄ ⊢ X •*[g] Z & U = ⓐY.Z.
  94 /2 width=3/ qed-.
  95
  96 (* Basic forward lemmas *****************************************************)
  97
  98 lemma sstas_fwd_correct: ∀h,g,L,T,U. ⦃h, L⦄ ⊢ T •*[g] U →
  99                          ∃∃W. ⦃h, L⦄ ⊢ U •[g, 0] W & ⦃h, L⦄ ⊢ U •*[g] U.
 100 #h #g #L #T #U #H @(sstas_ind_alt … H) -T /2 width=1/ /3 width=2/
 101 qed-.
 102
 103 (* Basic_1: removed theorems 7:
 104             sty1_bind sty1_abbr sty1_appl sty1_cast2
 105             sty1_lift sty1_correct sty1_trans
 106 *)