matita/matita/contribs/lambdadelta/basic_2/etc/sstas/sstas.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 notation "hvbox( ⦃ h , break L ⦄ ⊢ break term 46 T1 •* break [ g ] break term 46 T2 )"
  16    non associative with precedence 45
  17    for @{ 'StaticTypeStar $h $g $L $T1 $T2 }.
  18
  19 include "basic_2/static/ssta.ma".
  20
  21 (* ITERATED STRATIFIED STATIC TYPE ASSIGNMENTON TERMS ***********************)
  22
  23 inductive sstas (h:sh) (g:sd h) (L:lenv): relation term ≝
  24 | sstas_refl: ∀T,U. ⦃h, L⦄ ⊢ T •[g, 0] U → sstas h g L T T
  25 | sstas_step: ∀T,U1,U2,l. ⦃h, L⦄ ⊢ T •[g, l+1] U1 → sstas h g L U1 U2 →
  26               sstas h g L T U2.
  27
  28 interpretation "stratified unwind (term)"
  29    'StaticTypeStar h g L T U = (sstas h g L T U).
  30
  31 (* Basic eliminators ********************************************************)
  32
  33 fact sstas_ind_alt_aux: ∀h,g,L,U2. ∀R:predicate term.
  34                         (∀T. ⦃h, L⦄ ⊢ U2 •[g , 0] T → R U2) →
  35                         (∀T,U1,l. ⦃h, L⦄ ⊢ T •[g, l + 1] U1 →
  36                                   ⦃h, L⦄ ⊢ U1 •* [g] U2 → R U1 → R T
  37                         ) →
  38                         ∀T,U. ⦃h, L⦄ ⊢ T •*[g] U → U = U2 → R T.
  39 #h #g #L #U2 #R #H1 #H2 #T #U #H elim H -H -T -U /2 width=2/ /3 width=5/
  40 qed-.
  41
  42 lemma sstas_ind_alt: ∀h,g,L,U2. ∀R:predicate term.
  43                      (∀T. ⦃h, L⦄ ⊢ U2 •[g , 0] T → R U2) →
  44                      (∀T,U1,l. ⦃h, L⦄ ⊢ T •[g, l + 1] U1 →
  45                                ⦃h, L⦄ ⊢ U1 •* [g] U2 → R U1 → R T
  46                      ) →
  47                      ∀T. ⦃h, L⦄ ⊢ T •*[g] U2 → R T.
  48 /3 width=9 by sstas_ind_alt_aux/ qed-.
  49
  50 (* Basic inversion lemmas ***************************************************)
  51
  52 fact sstas_inv_sort1_aux: ∀h,g,L,T,U. ⦃h, L⦄ ⊢ T •*[g] U → ∀k. T = ⋆k →
  53                           ∀l. deg h g k l → U = ⋆((next h)^l k).
  54 #h #g #L #T #U #H @(sstas_ind_alt … H) -T
  55 [ #U0 #HU0 #k #H #l #Hkl destruct
  56   elim (ssta_inv_sort1 … HU0) -L #HkO #_ -U0
  57   >(deg_mono … Hkl HkO) -g -l //
  58 | #T0 #U0 #l0 #HTU0 #_ #IHU0 #k #H #l #Hkl destruct
  59   elim (ssta_inv_sort1 … HTU0) -L #HkS #H destruct
  60   lapply (deg_mono … Hkl HkS) -Hkl #H destruct
  61   >(IHU0 (next h k) ? l0) -IHU0 // /2 width=1/ >iter_SO >iter_n_Sm //
  62 ]
  63 qed.
  64
  65 lemma sstas_inv_sort1: ∀h,g,L,U,k. ⦃h, L⦄ ⊢ ⋆k •*[g] U → ∀l. deg h g k l →
  66                        U = ⋆((next h)^l k).
  67 /2 width=6/ qed-.
  68
  69 fact sstas_inv_bind1_aux: ∀h,g,L,T,U. ⦃h, L⦄ ⊢ T •*[g] U →
  70                           ∀J,X,Y. T = ⓑ{J}Y.X →
  71                           ∃∃Z. ⦃h, L.ⓑ{J}Y⦄ ⊢ X •*[g] Z & U = ⓑ{J}Y.Z.
  72 #h #g #L #T #U #H @(sstas_ind_alt … H) -T
  73 [ #U0 #HU0 #J #X #Y #H destruct
  74   elim (ssta_inv_bind1 … HU0) -HU0 #X0 #HX0 #H destruct /3 width=3/
  75 | #T0 #U0 #l #HTU0 #_ #IHU0 #J #X #Y #H destruct
  76   elim (ssta_inv_bind1 … HTU0) -HTU0 #X0 #HX0 #H destruct
  77   elim (IHU0 J X0 Y ?) -IHU0 // #X1 #HX01 #H destruct /3 width=4/
  78 ]
  79 qed.
  80
  81 lemma sstas_inv_bind1: ∀h,g,J,L,Y,X,U. ⦃h, L⦄ ⊢ ⓑ{J}Y.X •*[g] U →
  82                        ∃∃Z. ⦃h, L.ⓑ{J}Y⦄ ⊢ X •*[g] Z & U = ⓑ{J}Y.Z.
  83 /2 width=3/ qed-.
  84
  85 fact sstas_inv_appl1_aux: ∀h,g,L,T,U. ⦃h, L⦄ ⊢ T •*[g] U → ∀X,Y. T = ⓐY.X →
  86                           ∃∃Z. ⦃h, L⦄ ⊢ X •*[g] Z & U = ⓐY.Z.
  87 #h #g #L #T #U #H @(sstas_ind_alt … H) -T
  88 [ #U0 #HU0 #X #Y #H destruct
  89   elim (ssta_inv_appl1 … HU0) -HU0 #X0 #HX0 #H destruct /3 width=3/
  90 | #T0 #U0 #l #HTU0 #_ #IHU0 #X #Y #H destruct
  91   elim (ssta_inv_appl1 … HTU0) -HTU0 #X0 #HX0 #H destruct
  92   elim (IHU0 X0 Y ?) -IHU0 // #X1 #HX01 #H destruct /3 width=4/
  93 ]
  94 qed.
  95
  96 lemma sstas_inv_appl1: ∀h,g,L,Y,X,U. ⦃h, L⦄ ⊢ ⓐY.X •*[g] U →
  97                        ∃∃Z. ⦃h, L⦄ ⊢ X •*[g] Z & U = ⓐY.Z.
  98 /2 width=3/ qed-.
  99
 100 (* Basic forward lemmas *****************************************************)
 101
 102 lemma sstas_fwd_correct: ∀h,g,L,T,U. ⦃h, L⦄ ⊢ T •*[g] U →
 103                          ∃∃W. ⦃h, L⦄ ⊢ U •[g, 0] W & ⦃h, L⦄ ⊢ U •*[g] U.
 104 #h #g #L #T #U #H @(sstas_ind_alt … H) -T /2 width=1/ /3 width=2/
 105 qed-.
 106
 107 (* Basic_1: removed theorems 7:
 108             sty1_bind sty1_abbr sty1_appl sty1_cast2
 109             sty1_lift sty1_correct sty1_trans
 110 *)