matita/matita/contribs/lambdadelta/basic_2/etc_2A1/cofrees/cofrees.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/cofreestar_4.ma".
  16 include "basic_2/relocation/lift_neg.ma".
  17 include "basic_2/substitution/cpys.ma".
  18
  19 (* CONTEXT-SENSITIVE EXCLUSION FROM FREE VARIABLES **************************)
  20
  21 definition cofrees: relation4 ynat nat lenv term ≝
  22                     λd,i,L,U1. ∀U2. ⦃⋆, L⦄ ⊢ U1 ▶*[d, ∞] U2 → ∃T2. ⇧[i, 1] T2 ≡ U2.
  23
  24 interpretation
  25    "context-sensitive exclusion from free variables (term)"
  26    'CoFreeStar L i d T = (cofrees d i L T).
  27
  28 (* Basic forward lemmas *****************************************************)
  29
  30 lemma cofrees_fwd_lift: ∀L,U,d,i. L ⊢ i ~ϵ 𝐅*[d]⦃U⦄ → ∃T. ⇧[i, 1] T ≡ U.
  31 /2 width=1 by/ qed-.
  32
  33 lemma cofrees_fwd_bind_sn: ∀a,I,L,W,U,i,d. L ⊢ i ~ϵ 𝐅*[d]⦃ⓑ{a,I}W.U⦄ →
  34                            L ⊢ i ~ϵ 𝐅*[d]⦃W⦄.
  35 #a #I #L #W1 #U #i #d #H #W2 #HW12 elim (H (ⓑ{a,I}W2.U)) /2 width=1 by cpys_bind/ -W1
  36 #X #H elim (lift_inv_bind2 … H) -H /2 width=2 by ex_intro/
  37 qed-.
  38
  39 lemma cofrees_fwd_bind_dx: ∀a,I,L,W,U,i,d. L ⊢ i ~ϵ 𝐅*[d]⦃ⓑ{a,I}W.U⦄ →
  40                            L.ⓑ{I}W ⊢ i+1 ~ϵ 𝐅*[⫯d]⦃U⦄.
  41 #a #I #L #W #U1 #i #d #H #U2 #HU12 elim (H (ⓑ{a,I}W.U2)) /2 width=1 by cpys_bind/ -U1
  42 #X #H elim (lift_inv_bind2 … H) -H /2 width=2 by ex_intro/
  43 qed-.
  44
  45 lemma cofrees_fwd_flat_sn: ∀I,L,W,U,i,d. L ⊢ i ~ϵ 𝐅*[d]⦃ⓕ{I}W.U⦄ →
  46                            L ⊢ i ~ϵ 𝐅*[d]⦃W⦄.
  47 #I #L #W1 #U #i #d #H #W2 #HW12 elim (H (ⓕ{I}W2.U)) /2 width=1 by cpys_flat/ -W1
  48 #X #H elim (lift_inv_flat2 … H) -H /2 width=2 by ex_intro/
  49 qed-.
  50
  51 lemma cofrees_fwd_flat_dx: ∀I,L,W,U,i,d. L ⊢ i ~ϵ 𝐅*[d]⦃ⓕ{I}W.U⦄ →
  52                            L ⊢ i ~ϵ 𝐅*[d]⦃U⦄.
  53 #I #L #W #U1 #i #d #H #U2 #HU12 elim (H (ⓕ{I}W.U2)) /2 width=1 by cpys_flat/ -U1
  54 #X #H elim (lift_inv_flat2 … H) -H /2 width=2 by ex_intro/
  55 qed-.
  56
  57 (* Basic inversion lemmas ***************************************************)
  58
  59 lemma cofrees_inv_gen: ∀L,U,U0,d,i. ⦃⋆, L⦄ ⊢ U ▶*[d, ∞] U0 → (∀T. ⇧[i, 1] T ≡ U0 → ⊥) →
  60                        L ⊢ i ~ϵ 𝐅*[d]⦃U⦄ → ⊥.
  61 #L #U #U0 #d #i #HU0 #HnU0 #HU elim (HU … HU0) -L -U -d /2 width=2 by/
  62 qed-.
  63
  64 lemma cofrees_inv_lref_eq: ∀L,d,i. L ⊢ i ~ϵ 𝐅*[d]⦃#i⦄ → ⊥.
  65 #L #d #i #H elim (H (#i)) -H //
  66 #X #H elim (lift_inv_lref2_be … H) -H //
  67 qed-.
  68
  69 lemma cofrees_inv_bind: ∀a,I,L,W,U,i,d. L ⊢ i ~ϵ 𝐅*[d]⦃ⓑ{a,I}W.U⦄ →
  70                         L ⊢ i ~ϵ 𝐅*[d]⦃W⦄ ∧ L.ⓑ{I}W ⊢ i+1 ~ϵ 𝐅*[⫯d]⦃U⦄.
  71 /3 width=8 by cofrees_fwd_bind_sn, cofrees_fwd_bind_dx, conj/ qed-.
  72
  73 lemma cofrees_inv_flat: ∀I,L,W,U,i,d. L ⊢ i ~ϵ 𝐅*[d]⦃ⓕ{I}W.U⦄ →
  74                         L ⊢ i ~ϵ 𝐅*[d]⦃W⦄ ∧ L ⊢ i ~ϵ 𝐅*[d]⦃U⦄.
  75 /3 width=7 by cofrees_fwd_flat_sn, cofrees_fwd_flat_dx, conj/ qed-.
  76
  77 (* Basic Properties *********************************************************)
  78
  79 lemma cofrees_lsuby_conf: ∀L1,U,d,i. L1 ⊢ i ~ϵ 𝐅*[d]⦃U⦄ →
  80                           ∀L2. L1 ⊆[d, ∞] L2 → L2 ⊢ i ~ϵ 𝐅*[d]⦃U⦄.
  81 /3 width=3 by lsuby_cpys_trans/ qed-.
  82
  83 lemma cofrees_sort: ∀L,d,i,k. L ⊢ i ~ϵ 𝐅*[d]⦃⋆k⦄.
  84 #L #d #i #k #X #H >(cpys_inv_sort1 … H) -X /2 width=2 by ex_intro/
  85 qed.
  86
  87 lemma cofrees_gref: ∀L,d,i,p. L ⊢ i ~ϵ 𝐅*[d]⦃§p⦄.
  88 #L #d #i #p #X #H >(cpys_inv_gref1 … H) -X /2 width=2 by ex_intro/
  89 qed.
  90
  91 lemma cofrees_bind: ∀L,V,d,i. L ⊢ i ~ϵ 𝐅*[d] ⦃V⦄ →
  92                     ∀I,T. L.ⓑ{I}V ⊢ i+1 ~ϵ 𝐅*[⫯d]⦃T⦄ →
  93                     ∀a. L ⊢ i ~ϵ 𝐅*[d]⦃ⓑ{a,I}V.T⦄.
  94 #L #W1 #d #i #HW1 #I #U1 #HU1 #a #X #H elim (cpys_inv_bind1 … H) -H
  95 #W2 #U2 #HW12 #HU12 #H destruct
  96 elim (HW1 … HW12) elim (HU1 … HU12) -W1 -U1 /3 width=2 by lift_bind, ex_intro/
  97 qed.
  98
  99 lemma cofrees_flat: ∀L,V,d,i. L ⊢ i ~ϵ 𝐅*[d]⦃V⦄ → ∀T. L ⊢ i ~ϵ 𝐅*[d]⦃T⦄ →
 100                     ∀I. L ⊢ i ~ϵ 𝐅*[d]⦃ⓕ{I}V.T⦄.
 101 #L #W1 #d #i #HW1 #U1 #HU1 #I #X #H elim (cpys_inv_flat1 … H) -H
 102 #W2 #U2 #HW12 #HU12 #H destruct
 103 elim (HW1 … HW12) elim (HU1 … HU12) -W1 -U1 /3 width=2 by lift_flat, ex_intro/
 104 qed.
 105
 106 lemma cofrees_cpy_trans: ∀L,U1,U2,d. ⦃⋆, L⦄ ⊢ U1 ▶[d, ∞] U2 →
 107                          ∀i. L ⊢ i ~ϵ 𝐅*[d]⦃U1⦄ → L ⊢ i ~ϵ 𝐅*[d]⦃U2⦄.
 108 /3 width=3 by cpys_strap2/ qed-.
 109
 110 axiom cofrees_dec: ∀L,T,d,i. Decidable (L ⊢ i ~ϵ 𝐅*[d]⦃T⦄).
 111
 112 (* Basic negated properties *************************************************)
 113
 114 lemma frees_cpy_div: ∀L,U1,U2,d. ⦃⋆, L⦄ ⊢ U1 ▶[d, ∞] U2 →
 115                      ∀i. (L ⊢ i ~ϵ 𝐅*[d]⦃U2⦄ → ⊥) → (L ⊢ i ~ϵ 𝐅*[d]⦃U1⦄ → ⊥).
 116 /3 width=7 by cofrees_cpy_trans/ qed-.
 117
 118 (* Basic negated inversion lemmas *******************************************)
 119
 120 lemma frees_inv_bind: ∀a,I,L,V,T,d,i. (L ⊢ i ~ϵ 𝐅*[d]⦃ⓑ{a,I}V.T⦄ → ⊥) →
 121                       (L ⊢ i ~ϵ 𝐅*[d]⦃V⦄ → ⊥) ∨ (L.ⓑ{I}V ⊢ i+1 ~ϵ 𝐅*[⫯d]⦃T⦄ → ⊥).
 122 #a #I #L #W #U #d #i #H elim (cofrees_dec L W d i)
 123 /4 width=9 by cofrees_bind, or_intror, or_introl/
 124 qed-.
 125
 126 lemma frees_inv_flat: ∀I,L,V,T,d,i. (L ⊢ i ~ϵ 𝐅*[d]⦃ⓕ{I}V.T⦄ → ⊥) →
 127                       (L ⊢ i ~ϵ 𝐅*[d]⦃V⦄ → ⊥) ∨ (L ⊢ i ~ϵ 𝐅*[d]⦃T⦄ → ⊥).
 128 #I #L #W #U #d #H elim (cofrees_dec L W d)
 129 /4 width=8 by cofrees_flat, or_intror, or_introl/
 130 qed-.