matita/matita/contribs/lambdadelta/basic_2/etc_2A1/cpr/ltpss_sn.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 notation "hvbox( T1 break ⊢ ▶ * [ term 46 d , break term 46 e ] break term 46 T2 )"
  16    non associative with precedence 45
  17    for @{ 'PSubstStarSn $T1 $d $e $T2 }.
  18
  19 include "basic_2/unfold/tpss.ma".
  20
  21 (* SN PARALLEL UNFOLD ON LOCAL ENVIRONMENTS *********************************)
  22
  23 inductive ltpss_sn: nat → nat → relation lenv ≝
  24 | ltpss_sn_atom : ∀d,e. ltpss_sn d e (⋆) (⋆)
  25 | ltpss_sn_pair : ∀L,I,V. ltpss_sn 0 0 (L. ⓑ{I} V) (L. ⓑ{I} V)
  26 | ltpss_sn_tpss2: ∀L1,L2,I,V1,V2,e.
  27                   ltpss_sn 0 e L1 L2 → L1 ⊢ V1 ▶* [0, e] V2 →
  28                   ltpss_sn 0 (e + 1) (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  29 | ltpss_sn_tpss1: ∀L1,L2,I,V1,V2,d,e.
  30                   ltpss_sn d e L1 L2 → L1 ⊢ V1 ▶* [d, e] V2 →
  31                   ltpss_sn (d + 1) e (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  32 .
  33
  34 interpretation "parallel unfold (local environment, sn variant)"
  35    'PSubstStarSn L1 d e L2 = (ltpss_sn d e L1 L2).
  36
  37 (* Basic inversion lemmas ***************************************************)
  38
  39 fact ltpss_sn_inv_refl_O2_aux: ∀d,e,L1,L2. L1 ⊢ ▶* [d, e] L2 → e = 0 → L1 = L2.
  40 #d #e #L1 #L2 #H elim H -d -e -L1 -L2 //
  41 [ #L1 #L2 #I #V1 #V2 #e #_ #_ #_ >commutative_plus normalize #H destruct
  42 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV12 #IHL12 #He destruct
  43   >(IHL12 ?) -IHL12 // >(tpss_inv_refl_O2 … HV12) //
  44 ]
  45 qed.
  46
  47 lemma ltpss_sn_inv_refl_O2: ∀d,L1,L2. L1 ⊢ ▶* [d, 0] L2 → L1 = L2.
  48 /2 width=4/ qed-.
  49
  50 fact ltpss_sn_inv_atom1_aux: ∀d,e,L1,L2.
  51                              L1 ⊢ ▶* [d, e] L2 → L1 = ⋆ → L2 = ⋆.
  52 #d #e #L1 #L2 * -d -e -L1 -L2
  53 [ //
  54 | #L #I #V #H destruct
  55 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
  56 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  57 ]
  58 qed.
  59
  60 lemma ltpss_sn_inv_atom1: ∀d,e,L2. ⋆ ⊢ ▶* [d, e] L2 → L2 = ⋆.
  61 /2 width=5/ qed-.
  62
  63 fact ltpss_sn_inv_tpss21_aux: ∀d,e,L1,L2. L1 ⊢ ▶* [d, e] L2 → d = 0 → 0 < e →
  64                               ∀K1,I,V1. L1 = K1. ⓑ{I} V1 →
  65                               ∃∃K2,V2. K1 ⊢ ▶* [0, e - 1] K2 &
  66                                        K1 ⊢ V1 ▶* [0, e - 1] V2 &
  67                                        L2 = K2. ⓑ{I} V2.
  68 #d #e #L1 #L2 * -d -e -L1 -L2
  69 [ #d #e #_ #_ #K1 #I #V1 #H destruct
  70 | #L1 #I #V #_ #H elim (lt_refl_false … H)
  71 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K1 #J #W1 #H destruct /2 width=5/
  72 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
  73 ]
  74 qed.
  75
  76 lemma ltpss_sn_inv_tpss21: ∀e,K1,I,V1,L2. K1. ⓑ{I} V1 ⊢ ▶* [0, e] L2 → 0 < e →
  77                            ∃∃K2,V2. K1 ⊢ ▶* [0, e - 1] K2 &
  78                                     K1 ⊢ V1 ▶* [0, e - 1] V2 &
  79                                     L2 = K2. ⓑ{I} V2.
  80 /2 width=5/ qed-.
  81
  82 fact ltpss_sn_inv_tpss11_aux: ∀d,e,L1,L2. L1 ⊢ ▶* [d, e] L2 → 0 < d →
  83                               ∀I,K1,V1. L1 = K1. ⓑ{I} V1 →
  84                               ∃∃K2,V2. K1 ⊢ ▶* [d - 1, e] K2 &
  85                                        K1 ⊢ V1 ▶* [d - 1, e] V2 &
  86                                        L2 = K2. ⓑ{I} V2.
  87 #d #e #L1 #L2 * -d -e -L1 -L2
  88 [ #d #e #_ #I #K1 #V1 #H destruct
  89 | #L #I #V #H elim (lt_refl_false … H)
  90 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
  91 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K1 #W1 #H destruct /2 width=5/
  92 ]
  93 qed.
  94
  95 lemma ltpss_sn_inv_tpss11: ∀d,e,I,K1,V1,L2. K1. ⓑ{I} V1 ⊢ ▶* [d, e] L2 → 0 < d →
  96                            ∃∃K2,V2. K1 ⊢ ▶* [d - 1, e] K2 &
  97                                     K1 ⊢ V1 ▶* [d - 1, e] V2 &
  98                                     L2 = K2. ⓑ{I} V2.
  99 /2 width=3/ qed-.
 100
 101 fact ltpss_sn_inv_atom2_aux: ∀d,e,L1,L2.
 102                              L1 ⊢ ▶* [d, e] L2 → L2 = ⋆ → L1 = ⋆.
 103 #d #e #L1 #L2 * -d -e -L1 -L2
 104 [ //
 105 | #L #I #V #H destruct
 106 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
 107 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
 108 ]
 109 qed.
 110
 111 lemma ltpss_sn_inv_atom2: ∀d,e,L1. L1 ⊢ ▶* [d, e] ⋆ → L1 = ⋆.
 112 /2 width=5/ qed-.
 113
 114 fact ltpss_sn_inv_tpss22_aux: ∀d,e,L1,L2. L1 ⊢ ▶* [d, e] L2 → d = 0 → 0 < e →
 115                               ∀K2,I,V2. L2 = K2. ⓑ{I} V2 →
 116                               ∃∃K1,V1. K1 ⊢ ▶* [0, e - 1] K2 &
 117                                        K1 ⊢ V1 ▶* [0, e - 1] V2 &
 118                                        L1 = K1. ⓑ{I} V1.
 119 #d #e #L1 #L2 * -d -e -L1 -L2
 120 [ #d #e #_ #_ #K1 #I #V1 #H destruct
 121 | #L1 #I #V #_ #H elim (lt_refl_false … H)
 122 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K2 #J #W2 #H destruct /2 width=5/
 123 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
 124 ]
 125 qed.
 126
 127 lemma ltpss_sn_inv_tpss22: ∀e,L1,K2,I,V2. L1 ⊢ ▶* [0, e] K2. ⓑ{I} V2 → 0 < e →
 128                            ∃∃K1,V1. K1 ⊢ ▶* [0, e - 1] K2 &
 129                                     K1 ⊢ V1 ▶* [0, e - 1] V2 &
 130                                     L1 = K1. ⓑ{I} V1.
 131 /2 width=5/ qed-.
 132
 133 fact ltpss_sn_inv_tpss12_aux: ∀d,e,L1,L2. L1 ⊢ ▶* [d, e] L2 → 0 < d →
 134                               ∀I,K2,V2. L2 = K2. ⓑ{I} V2 →
 135                               ∃∃K1,V1. K1 ⊢ ▶* [d - 1, e] K2 &
 136                                        K1 ⊢ V1 ▶* [d - 1, e] V2 &
 137                                        L1 = K1. ⓑ{I} V1.
 138 #d #e #L1 #L2 * -d -e -L1 -L2
 139 [ #d #e #_ #I #K2 #V2 #H destruct
 140 | #L #I #V #H elim (lt_refl_false … H)
 141 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
 142 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K2 #W2 #H destruct /2 width=5/
 143 ]
 144 qed.
 145
 146 lemma ltpss_sn_inv_tpss12: ∀L1,K2,I,V2,d,e. L1 ⊢ ▶* [d, e] K2. ⓑ{I} V2 → 0 < d →
 147                            ∃∃K1,V1. K1 ⊢ ▶* [d - 1, e] K2 &
 148                                     K1 ⊢ V1 ▶* [d - 1, e] V2 &
 149                                     L1 = K1. ⓑ{I} V1.
 150 /2 width=3/ qed-.
 151
 152 (* Basic properties *********************************************************)
 153
 154 lemma ltpss_sn_tps2: ∀L1,L2,I,V1,V2,e.
 155                      L1 ⊢ ▶* [0, e] L2 → L1 ⊢ V1 ▶ [0, e] V2 →
 156                      L1. ⓑ{I} V1 ⊢ ▶* [0, e + 1] L2. ⓑ{I} V2.
 157 /3 width=1/ qed.
 158
 159 lemma ltpss_sn_tps1: ∀L1,L2,I,V1,V2,d,e.
 160                      L1 ⊢ ▶* [d, e] L2 → L1 ⊢ V1 ▶ [d, e] V2 →
 161                      L1. ⓑ{I} V1 ⊢ ▶* [d + 1, e] L2. ⓑ{I} V2.
 162 /3 width=1/ qed.
 163
 164 lemma ltpss_sn_tpss2_lt: ∀L1,L2,I,V1,V2,e.
 165                          L1 ⊢ ▶* [0, e - 1] L2 → L1 ⊢ V1 ▶* [0, e - 1] V2 →
 166                          0 < e → L1. ⓑ{I} V1 ⊢ ▶* [0, e] L2. ⓑ{I} V2.
 167 #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #He
 168 >(plus_minus_m_m e 1) /2 width=1/
 169 qed.
 170
 171 lemma ltpss_sn_tpss1_lt: ∀L1,L2,I,V1,V2,d,e.
 172                          L1 ⊢ ▶* [d - 1, e] L2 → L1 ⊢ V1 ▶* [d - 1, e] V2 →
 173                          0 < d → L1. ⓑ{I} V1 ⊢ ▶* [d, e] L2. ⓑ{I} V2.
 174 #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #Hd
 175 >(plus_minus_m_m d 1) /2 width=1/
 176 qed.
 177
 178 lemma ltpss_sn_tps2_lt: ∀L1,L2,I,V1,V2,e.
 179                         L1 ⊢ ▶* [0, e - 1] L2 → L1 ⊢ V1 ▶ [0, e - 1] V2 →
 180                         0 < e → L1. ⓑ{I} V1 ⊢ ▶* [0, e] L2. ⓑ{I} V2.
 181 /3 width=1/ qed.
 182
 183 lemma ltpss_sn_tps1_lt: ∀L1,L2,I,V1,V2,d,e.
 184                         L1 ⊢ ▶* [d - 1, e] L2 → L1 ⊢ V1 ▶ [d - 1, e] V2 →
 185                         0 < d → L1. ⓑ{I} V1 ⊢ ▶* [d, e] L2. ⓑ{I} V2.
 186 /3 width=1/ qed.
 187
 188 lemma ltpss_sn_refl: ∀L,d,e. L ⊢ ▶* [d, e] L.
 189 #L elim L -L //
 190 #L #I #V #IHL * /2 width=1/ * /2 width=1/
 191 qed.
 192
 193 lemma ltpss_sn_weak: ∀L1,L2,d1,e1. L1 ⊢ ▶* [d1, e1] L2 →
 194                      ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 → L1 ⊢ ▶* [d2, e2] L2.
 195 #L1 #L2 #d1 #e1 #H elim H -L1 -L2 -d1 -e1 //
 196 [ #L1 #L2 #I #V1 #V2 #e1 #_ #HV12 #IHL12 #d2 #e2 #Hd2 #Hde2
 197   lapply (le_n_O_to_eq … Hd2) #H destruct normalize in Hde2;
 198   lapply (lt_to_le_to_lt 0 … Hde2) // #He2
 199   lapply (le_plus_to_minus_r … Hde2) -Hde2 /3 width=5/
 200 | #L1 #L2 #I #V1 #V2 #d1 #e1 #_ #HV12 #IHL12 #d2 #e2 #Hd21 #Hde12
 201   >plus_plus_comm_23 in Hde12; #Hde12
 202   elim (le_to_or_lt_eq 0 d2 ?) // #H destruct
 203   [ lapply (le_plus_to_minus_r … Hde12) -Hde12 <plus_minus // #Hde12
 204     lapply (le_plus_to_minus … Hd21) -Hd21 #Hd21 /3 width=5/
 205   | -Hd21 normalize in Hde12;
 206     lapply (lt_to_le_to_lt 0 … Hde12) // #He2
 207     lapply (le_plus_to_minus_r … Hde12) -Hde12
 208     /3 width=5 by ltpss_sn_tpss2_lt, tpss_weak/ (**) (* /3 width=5/ used to work *)
 209   ]
 210 ]
 211 qed.
 212
 213 lemma ltpss_sn_weak_full: ∀L1,L2,d,e. L1 ⊢ ▶* [d, e] L2 → L1 ⊢ ▶* [0, |L1|] L2.
 214 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 215 // /3 width=2/ /3 width=3/
 216 qed.
 217
 218 fact ltpss_sn_append_le_aux: ∀K1,K2,d,x. K1 ⊢ ▶* [d, x] K2 → x = |K1| - d →
 219                              ∀L1,L2,e. L1 ⊢ ▶* [0, e] L2 → d ≤ |K1| →
 220                              L1 @@ K1 ⊢ ▶* [d, x + e] L2 @@ K2.
 221 #K1 #K2 #d #x #H elim H -K1 -K2 -d -x
 222 [ #d #x #H1 #L1 #L2 #e #HL12 #H2 destruct
 223   lapply (le_n_O_to_eq … H2) -H2 #H destruct //
 224 | #K #I #V <minus_n_O normalize <plus_n_Sm #H destruct
 225 | #K1 #K2 #I #V1 #V2 #x #_ #HV12 <minus_n_O #IHK12 <minus_n_O #H #L1 #L2 #e #HL12 #_
 226   lapply (injective_plus_l … H) -H #H destruct >plus_plus_comm_23
 227   /4 width=5 by ltpss_sn_tpss2, tpss_append, tpss_weak, monotonic_le_plus_r/ (**) (* too slow without trace *)
 228 | #K1 #K2 #I #V1 #V2 #d #x #_ #HV12 #IHK12 normalize <minus_le_minus_minus_comm // <minus_plus_m_m #H1 #L1 #L2 #e #HL12 #H2 destruct
 229   lapply (le_plus_to_le_r … H2) -H2 #Hd
 230   /4 width=5 by ltpss_sn_tpss1, tpss_append, tpss_weak, monotonic_le_plus_r/ (**) (* too slow without trace *)
 231 ]
 232 qed-.
 233
 234 lemma ltpss_sn_append_le: ∀K1,K2,d. K1 ⊢ ▶* [d, |K1| - d] K2 →
 235                           ∀L1,L2,e. L1 ⊢ ▶* [0, e] L2 → d ≤ |K1| →
 236                           L1 @@ K1 ⊢ ▶* [d, |K1| - d + e] L2 @@ K2.
 237 /2 width=1 by ltpss_sn_append_le_aux/ qed.
 238
 239 lemma ltpss_sn_append_ge: ∀K1,K2,d,e. K1 ⊢ ▶* [d, e] K2 →
 240                           ∀L1,L2. L1 ⊢ ▶* [d - |K1|, e] L2 → |K1| ≤ d →
 241                           L1 @@ K1 ⊢ ▶* [d, e] L2 @@ K2.
 242 #K1 #K2 #d #e #H elim H -K1 -K2 -d -e
 243 [ #d #e #L1 #L2 <minus_n_O //
 244 | #K #I #V #L1 #L2 #_ #H
 245   lapply (le_n_O_to_eq … H) -H normalize <plus_n_Sm #H destruct
 246 | #K1 #K2 #I #V1 #V2 #e #_ #_ #_ #L1 #L2 #_ #H
 247   lapply (le_n_O_to_eq … H) -H normalize <plus_n_Sm #H destruct
 248 | #K1 #K2 #I #V1 #V2 #d #e #_ #HV12 #IHK12 #L1 #L2
 249   normalize <minus_le_minus_minus_comm // <minus_plus_m_m #HL12 #H
 250   lapply (le_plus_to_le_r … H) -H /3 width=1/
 251 ]
 252 qed.
 253
 254 (* Basic forward lemmas *****************************************************)
 255
 256 lemma ltpss_sn_fwd_length: ∀L1,L2,d,e. L1 ⊢ ▶* [d, e] L2 → |L1| = |L2|.
 257 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 258 normalize //
 259 qed-.