matita/matita/contribs/lambdadelta/basic_2/etc_2A1/cpr/tpss.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 notation "hvbox( L ⊢ break term 46 T1 break ▶ * [ term 46 d , break term 46 e ] break term 46 T2 )"
  16    non associative with precedence 45
  17    for @{ 'PSubstStar $L $T1 $d $e $T2 }.
  18
  19 include "basic_2/substitution/tps.ma".
  20
  21 (* PARTIAL UNFOLD ON TERMS **************************************************)
  22
  23 definition tpss: nat → nat → lenv → relation term ≝
  24                  λd,e,L. TC … (tps d e L).
  25
  26 interpretation "partial unfold (term)"
  27    'PSubstStar L T1 d e T2 = (tpss d e L T1 T2).
  28
  29 (* Basic eliminators ********************************************************)
  30
  31 lemma tpss_ind: ∀d,e,L,T1. ∀R:predicate term. R T1 →
  32                 (∀T,T2. L ⊢ T1 ▶* [d, e] T → L ⊢ T ▶ [d, e] T2 → R T → R T2) →
  33                 ∀T2. L ⊢ T1 ▶* [d, e] T2 → R T2.
  34 #d #e #L #T1 #R #HT1 #IHT1 #T2 #HT12
  35 @(TC_star_ind … HT1 IHT1 … HT12) //
  36 qed-.
  37
  38 lemma tpss_ind_dx: ∀d,e,L,T2. ∀R:predicate term. R T2 →
  39                    (∀T1,T. L ⊢ T1 ▶ [d, e] T → L ⊢ T ▶* [d, e] T2 → R T → R T1) →
  40                    ∀T1. L ⊢ T1 ▶* [d, e] T2 → R T1.
  41 #d #e #L #T2 #R #HT2 #IHT2 #T1 #HT12
  42 @(TC_star_ind_dx … HT2 IHT2 … HT12) //
  43 qed-.
  44
  45 (* Basic properties *********************************************************)
  46
  47 lemma tps_tpss: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 → L ⊢ T1 ▶* [d, e] T2.
  48 /2 width=1/ qed.
  49
  50 lemma tpss_strap1: ∀L,T1,T,T2,d,e.
  51                    L ⊢ T1 ▶* [d, e] T → L ⊢ T ▶ [d, e] T2 → L ⊢ T1 ▶* [d, e] T2.
  52 /2 width=3/ qed.
  53
  54 lemma tpss_strap2: ∀L,T1,T,T2,d,e.
  55                    L ⊢ T1 ▶ [d, e] T → L ⊢ T ▶* [d, e] T2 → L ⊢ T1 ▶* [d, e] T2.
  56 /2 width=3/ qed.
  57
  58 lemma tpss_lsubr_trans: ∀L1,T1,T2,d,e. L1 ⊢ T1 ▶* [d, e] T2 →
  59                         ∀L2. L2 ⊑ [d, e] L1 → L2 ⊢ T1 ▶* [d, e] T2.
  60 /3 width=3/ qed.
  61
  62 lemma tpss_refl: ∀d,e,L,T. L ⊢ T ▶* [d, e] T.
  63 /2 width=1/ qed.
  64
  65 lemma tpss_bind: ∀L,V1,V2,d,e. L ⊢ V1 ▶* [d, e] V2 →
  66                  ∀a,I,T1,T2. L. ⓑ{I} V2 ⊢ T1 ▶* [d + 1, e] T2 →
  67                  L ⊢ ⓑ{a,I} V1. T1 ▶* [d, e] ⓑ{a,I} V2. T2.
  68 #L #V1 #V2 #d #e #HV12 elim HV12 -V2
  69 [ #V2 #HV12 #a #I #T1 #T2 #HT12 elim HT12 -T2
  70   [ /3 width=5/
  71   | #T #T2 #_ #HT2 #IHT @step /2 width=5/ (**) (* /3 width=5/ is too slow *)
  72   ]
  73 | #V #V2 #_ #HV12 #IHV #a #I #T1 #T2 #HT12
  74   lapply (tpss_lsubr_trans … HT12 (L. ⓑ{I} V) ?) -HT12 /2 width=1/ #HT12
  75   lapply (IHV a … HT12) -IHV -HT12 #HT12 @step /2 width=5/ (**) (* /3 width=5/ is too slow *)
  76 ]
  77 qed.
  78
  79 lemma tpss_flat: ∀L,I,V1,V2,T1,T2,d,e.
  80                  L ⊢ V1 ▶* [d, e] V2 → L ⊢ T1 ▶* [d, e] T2 →
  81                  L ⊢ ⓕ{I} V1. T1 ▶* [d, e] ⓕ{I} V2. T2.
  82 #L #I #V1 #V2 #T1 #T2 #d #e #HV12 elim HV12 -V2
  83 [ #V2 #HV12 #HT12 elim HT12 -T2
  84   [ /3 width=1/
  85   | #T #T2 #_ #HT2 #IHT @step /2 width=5/ (**) (* /3 width=5/ is too slow *)
  86   ]
  87 | #V #V2 #_ #HV12 #IHV #HT12
  88   lapply (IHV … HT12) -IHV -HT12 #HT12 @step /2 width=5/ (**) (* /3 width=5/ is too slow *)
  89 ]
  90 qed.
  91
  92 lemma tpss_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 ▶* [d1, e1] T2 →
  93                  ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  94                  L ⊢ T1 ▶* [d2, e2] T2.
  95 #L #T1 #T2 #d1 #e1 #H #d1 #d2 #Hd21 #Hde12 @(tpss_ind … H) -T2
  96 [ //
  97 | #T #T2 #_ #HT12 #IHT
  98   lapply (tps_weak … HT12 … Hd21 Hde12) -HT12 -Hd21 -Hde12 /2 width=3/
  99 ]
 100 qed.
 101
 102 lemma tpss_weak_top: ∀L,T1,T2,d,e.
 103                      L ⊢ T1 ▶* [d, e] T2 → L ⊢ T1 ▶* [d, |L| - d] T2.
 104 #L #T1 #T2 #d #e #H @(tpss_ind … H) -T2
 105 [ //
 106 | #T #T2 #_ #HT12 #IHT
 107   lapply (tps_weak_top … HT12) -HT12 /2 width=3/
 108 ]
 109 qed.
 110
 111 lemma tpss_weak_full: ∀L,T1,T2,d,e.
 112                       L ⊢ T1 ▶* [d, e] T2 → L ⊢ T1 ▶* [0, |L|] T2.
 113 #L #T1 #T2 #d #e #HT12
 114 lapply (tpss_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
 115 lapply (tpss_weak_top … HT12) //
 116 qed.
 117
 118 lemma tpss_append: ∀K,T1,T2,d,e. K ⊢ T1 ▶* [d, e] T2 →
 119                    ∀L. L @@ K ⊢ T1 ▶* [d, e] T2.
 120 #K #T1 #T2 #d #e #H @(tpss_ind … H) -T2 // /3 width=3/
 121 qed.
 122
 123 (* Basic inversion lemmas ***************************************************)
 124
 125 (* Note: this can be derived from tpss_inv_atom1 *)
 126 lemma tpss_inv_sort1: ∀L,T2,k,d,e. L ⊢ ⋆k ▶* [d, e] T2 → T2 = ⋆k.
 127 #L #T2 #k #d #e #H @(tpss_ind … H) -T2
 128 [ //
 129 | #T #T2 #_ #HT2 #IHT destruct
 130   >(tps_inv_sort1 … HT2) -HT2 //
 131 ]
 132 qed-.
 133
 134 (* Note: this can be derived from tpss_inv_atom1 *)
 135 lemma tpss_inv_gref1: ∀L,T2,p,d,e. L ⊢ §p ▶* [d, e] T2 → T2 = §p.
 136 #L #T2 #p #d #e #H @(tpss_ind … H) -T2
 137 [ //
 138 | #T #T2 #_ #HT2 #IHT destruct
 139   >(tps_inv_gref1 … HT2) -HT2 //
 140 ]
 141 qed-.
 142
 143 lemma tpss_inv_bind1: ∀d,e,L,a,I,V1,T1,U2. L ⊢ ⓑ{a,I} V1. T1 ▶* [d, e] U2 →
 144                       ∃∃V2,T2. L ⊢ V1 ▶* [d, e] V2 &
 145                                L. ⓑ{I} V2 ⊢ T1 ▶* [d + 1, e] T2 &
 146                                U2 = ⓑ{a,I} V2. T2.
 147 #d #e #L #a #I #V1 #T1 #U2 #H @(tpss_ind … H) -U2
 148 [ /2 width=5/
 149 | #U #U2 #_ #HU2 * #V #T #HV1 #HT1 #H destruct
 150   elim (tps_inv_bind1 … HU2) -HU2 #V2 #T2 #HV2 #HT2 #H
 151   lapply (tpss_lsubr_trans … HT1 (L. ⓑ{I} V2) ?) -HT1 /2 width=1/ /3 width=5/
 152 ]
 153 qed-.
 154
 155 lemma tpss_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ ⓕ{I} V1. T1 ▶* [d, e] U2 →
 156                       ∃∃V2,T2. L ⊢ V1 ▶* [d, e] V2 & L ⊢ T1 ▶* [d, e] T2 &
 157                                U2 =  ⓕ{I} V2. T2.
 158 #d #e #L #I #V1 #T1 #U2 #H @(tpss_ind … H) -U2
 159 [ /2 width=5/
 160 | #U #U2 #_ #HU2 * #V #T #HV1 #HT1 #H destruct
 161   elim (tps_inv_flat1 … HU2) -HU2 /3 width=5/
 162 ]
 163 qed-.
 164
 165 lemma tpss_inv_refl_O2: ∀L,T1,T2,d. L ⊢ T1 ▶* [d, 0] T2 → T1 = T2.
 166 #L #T1 #T2 #d #H @(tpss_ind … H) -T2
 167 [ //
 168 | #T #T2 #_ #HT2 #IHT <(tps_inv_refl_O2 … HT2) -HT2 //
 169 ]
 170 qed-.
 171
 172 (* Basic forward lemmas *****************************************************)
 173
 174 lemma tpss_fwd_tw: ∀L,T1,T2,d,e. L ⊢ T1 ▶* [d, e] T2 → ♯{T1} ≤ ♯{T2}.
 175 #L #T1 #T2 #d #e #H @(tpss_ind … H) -T2 //
 176 #T #T2 #_ #HT2 #IHT1
 177 lapply (tps_fwd_tw … HT2) -HT2 #HT2
 178 @(transitive_le … IHT1) //
 179 qed-.
 180
 181 lemma tpss_fwd_shift1: ∀L,L1,T1,T,d,e. L ⊢ L1 @@ T1 ▶*[d, e] T →
 182                        ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 183 #L #L1 #T1 #T #d #e #H @(tpss_ind … H) -T
 184 [ /2 width=4/
 185 | #T #X #_ #H0 * #L0 #T0 #HL10 #H destruct
 186   elim (tps_fwd_shift1 … H0) -H0 #L2 #T2 #HL02 #H destruct /2 width=4/
 187 ]
 188 qed-.