matita/matita/contribs/lambdadelta/basic_2/etc_2A1/delift/delift_tpss.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/tpss_tpss.ma".
  16 include "basic_2/unfold/delift.ma".
  17
  18 (* INVERSE BASIC TERM RELOCATION  *******************************************)
  19
  20 (* Properties on partial unfold on terms ************************************)
  21
  22 lemma delift_tpss_conf_le: ∀L,U1,U2,d,e. L ⊢ U1 ▶* [d, e] U2 →
  23                            ∀T1,dd,ee. L ⊢ ▼*[dd, ee] U1 ≡ T1 →
  24                            ∀K. ⇩[dd, ee] L ≡ K → d + e ≤ dd →
  25                            ∃∃T2. K ⊢ T1 ▶* [d, e] T2 & L ⊢ ▼*[dd, ee] U2 ≡ T2.
  26 #L #U1 #U2 #d #e #HU12 #T1 #dd #ee * #X1 #HUX1 #HTX1 #K #HLK #H1
  27 elim (tpss_conf_eq … HU12 … HUX1) -U1 #U1 #HU21 #HXU1
  28 elim (tpss_inv_lift1_le … HXU1 … HLK … HTX1 ?) -X1 -HLK // -H1 /3 width=5/
  29 qed.
  30
  31 lemma delift_tps_conf_le: ∀L,U1,U2,d,e. L ⊢ U1 ▶ [d, e] U2 →
  32                           ∀T1,dd,ee. L ⊢ ▼*[dd, ee] U1 ≡ T1 →
  33                           ∀K. ⇩[dd, ee] L ≡ K → d + e ≤ dd →
  34                           ∃∃T2. K ⊢ T1 ▶* [d, e] T2 & L ⊢ ▼*[dd, ee] U2 ≡ T2.
  35 /3 width=3/ qed.
  36
  37 lemma delift_tpss_conf_le_up: ∀L,U1,U2,d,e. L ⊢ U1 ▶* [d, e] U2 →
  38                               ∀T1,dd,ee. L ⊢ ▼*[dd, ee] U1 ≡ T1 →
  39                               ∀K. ⇩[dd, ee] L ≡ K →
  40                               d ≤ dd → dd ≤ d + e → d + e ≤ dd + ee →
  41                               ∃∃T2. K ⊢ T1 ▶* [d, dd - d] T2 &
  42                                     L ⊢ ▼*[dd, ee] U2 ≡ T2.
  43 #L #U1 #U2 #d #e #HU12 #T1 #dd #ee * #X1 #HUX1 #HTX1 #K #HLK #H1 #H2 #H3
  44 elim (tpss_conf_eq … HU12 … HUX1) -U1 #U1 #HU21 #HXU1
  45 elim (tpss_inv_lift1_le_up … HXU1 … HLK … HTX1 ? ? ?) -X1 -HLK // -H1 -H2 -H3 /3 width=5/
  46 qed.
  47
  48 lemma delift_tps_conf_le_up: ∀L,U1,U2,d,e. L ⊢ U1 ▶ [d, e] U2 →
  49                              ∀T1,dd,ee. L ⊢ ▼*[dd, ee] U1 ≡ T1 →
  50                              ∀K. ⇩[dd, ee] L ≡ K →
  51                              d ≤ dd → dd ≤ d + e → d + e ≤ dd + ee →
  52                              ∃∃T2. K ⊢ T1 ▶* [d, dd - d] T2 &
  53                                    L ⊢ ▼*[dd, ee] U2 ≡ T2.
  54 /3 width=6/ qed.
  55
  56 lemma delift_tpss_conf_be: ∀L,U1,U2,d,e. L ⊢ U1 ▶* [d, e] U2 →
  57                            ∀T1,dd,ee. L ⊢ ▼*[dd, ee] U1 ≡ T1 →
  58                            ∀K. ⇩[dd, ee] L ≡ K → d ≤ dd → dd + ee ≤ d + e →
  59                            ∃∃T2. K ⊢ T1 ▶* [d, e - ee] T2 &
  60                                  L ⊢ ▼*[dd, ee] U2 ≡ T2.
  61 #L #U1 #U2 #d #e #HU12 #T1 #dd #ee * #X1 #HUX1 #HTX1 #K #HLK #H1 #H2
  62 elim (tpss_conf_eq … HU12 … HUX1) -U1 #U1 #HU21 #HXU1
  63 elim (tpss_inv_lift1_be … HXU1 … HLK … HTX1 ? ?) -X1 -HLK // -H1 -H2 /3 width=5/
  64 qed.
  65
  66 lemma delift_tps_conf_be: ∀L,U1,U2,d,e. L ⊢ U1 ▶ [d, e] U2 →
  67                           ∀T1,dd,ee. L ⊢ ▼*[dd, ee] U1 ≡ T1 →
  68                           ∀K. ⇩[dd, ee] L ≡ K → d ≤ dd → dd + ee ≤ d + e →
  69                           ∃∃T2. K ⊢ T1 ▶* [d, e - ee] T2 &
  70                                 L ⊢ ▼*[dd, ee] U2 ≡ T2.
  71 /3 width=3/ qed.
  72
  73 lemma delift_tpss_conf_eq: ∀L,U1,U2,d,e. L ⊢ U1 ▶* [d, e] U2 →
  74                            ∀T. L ⊢ ▼*[d, e] U1 ≡ T → L ⊢ ▼*[d, e] U2 ≡ T.
  75 #L #U1 #U2 #d #e #HU12 #T * #X1 #HUX1 #HTX1
  76 elim (tpss_conf_eq … HU12 … HUX1) -U1 #U1 #HU21 #HXU1
  77 lapply (tpss_inv_lift1_eq … HXU1 … HTX1) -HXU1 #H destruct /2 width=3/
  78 qed.
  79
  80 lemma delift_tps_conf_eq: ∀L,U1,U2,d,e. L ⊢ U1 ▶ [d, e] U2 →
  81                           ∀T. L ⊢ ▼*[d, e] U1 ≡ T → L ⊢ ▼*[d, e] U2 ≡ T.
  82 /3 width=3/ qed.
  83
  84 lemma tpss_delift_trans_eq: ∀L,U1,U2,d,e. L ⊢ U1 ▶* [d, e] U2 →
  85                             ∀T. L ⊢ ▼*[d, e] U2 ≡ T → L ⊢ ▼*[d, e] U1 ≡ T.
  86 #L #U1 #U2 #d #e #HU12 #T * #X1 #HUX1 #HTX1
  87 lapply (tpss_trans_eq … HU12 … HUX1) -U2 /2 width=3/
  88 qed.
  89
  90 lemma tps_delift_trans_eq: ∀L,U1,U2,d,e. L ⊢ U1 ▶ [d, e] U2 →
  91                            ∀T. L ⊢ ▼*[d, e] U2 ≡ T → L ⊢ ▼*[d, e] U1 ≡ T.
  92 /3 width=3/ qed.