matita/matita/contribs/lambdadelta/basic_2/etc_2A1/llpr/llpr.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/lazypredsn_5.ma".
  16 include "basic_2/relocation/llpx_sn.ma".
  17 include "basic_2/reduction/cpr.ma".
  18
  19 (* LAZY SN PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS ************************)
  20
  21 definition llpr: genv → relation4 ynat term lenv lenv ≝ λG. llpx_sn (cpr G).
  22
  23 interpretation "lazy parallel reduction (local environment, sn variant)"
  24    'LazyPRedSn G L1 L2 T d = (llpr G d T L1 L2).
  25
  26 (* Basic inversion lemmas ***************************************************)
  27
  28 lemma llpr_inv_flat: ∀I,G,L1,L2,V,T,d. ⦃G, L1⦄ ⊢ ➡[ⓕ{I}V.T, d] L2 →
  29                      ⦃G, L1⦄ ⊢ ➡[V, d] L2 ∧ ⦃G, L1⦄ ⊢ ➡[T, d] L2.
  30 /2 width=2 by llpx_sn_inv_flat/ qed-.
  31
  32 (* Basic forward lemmas *****************************************************)
  33
  34 lemma llpr_fwd_length: ∀G,L1,L2,T,d. ⦃G, L1⦄ ⊢ ➡[T, d] L2 → |L1| = |L2|.
  35 /2 width=4 by llpx_sn_fwd_length/ qed-.
  36
  37 (* Basic properties *********************************************************)
  38
  39 lemma llpr_lref: ∀I,G,L1,L2,K1,K2,V1,V2,d,i. d ≤ yinj i →
  40                  ⇩[i] L1 ≡ K1.ⓑ{I}V1 → ⇩[i] L2 ≡ K2.ⓑ{I}V2 →
  41                  ⦃G, K1⦄ ⊢ ➡[V1, 0] K2 → ⦃G, K1⦄ ⊢ V1 ➡ V2 → ⦃G, L1⦄ ⊢ ➡[#i, d] L2.
  42 /2 width=9 by llpx_sn_lref/ qed.
  43
  44 (* Note: lemma 250 *)
  45 lemma llpr_refl: ∀G,T,d. reflexive … (llpr G d T).
  46 /2 width=1 by llpx_sn_refl/ qed.
  47
  48 (* Basic_1: removed theorems 5: wcpr0_gen_sort wcpr0_gen_head
  49                                 wcpr0_getl wcpr0_getl_back
  50                                 pr0_subst1_back
  51 *)