matita/matita/contribs/lambdadelta/basic_2/etc_2A1/llpx/llpx_aaa.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/aaa_lift.ma".
  16 include "basic_2/static/lsuba_aaa.ma".
  17 include "basic_2/reduction/llpx_ldrop.ma".
  18
  19 (* SN EXTENDED PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS ********************)
  20
  21 (* Properties on atomic arity assignment for terms **************************)
  22
  23 (* Note: lemma 500 *)
  24 lemma aaa_cpx_llpx_conf: ∀h,g,G,L1,T1,A. ⦃G, L1⦄ ⊢ T1 ⁝ A →
  25                          ∀T2. ⦃G, L1⦄ ⊢ T1 ➡[h, g] T2 →
  26                          ∀L2. ⦃G, L1⦄ ⊢ ➡[h, g, T1, 0] L2 → ⦃G, L2⦄ ⊢ T2 ⁝ A.
  27 #h #g #G #L1 #T1 #A #H elim H -G -L1 -T1 -A
  28 [ #g #L1 #k #X #H elim (cpx_inv_sort1 … H) -H // * //
  29 | #I #G #L1 #K1 #V1 #B #i #HLK1 #_ #IHV1 #X #H #L2 #HL12
  30   elim (cpx_inv_lref1 … H) -H
  31   [ #H destruct
  32     elim (llpx_inv_lref_ge_sn … HL12 … HLK1) -L1 /3 width=6 by aaa_lref/
  33   | * #J #Y #Z #V2 #H #HV12 #HV2
  34     lapply (ldrop_mono … H … HLK1) -H #H destruct
  35     elim (llpx_inv_lref_ge_sn … HL12 … HLK1) -L1 /3 width=8 by aaa_lift, ldrop_fwd_drop2/
  36   ]
  37 | #a #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  38   elim (llpx_inv_bind_O … HL12) -HL12 #HV1 #HT1
  39   elim (cpx_inv_abbr1 … H) -H *
  40   [ #V2 #T2 #HV12 #HT12 #H destruct /4 width=4 by llpx_bind_repl_O, aaa_abbr/
  41   | #T2 #HT12 #HT2 #H destruct -IHV1 /3 width=8 by aaa_inv_lift, ldrop_drop/
  42   ]
  43 | #a #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  44   elim (llpx_inv_bind_O … HL12) -HL12 #HV1 #HT1
  45   elim (cpx_inv_abst1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct
  46   /4 width=4 by llpx_bind_repl_O, aaa_abst/
  47 | #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  48   elim (llpx_inv_flat … HL12) -HL12 #HV1 #HT1
  49   elim (cpx_inv_appl1 … H) -H *
  50   [ #V2 #T2 #HV12 #HT12 #H destruct /3 width=3 by aaa_appl/
  51   | #b #V2 #W1 #W2 #U1 #U2 #HV12 #HW12 #HU12 #H1 #H2 destruct
  52     lapply (IHV1 … HV12 … HV1) -IHV1 -HV12 #HV2
  53     lapply (IHT1 (ⓛ{b}W2.U2) … HT1) -IHT1 /2 width=1 by cpx_bind/ -L1 #H
  54     elim (aaa_inv_abst … H) -H #B0 #A0 #HW1 #HU2 #H destruct
  55     /5 width=6 by lsuba_aaa_trans, lsuba_abbr, aaa_abbr, aaa_cast/
  56   | #b #V #V2 #W1 #W2 #U1 #U2 #HV1 #HV2 #HW12 #HU12 #H1 #H2 destruct
  57     lapply (aaa_lift G L2 … B … (L2.ⓓW2) … HV2) -HV2 /2 width=2 by ldrop_drop/ #HV2
  58     lapply (IHT1 (ⓓ{b}W2.U2) … HT1) -IHT1 /2 width=1 by cpx_bind/ -L1 #H
  59     elim (aaa_inv_abbr … H) -H /3 width=3 by aaa_abbr, aaa_appl/
  60   ]
  61 | #G #L1 #V1 #T1 #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  62   elim (llpx_inv_flat … HL12) -HL12 #HV1 #HT1
  63   elim (cpx_inv_cast1 … H) -H
  64   [ * #V2 #T2 #HV12 #HT12 #H destruct /3 width=1 by aaa_cast/
  65   | -IHV1 /2 width=1 by/
  66   | -IHT1 /2 width=1 by/
  67   ]
  68 ]
  69 qed-.
  70
  71 lemma aaa_cpx_conf: ∀h,g,G,L,T1,A. ⦃G, L⦄ ⊢ T1 ⁝ A → ∀T2. ⦃G, L⦄ ⊢ T1 ➡[h, g] T2 → ⦃G, L⦄ ⊢ T2 ⁝ A.
  72 /2 width=7 by aaa_cpx_llpx_conf/ qed-.
  73
  74 lemma aaa_llpx_conf: ∀h,g,G,L1,T,A. ⦃G, L1⦄ ⊢ T ⁝ A → ∀L2. ⦃G, L1⦄ ⊢ ➡[h, g, T, 0] L2 → ⦃G, L2⦄ ⊢ T ⁝ A.
  75 /2 width=7 by aaa_cpx_llpx_conf/ qed-.
  76
  77 lemma aaa_cpr_conf: ∀G,L,T1,A. ⦃G, L⦄ ⊢ T1 ⁝ A → ∀T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → ⦃G, L⦄ ⊢ T2 ⁝ A.
  78 /3 width=5 by aaa_cpx_conf, cpr_cpx/ qed-.
  79 (*
  80 lamma aaa_llpr_conf: ∀G,L1,T,A. ⦃G, L1⦄ ⊢ T ⁝ A → ∀L2. ⦃G, L1⦄ ⊢ ➡[T, 0] L2 → ⦃G, L2⦄ ⊢ T ⁝ A.
  81 /3 width=5 by aaa_llpx_conf, llpr_llpx/ qed-.
  82 *)