matita/matita/contribs/lambdadelta/basic_2/etc_2A1/lsubr/lpqs_lpqs.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/lpqs_cpqs.ma".
  16
  17 (* SN RESTRICTED PARALLEL COMPUTATION ON LOCAL ENVIRONMENTS *****************)
  18
  19 (* Main properties on context-sensitive rest parallel computation for terms *)
  20
  21 fact cpqs_conf_lpqs_atom_atom:
  22    ∀I,L1,L2. ∃∃T. L1 ⊢ ⓪{I} ➤* T & L2 ⊢ ⓪{I} ➤* T.
  23 /2 width=3/ qed-.
  24
  25 fact cpqs_conf_lpqs_atom_delta:
  26    ∀L0,i. (
  27       ∀L,T. ⦃L0, #i⦄ ⊃+ ⦃L, T⦄ →
  28       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  29       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
  30       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
  31    ) →
  32    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  33    ∀V2. K0 ⊢ V0 ➤* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  34    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
  35    ∃∃T. L1 ⊢ #i ➤* T & L2 ⊢ T2 ➤* T.
  36 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  37 elim (lpqs_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  38 elim (lpqs_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  39 elim (lpqs_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  40 elim (lpqs_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  41 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  42 lapply (fsupp_lref … HLK0) -HLK0 #HLK0
  43 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  44 elim (lift_total V 0 (i+1)) #T #HVT
  45 lapply (cpqs_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  46 qed-.
  47
  48 fact cpqs_conf_lpqs_delta_delta:
  49    ∀L0,i. (
  50       ∀L,T. ⦃L0, #i⦄ ⊃+ ⦃L, T⦄ →
  51       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  52       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
  53       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
  54    ) →
  55    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  56    ∀V1. K0 ⊢ V0 ➤* V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  57    ∀KX,VX. ⇩[O, i] L0 ≡ KX.ⓓVX →
  58    ∀V2. KX ⊢ VX ➤* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  59    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
  60    ∃∃T. L1 ⊢ T1 ➤* T & L2 ⊢ T2 ➤* T.
  61 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  62 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  63 lapply (ldrop_mono … H … HLK0) -H #H destruct
  64 elim (lpqs_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  65 elim (lpqs_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  66 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  67 elim (lpqs_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  68 elim (lpqs_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  69 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  70 lapply (fsupp_lref … HLK0) -HLK0 #HLK0
  71 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  72 elim (lift_total V 0 (i+1)) #T #HVT
  73 lapply (cpqs_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
  74 lapply (cpqs_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
  75 qed-.
  76
  77 fact cpqs_conf_lpqs_bind_bind:
  78    ∀a,I,L0,V0,T0. (
  79       ∀L,T. ⦃L0,ⓑ{a,I}V0.T0⦄ ⊃+ ⦃L,T⦄ →
  80       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  81       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
  82       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
  83    ) →
  84    ∀V1. L0 ⊢ V0 ➤* V1 → ∀T1. L0.ⓑ{I}V0 ⊢ T0 ➤* T1 →
  85    ∀V2. L0 ⊢ V0 ➤* V2 → ∀T2. L0.ⓑ{I}V0 ⊢ T0 ➤* T2 →
  86    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
  87    ∃∃T. L1 ⊢ ⓑ{a,I}V1.T1 ➤* T & L2 ⊢ ⓑ{a,I}V2.T2 ➤* T.
  88 #a #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
  89 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
  90 elim (IH … HV01 … HV02 … HL01 … HL02) //
  91 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
  92 qed-.
  93
  94 fact cpqs_conf_lpqs_bind_zeta:
  95    ∀L0,V0,T0. (
  96       ∀L,T. ⦃L0,+ⓓV0.T0⦄ ⊃+ ⦃L,T⦄ →
  97       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  98       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
  99       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 100    ) →
 101    ∀V1. L0 ⊢ V0 ➤* V1 → ∀T1. L0.ⓓV0 ⊢ T0 ➤* T1 →
 102    ∀T2. L0.ⓓV0 ⊢ T0 ➤* T2 → ∀X2. ⇧[O, 1] X2 ≡ T2 →
 103    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 104    ∃∃T. L1 ⊢ +ⓓV1.T1 ➤* T & L2 ⊢ X2 ➤* T.
 105 #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 106 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 107 elim (IH … HT01 … HT02 (L1.ⓓV1) … (L2.ⓓV1)) -IH -HT01 -HT02 // /2 width=1/ -L0 -V0 -T0 #T #HT1 #HT2
 108 elim (cpqs_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=1/ /3 width=3/
 109 qed-.
 110
 111 fact cpqs_conf_lpqs_zeta_zeta:
 112    ∀L0,V0,T0. (
 113       ∀L,T. ⦃L0,+ⓓV0.T0⦄ ⊃+ ⦃L,T⦄ →
 114       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 115       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 116       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 117    ) →
 118    ∀T1. L0.ⓓV0 ⊢ T0 ➤* T1 → ∀X1. ⇧[O, 1] X1 ≡ T1 →
 119    ∀T2. L0.ⓓV0 ⊢ T0 ➤* T2 → ∀X2. ⇧[O, 1] X2 ≡ T2 →
 120    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 121    ∃∃T. L1 ⊢ X1 ➤* T & L2 ⊢ X2 ➤* T.
 122 #L0 #V0 #T0 #IH #T1 #HT01 #X1 #HXT1
 123 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 124 elim (IH … HT01 … HT02 (L1.ⓓV0) … (L2.ⓓV0)) -IH -HT01 -HT02 // /2 width=1/ -L0 -T0 #T #HT1 #HT2
 125 elim (cpqs_inv_lift1 … HT1 L1 … HXT1) -T1 /2 width=1/ #T1 #HT1 #HXT1
 126 elim (cpqs_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=1/ #T2 #HT2 #HXT2
 127 lapply (lift_inj … HT2 … HT1) -T #H destruct /2 width=3/
 128 qed-.
 129
 130 fact cpqs_conf_lpqs_flat_flat:
 131    ∀I,L0,V0,T0. (
 132       ∀L,T. ⦃L0,ⓕ{I}V0.T0⦄ ⊃+ ⦃L,T⦄ →
 133       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 134       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 135       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 136    ) →
 137    ∀V1. L0 ⊢ V0 ➤* V1 → ∀T1. L0 ⊢ T0 ➤* T1 →
 138    ∀V2. L0 ⊢ V0 ➤* V2 → ∀T2. L0 ⊢ T0 ➤* T2 →
 139    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 140    ∃∃T. L1 ⊢ ⓕ{I}V1.T1 ➤* T & L2 ⊢ ⓕ{I}V2.T2 ➤* T.
 141 #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 142 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 143 elim (IH … HV01 … HV02 … HL01 … HL02) //
 144 elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
 145 qed-.
 146
 147 fact cpqs_conf_lpqs_flat_tau:
 148    ∀L0,V0,T0. (
 149       ∀L,T. ⦃L0,ⓝV0.T0⦄ ⊃+ ⦃L,T⦄ →
 150       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 151       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 152       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 153    ) →
 154    ∀V1,T1. L0 ⊢ T0 ➤* T1 → ∀T2. L0 ⊢ T0 ➤* T2 →
 155    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 156    ∃∃T. L1 ⊢ ⓝV1.T1 ➤* T & L2 ⊢ T2 ➤* T.
 157 #L0 #V0 #T0 #IH #V1 #T1 #HT01
 158 #T2 #HT02 #L1 #HL01 #L2 #HL02
 159 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /3 width=3/
 160 qed-.
 161
 162 fact cpqs_conf_lpqs_tau_tau:
 163    ∀L0,V0,T0. (
 164       ∀L,T. ⦃L0,ⓝV0.T0⦄ ⊃+ ⦃L,T⦄ →
 165       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 166       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 167       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 168    ) →
 169    ∀T1. L0 ⊢ T0 ➤* T1 → ∀T2. L0 ⊢ T0 ➤* T2 →
 170    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 171    ∃∃T. L1 ⊢ T1 ➤* T & L2 ⊢ T2 ➤* T.
 172 #L0 #V0 #T0 #IH #T1 #HT01
 173 #T2 #HT02 #L1 #HL01 #L2 #HL02
 174 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /2 width=3/
 175 qed-.
 176
 177 theorem cpqs_conf_lpqs: lpx_sn_confluent cpqs cpqs.
 178 #L0 #T0 @(fsupp_wf_ind … L0 T0) -L0 -T0 #L #T #IH #L0 * [|*]
 179 [ #I0 #HL #HT #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 180   elim (cpqs_inv_atom1 … H1) -H1
 181   elim (cpqs_inv_atom1 … H2) -H2
 182   [ #H2 #H1 destruct
 183     /2 width=1 by cpqs_conf_lpqs_atom_atom/
 184   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 185     /3 width=10 by cpqs_conf_lpqs_atom_delta/
 186   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 187     /4 width=10 by ex2_commute, cpqs_conf_lpqs_atom_delta/
 188   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 189     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 190     /3 width=17 by cpqs_conf_lpqs_delta_delta/
 191   ]
 192 | #a #I #V0 #T0 #HL #HT #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 193   elim (cpqs_inv_bind1 … H1) -H1 *
 194   [ #V1 #T1 #HV01 #HT01 #H1
 195   | #T1 #HT01 #HXT1 #H11 #H12
 196   ]
 197   elim (cpqs_inv_bind1 … H2) -H2 *
 198   [1,3: #V2 #T2 #HV02 #HT02 #H2
 199   |2,4: #T2 #HT02 #HXT2 #H21 #H22
 200   ] destruct
 201   [ /3 width=10 by cpqs_conf_lpqs_bind_bind/
 202   | /4 width=11 by ex2_commute, cpqs_conf_lpqs_bind_zeta/
 203   | /3 width=11 by cpqs_conf_lpqs_bind_zeta/
 204   | /3 width=12 by cpqs_conf_lpqs_zeta_zeta/
 205   ]
 206 | #I #V0 #T0 #HL #HT #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 207   elim (cpqs_inv_flat1 … H1) -H1 *
 208   [ #V1 #T1 #HV01 #HT01 #H1
 209   | #HX1 #H1
 210   ]
 211   elim (cpqs_inv_flat1 … H2) -H2 *
 212   [1,3: #V2 #T2 #HV02 #HT02 #H2
 213   |2,4: #HX2 #H2
 214   ] destruct
 215   [ /3 width=10 by cpqs_conf_lpqs_flat_flat/
 216   | /4 width=8 by ex2_commute, cpqs_conf_lpqs_flat_tau/
 217   | /3 width=8 by cpqs_conf_lpqs_flat_tau/
 218   | /3 width=7 by cpqs_conf_lpqs_tau_tau/
 219   ]
 220 ]
 221 qed-.
 222
 223 theorem cpqs_conf: ∀L. confluent … (cpqs L).
 224 /2 width=6 by cpqs_conf_lpqs/ qed-.
 225
 226 (* Properties on context-sensitive rest. parallel computation for terms *****)
 227
 228 lemma lpqs_cpqs_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ➤* T1 → ∀L1. L0 ⊢ ➤* L1 →
 229                          ∃∃T. L1 ⊢ T0 ➤* T & L1 ⊢ T1 ➤* T.
 230 #L0 #T0 #T1 #HT01 #L1 #HL01
 231 elim (cpqs_conf_lpqs … HT01 T0 … HL01 … HL01) // -L0 /2 width=3/
 232 qed-.
 233
 234 lemma lpqs_cpqs_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ➤* T1 → ∀L1. L0 ⊢ ➤* L1 →
 235                          ∃∃T. L1 ⊢ T0 ➤* T & L0 ⊢ T1 ➤* T.
 236 #L0 #T0 #T1 #HT01 #L1 #HL01
 237 elim (cpqs_conf_lpqs … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 238 qed-.
 239
 240 (* Main properties **********************************************************)
 241
 242 theorem lpqs_conf: confluent … lpqs.
 243 /3 width=6 by lpx_sn_conf, cpqs_conf_lpqs/
 244 qed-.
 245
 246 theorem lpqs_trans: Transitive … lpqs.
 247 /3 width=5 by lpx_sn_trans, cpqs_trans_lpqs/
 248 qed-.
 249
 250 (* Advanced forward lemmas **************************************************)
 251
 252 lemma cpqs_fwd_shift1: ∀L1,L,T1,T. L ⊢ L1 @@ T1 ➤* T →
 253                        ∃∃L2,T2. L @@ L1 ⊢ ➤* L @@ L2 & L @@ L1 ⊢ T1 ➤* T2 &
 254                                 T = L2 @@ T2.
 255 #L1 @(lenv_ind_dx … L1) -L1
 256 [ #L #T1 #T #HT1
 257   @ex3_2_intro [3: // |4,5: // |1,2: skip ] (**) (* /2 width=4/ does not work *)
 258 | #I #L1 #V1 #IH #L #T1 #T >shift_append_assoc #H <append_assoc
 259   elim (cpqs_inv_bind1 … H) -H *
 260   [ #V2 #T2 #HV12 #HT12 #H destruct
 261     elim (IH … HT12) -IH -HT12 #L2 #T #HL12 #HT1 #H destruct
 262     lapply (lpqs_trans … HL12 (L.ⓑ{I}V2@@L2) ?) -HL12 /3 width=1/ #HL12
 263     @(ex3_2_intro … (⋆.ⓑ{I}V2@@L2)) [4: /2 width=3/ | skip ] <append_assoc // (**) (* explicit constructor *)
 264   | #T #_ #_ #H destruct
 265   ]
 266 ]
 267 qed-.