matita/matita/contribs/lambdadelta/basic_2/grammar/item.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/bool.ma".
  16 include "ground_2/lib/arith.ma".
  17
  18 (* ITEMS ********************************************************************)
  19
  20 (* atomic items *)
  21 inductive item0: Type[0] ≝
  22    | Sort: nat → item0 (* sort: starting at 0 *)
  23    | LRef: nat → item0 (* reference by index: starting at 0 *)
  24    | GRef: nat → item0 (* reference by position: starting at 0 *)
  25 .
  26
  27 (* binary binding items *)
  28 inductive bind2: Type[0] ≝
  29   | Abbr: bind2 (* abbreviation *)
  30   | Abst: bind2 (* abstraction *)
  31 .
  32
  33 (* binary non-binding items *)
  34 inductive flat2: Type[0] ≝
  35   | Appl: flat2 (* application *)
  36   | Cast: flat2 (* explicit type annotation *)
  37 .
  38
  39 (* binary items *)
  40 inductive item2: Type[0] ≝
  41   | Bind2: bool → bind2 → item2 (* polarized binding item *)
  42   | Flat2: flat2 → item2        (* non-binding item *)
  43 .
  44
  45 (* Basic properties *********************************************************)
  46
  47 lemma eq_item0_dec: ∀I1,I2:item0. Decidable (I1 = I2).
  48 * #i1 * #i2 [2,3,4,6,7,8: @or_intror #H destruct ]
  49 elim (eq_nat_dec i1 i2) /2 width=1 by or_introl/
  50 #Hni12 @or_intror #H destruct /2 width=1 by/
  51 qed-.
  52
  53 (* Basic_1: was: bind_dec *)
  54 lemma eq_bind2_dec: ∀I1,I2:bind2. Decidable (I1 = I2).
  55 * * /2 width=1 by or_introl/
  56 @or_intror #H destruct
  57 qed-.
  58
  59 (* Basic_1: was: flat_dec *)
  60 lemma eq_flat2_dec: ∀I1,I2:flat2. Decidable (I1 = I2).
  61 * * /2 width=1 by or_introl/
  62 @or_intror #H destruct
  63 qed-.
  64
  65 (* Basic_1: was: kind_dec *)
  66 lemma eq_item2_dec: ∀I1,I2:item2. Decidable (I1 = I2).
  67 * [ #a1 ] #I1 * [1,3: #a2 ] #I2
  68 [2,3: @or_intror #H destruct
  69 | elim (eq_bool_dec a1 a2) #Ha
  70   [ elim (eq_bind2_dec I1 I2) /2 width=1 by or_introl/ #HI ]
  71   @or_intror #H destruct /2 width=1 by/
  72 | elim (eq_flat2_dec I1 I2) /2 width=1 by or_introl/ #HI
  73   @or_intror #H destruct /2 width=1 by/
  74 ]
  75 qed-.
  76
  77 (* Basic_1: removed theorems 21:
  78             s_S s_plus s_plus_sym s_minus minus_s_s s_le s_lt s_inj s_inc
  79             s_arith0 s_arith1
  80             r_S r_plus r_plus_sym r_minus r_dis s_r r_arith0 r_arith1
  81             not_abbr_abst bind_dec_not
  82 *)