matita/matita/contribs/lambdadelta/basic_2/grammar/lenv_append.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lenv_length.ma".
  16
  17 (* LOCAL ENVIRONMENTS *******************************************************)
  18
  19 let rec append L K on K ≝ match K with
  20 [ LAtom       ⇒ L
  21 | LPair K I V ⇒ (append L K). ⓑ{I} V
  22 ].
  23
  24 interpretation "append (local environment)" 'Append L1 L2 = (append L1 L2).
  25
  26 definition l_appendable_sn: predicate (lenv→relation term) ≝ λR.
  27                             ∀K,T1,T2. R K T1 T2 → ∀L. R (L @@ K) T1 T2.
  28
  29 (* Basic properties *********************************************************)
  30
  31 lemma append_atom_sn: ∀L. ⋆ @@ L = L.
  32 #L elim L -L normalize //
  33 qed.
  34
  35 lemma append_assoc: associative … append.
  36 #L1 #L2 #L3 elim L3 -L3 normalize //
  37 qed.
  38
  39 lemma append_length: ∀L1,L2. |L1 @@ L2| = |L1| + |L2|.
  40 #L1 #L2 elim L2 -L2 normalize //
  41 qed.
  42
  43 (* Basic inversion lemmas ***************************************************)
  44
  45 lemma append_inj_sn: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |K1| = |K2| →
  46                      L1 = L2 ∧ K1 = K2.
  47 #K1 elim K1 -K1
  48 [ * normalize /2 width=1/
  49   #K2 #I2 #V2 #L1 #L2 #_ <plus_n_Sm #H destruct
  50 | #K1 #I1 #V1 #IH * normalize
  51   [ #L1 #L2 #_ <plus_n_Sm #H destruct
  52   | #K2 #I2 #V2 #L1 #L2 #H1 #H2
  53     elim (destruct_lpair_lpair … H1) -H1 #H1 #H3 #H4 destruct (**) (* destruct lemma needed *)
  54     elim (IH … H1) -IH -H1 // -H2 /2 width=1/
  55   ]
  56 ]
  57 qed-.
  58
  59 (* Note: lemma 750 *)
  60 lemma append_inj_dx: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |L1| = |L2| →
  61                      L1 = L2 ∧ K1 = K2.
  62 #K1 elim K1 -K1
  63 [ * normalize /2 width=1/
  64   #K2 #I2 #V2 #L1 #L2 #H1 #H2 destruct
  65   normalize in H2; >append_length in H2; #H
  66   elim (plus_xySz_x_false … H)
  67 | #K1 #I1 #V1 #IH * normalize
  68   [ #L1 #L2 #H1 #H2 destruct
  69     normalize in H2; >append_length in H2; #H
  70     elim (plus_xySz_x_false … (sym_eq … H))
  71   | #K2 #I2 #V2 #L1 #L2 #H1 #H2
  72     elim (destruct_lpair_lpair … H1) -H1 #H1 #H3 #H4 destruct (**) (* destruct lemma needed *)
  73     elim (IH … H1) -IH -H1 // -H2 /2 width=1/
  74   ]
  75 ]
  76 qed-.
  77
  78 lemma append_inv_refl_dx: ∀L,K. L @@ K = L → K = ⋆.
  79 #L #K #H
  80 elim (append_inj_dx … (⋆) … H) //
  81 qed-.
  82
  83 lemma append_inv_pair_dx: ∀I,L,K,V. L @@ K = L.ⓑ{I}V → K = ⋆.ⓑ{I}V.
  84 #I #L #K #V #H
  85 elim (append_inj_dx … (⋆.ⓑ{I}V) … H) //
  86 qed-.
  87
  88 lemma length_inv_pos_dx_append: ∀d,L. |L| = d + 1 →
  89                                 ∃∃I,K,V. |K| = d & L = ⋆.ⓑ{I}V @@ K.
  90 #d @(nat_ind_plus … d) -d
  91 [ #L #H
  92   elim (length_inv_pos_dx … H) -H #I #K #V #H
  93   >(length_inv_zero_dx … H) -H #H destruct
  94   @ex2_3_intro [4: /2 width=2/ |5: // |1,2,3: skip ] (**) (* /3/ does not work *)
  95 | #d #IHd #L #H
  96   elim (length_inv_pos_dx … H) -H #I #K #V #H
  97   elim (IHd … H) -IHd -H #I0 #K0 #V0 #H1 #H2 #H3 destruct
  98   @(ex2_3_intro … (K0.ⓑ{I}V)) //
  99 ]
 100 qed-.
 101
 102 (* Basic_eliminators ********************************************************)
 103
 104 fact lenv_ind_dx_aux: ∀R:predicate lenv. R (⋆) →
 105                       (∀I,L,V. R L → R (⋆.ⓑ{I}V @@ L)) →
 106                       ∀d,L. |L| = d → R L.
 107 #R #Hatom #Hpair #d @(nat_ind_plus … d) -d
 108 [ #L #H >(length_inv_zero_dx … H) -H //
 109 | #d #IH #L #H
 110   elim (length_inv_pos_dx_append … H) -H #I #K #V #H1 #H2 destruct /3 width=1/
 111 ]
 112 qed-.
 113
 114 lemma lenv_ind_dx: ∀R:predicate lenv. R (⋆) →
 115                    (∀I,L,V. R L → R (⋆.ⓑ{I}V @@ L)) →
 116                    ∀L. R L.
 117 /3 width=2 by lenv_ind_dx_aux/ qed-.
 118
 119 (* Advanced inversion lemmas ************************************************)
 120
 121 lemma length_inv_pos_sn_append: ∀d,L. 1 + d = |L| →
 122                                 ∃∃I,K,V. d = |K| & L = ⋆. ⓑ{I}V @@ K.
 123 #d >commutative_plus @(nat_ind_plus … d) -d
 124 [ #L #H elim (length_inv_pos_sn … H) -H #I #K #V #H1 #H2 destruct
 125   >(length_inv_zero_sn … H1) -K
 126   @(ex2_3_intro … (⋆)) // (**) (* explicit constructor *)
 127 | #d #IHd #L #H elim (length_inv_pos_sn … H) -H #I #K #V #H1 #H2 destruct
 128   >H1 in IHd; -H1 #IHd
 129   elim (IHd K) -IHd // #J #L #W #H1 #H2 destruct
 130   @(ex2_3_intro … (L.ⓑ{I}V)) // (**) (* explicit constructor *)
 131   >append_length /2 width=1/
 132 ]
 133 qed-.