matita/matita/contribs/lambdadelta/basic_2/grammar/lenv_append.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lenv_length.ma".
  16
  17 (* LOCAL ENVIRONMENTS *******************************************************)
  18
  19 let rec append L K on K ≝ match K with
  20 [ LAtom       ⇒ L
  21 | LPair K I V ⇒ (append L K). ⓑ{I} V
  22 ].
  23
  24 interpretation "append (local environment)" 'Append L1 L2 = (append L1 L2).
  25
  26 (* Basic properties *********************************************************)
  27
  28 lemma append_atom_sn: ∀L. ⋆ @@ L = L.
  29 #L elim L -L normalize //
  30 qed.
  31
  32 lemma append_assoc: associative … append.
  33 #L1 #L2 #L3 elim L3 -L3 normalize //
  34 qed.
  35
  36 lemma append_length: ∀L1,L2. |L1 @@ L2| = |L1| + |L2|.
  37 #L1 #L2 elim L2 -L2 normalize //
  38 qed.
  39
  40 (* Basic inversion lemmas ***************************************************)
  41
  42 lemma append_inj_sn: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |K1| = |K2| →
  43                      L1 = L2 ∧ K1 = K2.
  44 #K1 elim K1 -K1
  45 [ * normalize /2 width=1/
  46   #K2 #I2 #V2 #L1 #L2 #_ <plus_n_Sm #H destruct
  47 | #K1 #I1 #V1 #IH * normalize
  48   [ #L1 #L2 #_ <plus_n_Sm #H destruct
  49   | #K2 #I2 #V2 #L1 #L2 #H1 #H2
  50     elim (destruct_lpair_lpair … H1) -H1 #H1 #H3 #H4 destruct (**) (* destruct lemma needed *)
  51     elim (IH … H1 ?) -IH -H1 // -H2 /2 width=1/
  52   ]
  53 ]
  54 qed-.
  55
  56 (* Note: lemma 750 *)
  57 lemma append_inj_dx: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |L1| = |L2| →
  58                      L1 = L2 ∧ K1 = K2.
  59 #K1 elim K1 -K1
  60 [ * normalize /2 width=1/
  61   #K2 #I2 #V2 #L1 #L2 #H1 #H2 destruct
  62   normalize in H2; >append_length in H2; #H
  63   elim (plus_xySz_x_false … H)
  64 | #K1 #I1 #V1 #IH * normalize
  65   [ #L1 #L2 #H1 #H2 destruct
  66     normalize in H2; >append_length in H2; #H
  67     elim (plus_xySz_x_false … (sym_eq … H))
  68   | #K2 #I2 #V2 #L1 #L2 #H1 #H2
  69     elim (destruct_lpair_lpair … H1) -H1 #H1 #H3 #H4 destruct (**) (* destruct lemma needed *)
  70     elim (IH … H1 ?) -IH -H1 // -H2 /2 width=1/
  71   ]
  72 ]
  73 qed-.
  74
  75 lemma append_inv_refl_dx: ∀L,K. L @@ K = L → K = ⋆.
  76 #L #K #H
  77 elim (append_inj_dx … (⋆) … H ?) //
  78 qed-.
  79
  80 lemma append_inv_pair_dx: ∀I,L,K,V. L @@ K = L.ⓑ{I}V → K = ⋆.ⓑ{I}V.
  81 #I #L #K #V #H
  82 elim (append_inj_dx … (⋆.ⓑ{I}V) … H ?) //
  83 qed-.
  84
  85 lemma length_inv_pos_dx_append: ∀d,L. |L| = d + 1 →
  86                                 ∃∃I,K,V. |K| = d & L = ⋆.ⓑ{I}V @@ K.
  87 #d @(nat_ind_plus … d) -d
  88 [ #L #H
  89   elim (length_inv_pos_dx … H) -H #I #K #V #H
  90   >(length_inv_zero_dx … H) -H #H destruct
  91   @ex2_3_intro [4: /2 width=2/ |5: // |1,2,3: skip ] (**) (* /3/ does not work *)
  92 | #d #IHd #L #H
  93   elim (length_inv_pos_dx … H) -H #I #K #V #H
  94   elim (IHd … H) -IHd -H #I0 #K0 #V0 #H1 #H2 #H3 destruct
  95   @(ex2_3_intro … (K0.ⓑ{I}V)) //
  96 ]
  97 qed-.
  98
  99 (* Basic_eliminators ********************************************************)
 100
 101 fact lenv_ind_dx_aux: ∀R:predicate lenv. R ⋆ →
 102                       (∀I,L,V. R L → R (⋆.ⓑ{I}V @@ L)) →
 103                       ∀d,L. |L| = d → R L.
 104 #R #Hatom #Hpair #d @(nat_ind_plus … d) -d
 105 [ #L #H >(length_inv_zero_dx … H) -H //
 106 | #d #IH #L #H
 107   elim (length_inv_pos_dx_append … H) -H #I #K #V #H1 #H2 destruct /3 width=1/
 108 ]
 109 qed-.
 110
 111 lemma lenv_ind_dx: ∀R:predicate lenv. R ⋆ →
 112                    (∀I,L,V. R L → R (⋆.ⓑ{I}V @@ L)) →
 113                    ∀L. R L.
 114 /3 width=2 by lenv_ind_dx_aux/ qed-.
 115
 116 (* Advanced inversion lemmas ************************************************)
 117
 118 lemma length_inv_pos_sn_append: ∀d,L. 1 + d = |L| →
 119                                 ∃∃I,K,V. d = |K| & L = ⋆. ⓑ{I}V @@ K.
 120 #d >commutative_plus @(nat_ind_plus … d) -d
 121 [ #L #H elim (length_inv_pos_sn … H) -H #I #K #V #H1 #H2 destruct
 122   >(length_inv_zero_sn … H1) -K
 123   @(ex2_3_intro … (⋆)) // (**) (* explicit constructor *)
 124 | #d #IHd #L #H elim (length_inv_pos_sn … H) -H #I #K #V #H1 #H2 destruct
 125   >H1 in IHd; -H1 #IHd
 126   elim (IHd K ?) -IHd // #J #L #W #H1 #H2 destruct
 127   @(ex2_3_intro … (L.ⓑ{I}V)) // (**) (* explicit constructor *)
 128   >append_length /2 width=1/
 129 ]
 130 qed-.