matita/matita/contribs/lambdadelta/basic_2/grammar/leq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_lt.ma".
  16 include "basic_2/notation/relations/iso_4.ma".
  17 include "basic_2/grammar/lenv_length.ma".
  18
  19 (* EQUIVALENCE FOR LOCAL ENVIRONMENTS ***************************************)
  20
  21 inductive leq: relation4 ynat ynat lenv lenv ≝
  22 | leq_atom: ∀d,e. leq d e (⋆) (⋆)
  23 | leq_zero: ∀I1,I2,L1,L2,V1,V2.
  24             leq 0 0 L1 L2 → leq 0 0 (L1.ⓑ{I1}V1) (L2.ⓑ{I2}V2)
  25 | leq_pair: ∀I,L1,L2,V,e. leq 0 e L1 L2 →
  26             leq 0 (⫯e) (L1.ⓑ{I}V) (L2.ⓑ{I}V)
  27 | leq_succ: ∀I1,I2,L1,L2,V1,V2,d,e.
  28             leq d e L1 L2 → leq (⫯d) e (L1. ⓑ{I1}V1) (L2. ⓑ{I2} V2)
  29 .
  30
  31 interpretation
  32   "equivalence (local environment)"
  33   'Iso d e L1 L2 = (leq d e L1 L2).
  34
  35 (* Basic properties *********************************************************)
  36
  37 lemma leq_pair_lt: ∀I,L1,L2,V,e. L1 ≃[0, ⫰e] L2 → 0 < e →
  38                    L1.ⓑ{I}V ≃[0, e] L2.ⓑ{I}V.
  39 #I #L1 #L2 #V #e #HL12 #He <(ylt_inv_O1 … He) /2 width=1 by leq_pair/
  40 qed.
  41
  42 lemma leq_succ_lt: ∀I1,I2,L1,L2,V1,V2,d,e. L1 ≃[⫰d, e] L2 → 0 < d →
  43                    L1.ⓑ{I1}V1 ≃[d, e] L2. ⓑ{I2}V2.
  44 #I1 #I2 #L1 #L2 #V1 #V2 #d #e #HL12 #Hd <(ylt_inv_O1 … Hd) /2 width=1 by leq_succ/
  45 qed.
  46
  47 lemma leq_pair_O_Y: ∀L1,L2. L1 ≃[0, ∞] L2 →
  48                     ∀I,V. L1.ⓑ{I}V ≃[0, ∞] L2.ⓑ{I}V.
  49 #L1 #L2 #HL12 #I #V lapply (leq_pair I … V … HL12) -HL12 //
  50 qed.
  51
  52 lemma leq_refl: ∀L,d,e. L ≃[d, e] L.
  53 #L elim L -L //
  54 #L #I #V #IHL #d elim (ynat_cases … d) [| * #x ]
  55 #Hd destruct /2 width=1 by leq_succ/
  56 #e elim (ynat_cases … e) [| * #x ]
  57 #He destruct /2 width=1 by leq_zero, leq_pair/
  58 qed.
  59
  60 lemma leq_O2: ∀L1,L2,d. |L1| = |L2| → L1 ≃[d, yinj 0] L2.
  61 #L1 elim L1 -L1 [| #L1 #I1 #V1 #IHL1 ]
  62 * // [1,3: #L2 #I2 #V2 ] #d normalize
  63 [1,3: <plus_n_Sm #H destruct ]
  64 #H lapply (injective_plus_l … H) -H #HL12
  65 elim (ynat_cases d) /3 width=1 by leq_zero/
  66 * /3 width=1 by leq_succ/
  67 qed.
  68
  69 lemma leq_sym: ∀d,e. symmetric … (leq d e).
  70 #d #e #L1 #L2 #H elim H -L1 -L2 -d -e
  71 /2 width=1 by leq_zero, leq_pair, leq_succ/
  72 qed-.
  73
  74 (* Basic inversion lemmas ***************************************************)
  75
  76 fact leq_inv_atom1_aux: ∀L1,L2,d,e. L1 ≃[d, e] L2 → L1 = ⋆ → L2 = ⋆.
  77 #L1 #L2 #d #e * -L1 -L2 -d -e //
  78 [ #I1 #I2 #L1 #L2 #V1 #V2 #_ #H destruct
  79 | #I #L1 #L2 #V #e #_ #H destruct
  80 | #I1 #I2 #L1 #L2 #V1 #V2 #d #e #_ #H destruct
  81 ]
  82 qed-.
  83
  84 lemma leq_inv_atom1: ∀L2,d,e. ⋆ ≃[d, e] L2 → L2 = ⋆.
  85 /2 width=5 by leq_inv_atom1_aux/ qed-.
  86
  87 fact leq_inv_zero1_aux: ∀L1,L2,d,e. L1 ≃[d, e] L2 →
  88                         ∀J1,K1,W1. L1 = K1.ⓑ{J1}W1 → d = 0 → e = 0 →
  89                         ∃∃J2,K2,W2. K1 ≃[0, 0] K2 & L2 = K2.ⓑ{J2}W2.
  90 #L1 #L2 #d #e * -L1 -L2 -d -e
  91 [ #d #e #J1 #K1 #W1 #H destruct
  92 | #I1 #I2 #L1 #L2 #V1 #V2 #HL12 #J1 #K1 #W1 #H #_ #_ destruct
  93   /2 width=5 by ex2_3_intro/
  94 | #I #L1 #L2 #V #e #_ #J1 #K1 #W1 #_ #_ #H
  95   elim (ysucc_inv_O_dx … H)
  96 | #I1 #I2 #L1 #L2 #V1 #V2 #d #e #_ #J1 #K1 #W1 #_ #H
  97   elim (ysucc_inv_O_dx … H)
  98 ]
  99 qed-.
 100
 101 lemma leq_inv_zero1: ∀I1,K1,L2,V1. K1.ⓑ{I1}V1 ≃[0, 0] L2 →
 102                      ∃∃I2,K2,V2. K1 ≃[0, 0] K2 & L2 = K2.ⓑ{I2}V2.
 103 /2 width=9 by leq_inv_zero1_aux/ qed-.
 104
 105 fact leq_inv_pair1_aux: ∀L1,L2,d,e. L1 ≃[d, e] L2 →
 106                         ∀J,K1,W. L1 = K1.ⓑ{J}W → d = 0 → 0 < e →
 107                         ∃∃K2. K1 ≃[0, ⫰e] K2 & L2 = K2.ⓑ{J}W.
 108 #L1 #L2 #d #e * -L1 -L2 -d -e
 109 [ #d #e #J #K1 #W #H destruct
 110 | #I1 #I2 #L1 #L2 #V1 #V2 #_ #J #K1 #W #_ #_ #H
 111   elim (ylt_yle_false … H) //
 112 | #I #L1 #L2 #V #e #HL12 #J #K1 #W #H #_ #_ destruct
 113   /2 width=3 by ex2_intro/
 114 | #I1 #I2 #L1 #L2 #V1 #V2 #d #e #_ #J #K1 #W #_ #H
 115   elim (ysucc_inv_O_dx … H)
 116 ]
 117 qed-.
 118
 119 lemma leq_inv_pair1: ∀I,K1,L2,V,e. K1.ⓑ{I}V ≃[0, e] L2 → 0 < e →
 120                      ∃∃K2. K1 ≃[0, ⫰e] K2 & L2 = K2.ⓑ{I}V.
 121 /2 width=6 by leq_inv_pair1_aux/ qed-.
 122
 123 lemma leq_inv_pair: ∀I1,I2,L1,L2,V1,V2,e. L1.ⓑ{I1}V1 ≃[0, e] L2.ⓑ{I2}V2 → 0 < e →
 124                     ∧∧ L1 ≃[0, ⫰e] L2 & I1 = I2 & V1 = V2.
 125 #I1 #I2 #L1 #L2 #V1 #V2 #e #H #He elim (leq_inv_pair1 … H) -H //
 126 #Y #HL12 #H destruct /2 width=1 by and3_intro/
 127 qed-.
 128
 129 fact leq_inv_succ1_aux: ∀L1,L2,d,e. L1 ≃[d, e] L2 →
 130                         ∀J1,K1,W1. L1 = K1.ⓑ{J1}W1 → 0 < d →
 131                         ∃∃J2,K2,W2. K1 ≃[⫰d, e] K2 & L2 = K2.ⓑ{J2}W2.
 132 #L1 #L2 #d #e * -L1 -L2 -d -e
 133 [ #d #e #J1 #K1 #W1 #H destruct
 134 | #I1 #I2 #L1 #L2 #V1 #V2 #_ #J1 #K1 #W1 #_ #H
 135   elim (ylt_yle_false … H) //
 136 | #I #L1 #L2 #V #e #_ #J1 #K1 #W1 #_ #H
 137   elim (ylt_yle_false … H) //
 138 | #I1 #I2 #L1 #L2 #V1 #V2 #d #e #HL12 #J1 #K1 #W1 #H #_ destruct
 139   /2 width=5 by ex2_3_intro/
 140 ]
 141 qed-.
 142
 143 lemma leq_inv_succ1: ∀I1,K1,L2,V1,d,e. K1.ⓑ{I1}V1 ≃[d, e] L2 → 0 < d →
 144                      ∃∃I2,K2,V2. K1 ≃[⫰d, e] K2 & L2 = K2.ⓑ{I2}V2.
 145 /2 width=5 by leq_inv_succ1_aux/ qed-.
 146
 147 lemma leq_inv_atom2: ∀L1,d,e. L1 ≃[d, e] ⋆ → L1 = ⋆.
 148 /3 width=3 by leq_inv_atom1, leq_sym/
 149 qed-.
 150
 151 lemma leq_inv_succ: ∀I1,I2,L1,L2,V1,V2,d,e. L1.ⓑ{I1}V1 ≃[d, e] L2.ⓑ{I2}V2 → 0 < d →
 152                     L1 ≃[⫰d, e] L2.
 153 #I1 #I2 #L1 #L2 #V1 #V2 #d #e #H #Hd elim (leq_inv_succ1 … H) -H //
 154 #Z #Y #X #HL12 #H destruct //
 155 qed-.
 156
 157 lemma leq_inv_zero2: ∀I2,K2,L1,V2. L1 ≃[0, 0] K2.ⓑ{I2}V2 →
 158                      ∃∃I1,K1,V1. K1 ≃[0, 0] K2 & L1 = K1.ⓑ{I1}V1.
 159 #I2 #K2 #L1 #V2 #H elim (leq_inv_zero1 … (leq_sym … H)) -H
 160 /3 width=5 by leq_sym, ex2_3_intro/
 161 qed-.
 162
 163 lemma leq_inv_pair2: ∀I,K2,L1,V,e. L1 ≃[0, e] K2.ⓑ{I}V → 0 < e →
 164                      ∃∃K1. K1 ≃[0, ⫰e] K2 & L1 = K1.ⓑ{I}V.
 165 #I #K2 #L1 #V #e #H #He elim (leq_inv_pair1 … (leq_sym … H)) -H
 166 /3 width=3 by leq_sym, ex2_intro/
 167 qed-.
 168
 169 lemma leq_inv_succ2: ∀I2,K2,L1,V2,d,e. L1 ≃[d, e] K2.ⓑ{I2}V2 → 0 < d →
 170                      ∃∃I1,K1,V1. K1 ≃[⫰d, e] K2 & L1 = K1.ⓑ{I1}V1.
 171 #I2 #K2 #L1 #V2 #d #e #H #Hd elim (leq_inv_succ1 … (leq_sym … H)) -H
 172 /3 width=5 by leq_sym, ex2_3_intro/
 173 qed-.
 174
 175 (* Basic forward lemmas *****************************************************)
 176
 177 lemma leq_fwd_length: ∀L1,L2,d,e. L1 ≃[d, e] L2 → |L2| = |L1|.
 178 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e normalize //
 179 qed-.
 180
 181 (* Advanced inversion lemmas ************************************************)
 182
 183 fact leq_inv_O_Y_aux: ∀L1,L2,d,e. L1 ≃[d, e] L2 → d = 0 → e = ∞ → L1 = L2.
 184 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e //
 185 [ #I1 #I2 #L1 #L2 #V1 #V2 #_ #_ #_ #H destruct
 186 | /4 width=1 by eq_f3, ysucc_inv_Y_dx/
 187 | #I1 #I2 #L1 #L2 #V1 #V2 #d #e #_ #_ #H elim (ysucc_inv_O_dx … H)
 188 ]
 189 qed-.
 190
 191 lemma leq_inv_O_Y: ∀L1,L2. L1 ≃[0, ∞] L2 → L1 = L2.
 192 /2 width=5 by leq_inv_O_Y_aux/ qed-.