matita/matita/contribs/lambdadelta/basic_2/grammar/lpx_sn_tc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lpx_sn.ma".
  16
  17 (* SN POINTWISE EXTENSION OF A CONTEXT-SENSITIVE REALTION FOR TERMS *********)
  18
  19 (* Properties on transitive_closure *****************************************)
  20
  21 lemma TC_lpx_sn_pair_refl: ∀R. (∀L. reflexive … (R L)) →
  22                            ∀L1,L2. TC … (lpx_sn R) L1 L2 →
  23                            ∀I,V. TC … (lpx_sn R) (L1. ⓑ{I} V) (L2. ⓑ{I} V).
  24 #R #HR #L1 #L2 #H @(TC_star_ind … L2 H) -L2
  25 [ /2 width=1 by lpx_sn_refl/
  26 | /3 width=1 by TC_reflexive, lpx_sn_refl/
  27 | /3 width=5/
  28 ]
  29 qed-.
  30
  31 lemma TC_lpx_sn_pair: ∀R. (∀L. reflexive … (R L)) →
  32                       ∀I,L1,L2. TC … (lpx_sn R) L1 L2 →
  33                       ∀V1,V2. LTC … R L1 V1 V2 →
  34                       TC … (lpx_sn R) (L1. ⓑ{I} V1) (L2. ⓑ{I} V2).
  35 #R #HR #I #L1 #L2 #HL12 #V1 #V2 #H @(TC_star_ind_dx … V1 H) -V1 //
  36 [ /2 width=1 by TC_lpx_sn_pair_refl/
  37 | /4 width=3 by TC_strap, lpx_sn_pair, lpx_sn_refl/
  38 ]
  39 qed-.
  40
  41 lemma lpx_sn_LTC_TC_lpx_sn: ∀R. (∀L. reflexive … (R L)) →
  42                             ∀L1,L2. lpx_sn (LTC … R) L1 L2 →
  43                             TC … (lpx_sn R) L1 L2.
  44 #R #HR #L1 #L2 #H elim H -L1 -L2 /2 width=1/
  45 /2 width=1 by TC_lpx_sn_pair/
  46 qed-.
  47
  48 (* Inversion lemmas on transitive closure ***********************************)
  49
  50 lemma TC_lpx_sn_inv_atom2: ∀R,L1. TC … (lpx_sn R) L1 (⋆) → L1 = ⋆.
  51 #R #L1 #H @(TC_ind_dx … L1 H) -L1
  52 [ #L1 #H lapply (lpx_sn_inv_atom2 … H) -H //
  53 | #L1 #L #HL1 #_ #IHL2 destruct
  54   lapply (lpx_sn_inv_atom2 … HL1) -HL1 //
  55 ]
  56 qed-.
  57
  58 lemma TC_lpx_sn_inv_pair2: ∀R. s_rs_trans … R (lpx_sn R) →
  59                            ∀I,L1,K2,V2. TC  … (lpx_sn R) L1 (K2.ⓑ{I}V2) →
  60                            ∃∃K1,V1. TC … (lpx_sn R) K1 K2 & LTC … R K1 V1 V2 & L1 = K1. ⓑ{I} V1.
  61 #R #HR #I #L1 #K2 #V2 #H @(TC_ind_dx … L1 H) -L1
  62 [ #L1 #H elim (lpx_sn_inv_pair2 … H) -H /3 width=5/
  63 | #L1 #L #HL1 #_ * #K #V #HK2 #HV2 #H destruct
  64   elim (lpx_sn_inv_pair2 … HL1) -HL1 #K1 #V1 #HK1 #HV1 #H destruct
  65   lapply (HR … HV2 … HK1) -HR -HV2 #HV2 /3 width=5/
  66 ]
  67 qed-.
  68
  69 lemma TC_lpx_sn_ind: ∀R. s_rs_trans … R (lpx_sn R) →
  70                      ∀S:relation lenv.
  71                      S (⋆) (⋆) → (
  72                         ∀I,K1,K2,V1,V2.
  73                         TC … (lpx_sn R) K1 K2 → LTC … R K1 V1 V2 →
  74                         S K1 K2 → S (K1.ⓑ{I}V1) (K2.ⓑ{I}V2)
  75                      ) →
  76                      ∀L2,L1. TC … (lpx_sn R) L1 L2 → S L1 L2.
  77 #R #HR #S #IH1 #IH2 #L2 elim L2 -L2
  78 [ #X #H >(TC_lpx_sn_inv_atom2 … H) -X //
  79 | #L2 #I #V2 #IHL2 #X #H
  80   elim (TC_lpx_sn_inv_pair2 … H) // -H -HR
  81   #L1 #V1 #HL12 #HV12 #H destruct /3 width=1/
  82 ]
  83 qed-.
  84
  85 lemma TC_lpx_sn_inv_atom1: ∀R,L2. TC … (lpx_sn R) (⋆) L2 → L2 = ⋆.
  86 #R #L2 #H elim H -L2
  87 [ #L2 #H lapply (lpx_sn_inv_atom1 … H) -H //
  88 | #L #L2 #_ #HL2 #IHL1 destruct
  89   lapply (lpx_sn_inv_atom1 … HL2) -HL2 //
  90 ]
  91 qed-.
  92
  93 fact TC_lpx_sn_inv_pair1_aux: ∀R. s_rs_trans … R (lpx_sn R) →
  94                               ∀L1,L2. TC … (lpx_sn R) L1 L2 →
  95                               ∀I,K1,V1. L1 = K1.ⓑ{I}V1 →
  96                               ∃∃K2,V2. TC … (lpx_sn R) K1 K2 & LTC … R K1 V1 V2 & L2 = K2. ⓑ{I} V2.
  97 #R #HR #L1 #L2 #H @(TC_lpx_sn_ind … H) // -HR -L1 -L2
  98 [ #J #K #W #H destruct
  99 | #I #L1 #L2 #V1 #V2 #HL12 #HV12 #_ #J #K #W #H destruct /2 width=5/
 100 ]
 101 qed-.
 102
 103 lemma TC_lpx_sn_inv_pair1: ∀R. s_rs_trans … R (lpx_sn R) →
 104                            ∀I,K1,L2,V1. TC … (lpx_sn R) (K1.ⓑ{I}V1) L2 →
 105                            ∃∃K2,V2. TC … (lpx_sn R) K1 K2 & LTC … R K1 V1 V2 & L2 = K2. ⓑ{I} V2.
 106 /2 width=3 by TC_lpx_sn_inv_pair1_aux/ qed-.
 107
 108 lemma TC_lpx_sn_inv_lpx_sn_LTC: ∀R. s_rs_trans … R (lpx_sn R) →
 109                                 ∀L1,L2. TC … (lpx_sn R) L1 L2 →
 110                                 lpx_sn (LTC … R) L1 L2.
 111 #R #HR #L1 #L2 #H @(TC_lpx_sn_ind … H) // -HR -L1 -L2 /2 width=1/
 112 qed-.
 113
 114 (* Forward lemmas on transitive closure *************************************)
 115
 116 lemma TC_lpx_sn_fwd_length: ∀R,L1,L2. TC … (lpx_sn R) L1 L2 → |L1| = |L2|.
 117 #R #L1 #L2 #H elim H -L2
 118 [ #L2 #HL12 >(lpx_sn_fwd_length … HL12) -HL12 //
 119 | #L #L2 #_ #HL2 #IHL1
 120   >IHL1 -L1 >(lpx_sn_fwd_length … HL2) -HL2 //
 121 ]
 122 qed-.