matita/matita/contribs/lambdadelta/basic_2/grammar/tstc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/iso_2.ma".
  16 include "basic_2/grammar/term_simple.ma".
  17
  18 (* SAME TOP TERM CONSTRUCTOR ************************************************)
  19
  20 inductive tstc: relation term ≝
  21    | tstc_atom: ∀I. tstc (⓪{I}) (⓪{I})
  22    | tstc_pair: ∀I,V1,V2,T1,T2. tstc (②{I} V1. T1) (②{I} V2. T2)
  23 .
  24
  25 interpretation "same top constructor (term)" 'Iso T1 T2 = (tstc T1 T2).
  26
  27 (* Basic inversion lemmas ***************************************************)
  28
  29 fact tstc_inv_atom1_aux: ∀T1,T2. T1 ≃ T2 → ∀I. T1 = ⓪{I} → T2 = ⓪{I}.
  30 #T1 #T2 * -T1 -T2 //
  31 #J #V1 #V2 #T1 #T2 #I #H destruct
  32 qed.
  33
  34 (* Basic_1: was: iso_gen_sort iso_gen_lref *)
  35 lemma tstc_inv_atom1: ∀I,T2. ⓪{I} ≃ T2 → T2 = ⓪{I}.
  36 /2 width=3/ qed-.
  37
  38 fact tstc_inv_pair1_aux: ∀T1,T2. T1 ≃ T2 → ∀I,W1,U1. T1 = ②{I}W1.U1 →
  39                          ∃∃W2,U2. T2 = ②{I}W2. U2.
  40 #T1 #T2 * -T1 -T2
  41 [ #J #I #W1 #U1 #H destruct
  42 | #J #V1 #V2 #T1 #T2 #I #W1 #U1 #H destruct /2 width=3/
  43 ]
  44 qed.
  45
  46 (* Basic_1: was: iso_gen_head *)
  47 lemma tstc_inv_pair1: ∀I,W1,U1,T2. ②{I}W1.U1 ≃ T2 →
  48                       ∃∃W2,U2. T2 = ②{I}W2. U2.
  49 /2 width=5/ qed-.
  50
  51 fact tstc_inv_atom2_aux: ∀T1,T2. T1 ≃ T2 → ∀I. T2 = ⓪{I} → T1 = ⓪{I}.
  52 #T1 #T2 * -T1 -T2 //
  53 #J #V1 #V2 #T1 #T2 #I #H destruct
  54 qed.
  55
  56 lemma tstc_inv_atom2: ∀I,T1. T1 ≃ ⓪{I} → T1 = ⓪{I}.
  57 /2 width=3/ qed-.
  58
  59 fact tstc_inv_pair2_aux: ∀T1,T2. T1 ≃ T2 → ∀I,W2,U2. T2 = ②{I}W2.U2 →
  60                          ∃∃W1,U1. T1 = ②{I}W1. U1.
  61 #T1 #T2 * -T1 -T2
  62 [ #J #I #W2 #U2 #H destruct
  63 | #J #V1 #V2 #T1 #T2 #I #W2 #U2 #H destruct /2 width=3/
  64 ]
  65 qed.
  66
  67 lemma tstc_inv_pair2: ∀I,T1,W2,U2. T1 ≃ ②{I}W2.U2 →
  68                       ∃∃W1,U1. T1 = ②{I}W1. U1.
  69 /2 width=5/ qed-.
  70
  71 (* Basic properties *********************************************************)
  72
  73 (* Basic_1: was: iso_refl *)
  74 lemma tstc_refl: ∀T. T ≃ T.
  75 #T elim T -T //
  76 qed.
  77
  78 lemma tstc_sym: ∀T1,T2. T1 ≃ T2 → T2 ≃ T1.
  79 #T1 #T2 #H elim H -T1 -T2 //
  80 qed.
  81
  82 lemma tstc_dec: ∀T1,T2. Decidable (T1 ≃ T2).
  83 * #I1 [2: #V1 #T1 ] * #I2 [2,4: #V2 #T2 ]
  84 [ elim (item2_eq_dec I1 I2) #HI12
  85   [ destruct /2 width=1/
  86   | @or_intror #H
  87     elim (tstc_inv_pair1 … H) -H #V #T #H destruct /2 width=1/
  88   ]
  89 | @or_intror #H
  90   lapply (tstc_inv_atom1 … H) -H #H destruct
  91 | @or_intror #H
  92   lapply (tstc_inv_atom2 … H) -H #H destruct
  93 | elim (item0_eq_dec I1 I2) #HI12
  94   [ destruct /2 width=1/
  95   | @or_intror #H
  96     lapply (tstc_inv_atom2 … H) -H #H destruct /2 width=1/
  97   ]
  98 ]
  99 qed.
 100
 101 lemma simple_tstc_repl_dx: ∀T1,T2. T1 ≃ T2 → 𝐒⦃T1⦄ → 𝐒⦃T2⦄.
 102 #T1 #T2 * -T1 -T2 //
 103 #I #V1 #V2 #T1 #T2 #H
 104 elim (simple_inv_pair … H) -H #J #H destruct //
 105 qed. (**) (* remove from index *)
 106
 107 lemma simple_tstc_repl_sn: ∀T1,T2. T1 ≃ T2 → 𝐒⦃T2⦄ → 𝐒⦃T1⦄.
 108 /3 width=3/ qed-.