matita/matita/contribs/lambdadelta/basic_2/i_static/tc_lfxs_fqup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/lfxs_fqup.ma".
  16 include "basic_2/i_static/tc_lfxs.ma".
  17
  18 (* ITERATED EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ***)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma tc_lfxs_refl: ∀R. c_reflexive … R →
  23                     ∀T. reflexive … (tc_lfxs R T).
  24 /3 width=1 by lfxs_refl, inj/ qed.
  25
  26 (* Basic_2A1: uses: TC_lpx_sn_pair TC_lpx_sn_pair_refl *)
  27 lemma tc_lfxs_pair_refl: ∀R. c_reflexive … R →
  28                          ∀L,V1,V2. CTC … R L V1 V2 → ∀I,T. L.ⓑ{I}V1 ⪤**[R, T] L.ⓑ{I}V2.
  29 #R #HR #L #V1 #V2 #H elim H -V2
  30 /3 width=3 by tc_lfxs_step_dx, lfxs_pair_refl, inj/
  31 qed.
  32
  33 lemma tc_lfxs_tc: ∀R,L1,L2,T,f. 𝐈⦃f⦄ → TC … (lexs cfull (cext2 R) f) L1 L2 →
  34                   L1 ⪤**[R, T] L2.
  35 #R #L1 #L2 #T #f #Hf #H elim H -L2
  36 [ elim (frees_total L1 T) | #L elim (frees_total L T) ]
  37 /5 width=7 by lexs_sdj, tc_lfxs_step_dx, sdj_isid_sn, inj, ex2_intro/
  38 qed.
  39
  40 (* Advanced eliminators *****************************************************)
  41
  42 lemma tc_lfxs_ind_sn: ∀R. c_reflexive … R →
  43                       ∀L1,T. ∀Q:predicate …. Q L1 →
  44                       (∀L,L2. L1 ⪤**[R, T] L → L ⪤*[R, T] L2 → Q L → Q L2) →
  45                       ∀L2. L1 ⪤**[R, T] L2 → Q L2.
  46 #R #HR #L1 #T #Q #HL1 #IHL1 #L2 #HL12
  47 @(TC_star_ind … HL1 IHL1 … HL12) /2 width=1 by lfxs_refl/
  48 qed-.
  49
  50 lemma tc_lfxs_ind_dx: ∀R. c_reflexive … R →
  51                       ∀L2,T. ∀Q:predicate …. Q L2 →
  52                       (∀L1,L. L1 ⪤*[R, T] L → L ⪤**[R, T] L2 → Q L → Q L1) →
  53                       ∀L1. L1 ⪤**[R, T] L2 → Q L1.
  54 #R #HR #L2 #Q #HL2 #IHL2 #L1 #HL12
  55 @(TC_star_ind_dx … HL2 IHL2 … HL12) /2 width=4 by lfxs_refl/
  56 qed-.
  57
  58 (* Advanced inversion lemmas ************************************************)
  59
  60 lemma tc_lfxs_inv_bind_void: ∀R. c_reflexive … R →
  61                              ∀p,I,L1,L2,V,T. L1 ⪤**[R, ⓑ{p,I}V.T] L2 →
  62                              L1 ⪤**[R, V] L2 ∧ L1.ⓧ ⪤**[R, T] L2.ⓧ.
  63 #R #HR #p #I #L1 #L2 #V #T #H @(tc_lfxs_ind_sn … HR … H) -L2
  64 [ /3 width=1 by tc_lfxs_refl, conj/
  65 | #L #L2 #_ #H * elim (lfxs_inv_bind_void … H) -H /3 width=3 by tc_lfxs_step_dx, conj/
  66 ]
  67 qed-.
  68
  69 (* Advanced forward lemmas **************************************************)
  70
  71 lemma tc_lfxs_fwd_bind_dx_void: ∀R. c_reflexive … R →
  72                                 ∀p,I,L1,L2,V,T. L1 ⪤**[R, ⓑ{p,I}V.T] L2 →
  73                                 L1.ⓧ ⪤**[R, T] L2.ⓧ.
  74 #R #HR #p #I #L1 #L2 #V #T #H elim (tc_lfxs_inv_bind_void … H) -H //
  75 qed-.