matita/matita/contribs/lambdadelta/basic_2/i_static/tc_lfxs_fqup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/lfxs_fqup.ma".
  16 include "basic_2/i_static/tc_lfxs.ma".
  17
  18 (* ITERATED EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ***)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma tc_lfxs_refl: ∀R. c_reflexive … R →
  23                     ∀T. reflexive … (tc_lfxs R T).
  24 /3 width=1 by lfxs_refl, inj/ qed.
  25
  26 (* Basic_2A1: uses: TC_lpx_sn_pair TC_lpx_sn_pair_refl *)
  27 lemma tc_lfxs_pair_refl: ∀R. c_reflexive … R →
  28                          ∀L,V1,V2. LTC … R L V1 V2 → ∀I,T. L.ⓑ{I}V1 ⪤**[R, T] L.ⓑ{I}V2.
  29 #R #HR #L #V1 #V2 #H elim H -V2
  30 /3 width=3 by tc_lfxs_step_dx, lfxs_pair_refl, inj/
  31 qed.
  32
  33 (* Advanced eliminators *****************************************************)
  34
  35 lemma tc_lfxs_ind_sn: ∀R. c_reflexive … R →
  36                       ∀L1,T. ∀R0:predicate …. R0 L1 →
  37                       (∀L,L2. L1 ⪤**[R, T] L → L ⪤*[R, T] L2 → R0 L → R0 L2) →
  38                       ∀L2. L1 ⪤**[R, T] L2 → R0 L2.
  39 #R #HR #L1 #T #R0 #HL1 #IHL1 #L2 #HL12
  40 @(TC_star_ind … HL1 IHL1 … HL12) /2 width=1 by lfxs_refl/
  41 qed-.
  42
  43 lemma tc_lfxs_ind_dx: ∀R. c_reflexive … R →
  44                       ∀L2,T. ∀R0:predicate …. R0 L2 →
  45                       (∀L1,L. L1 ⪤*[R, T] L → L ⪤**[R, T] L2 → R0 L → R0 L1) →
  46                       ∀L1. L1 ⪤**[R, T] L2 → R0 L1.
  47 #R #HR #L2 #R0 #HL2 #IHL2 #L1 #HL12
  48 @(TC_star_ind_dx … HL2 IHL2 … HL12) /2 width=4 by lfxs_refl/
  49 qed-.
  50
  51 (* Advanced inversion lemmas ************************************************)
  52
  53 lemma tc_lfxs_inv_bind_void: ∀R. c_reflexive … R →
  54                              ∀p,I,L1,L2,V,T. L1 ⪤**[R, ⓑ{p,I}V.T] L2 →
  55                              L1 ⪤**[R, V] L2 ∧ L1.ⓧ ⪤**[R, T] L2.ⓧ.
  56 #R #HR #p #I #L1 #L2 #V #T #H @(tc_lfxs_ind_sn … HR … H) -L2
  57 [ /3 width=1 by tc_lfxs_refl, conj/
  58 | #L #L2 #_ #H * elim (lfxs_inv_bind_void … H) -H /3 width=3 by tc_lfxs_step_dx, conj/
  59 ]
  60 qed-.
  61
  62 (* Advanced forward lemmas **************************************************)
  63
  64 lemma tc_lfxs_fwd_bind_dx_void: ∀R. c_reflexive … R →
  65                                 ∀p,I,L1,L2,V,T. L1 ⪤**[R, ⓑ{p,I}V.T] L2 →
  66                                 L1.ⓧ ⪤**[R, T] L2.ⓧ.
  67 #R #HR #p #I #L1 #L2 #V #T #H elim (tc_lfxs_inv_bind_void … H) -H //
  68 qed-.