matita/matita/contribs/lambdadelta/basic_2/i_static/tc_lfxs_lex.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/syntax/ext2_tc.ma".
  16 include "basic_2/relocation/lexs_tc.ma".
  17 include "basic_2/relocation/lex.ma".
  18 include "basic_2/static/lfeq_fqup.ma".
  19 include "basic_2/static/lfeq_lfeq.ma".
  20 include "basic_2/i_static/tc_lfxs_fqup.ma".
  21
  22 (* ITERATED EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ***)
  23
  24 (* Properties with generic extension of a context sensitive relation ********)
  25
  26 lemma tc_lfxs_lex: ∀R. c_reflexive … R →
  27                    ∀L1,L2,T. L1 ⪤[LTC … R] L2 → L1 ⪤**[R, T] L2.
  28 #R #HR #L1 #L2 #T *
  29 /5 width=7 by tc_lfxs_tc, lexs_inv_tc_dx, lexs_co, ext2_inv_tc, ext2_refl/
  30 qed.
  31
  32 lemma tc_lfxs_lex_lfeq: ∀R. c_reflexive … R →
  33                         ∀L1,L. L1 ⪤[LTC … R] L → ∀L2,T. L ≡[T] L2 →
  34                         L1 ⪤**[R, T] L2.
  35 /3 width=3 by tc_lfxs_lex, tc_lfxs_step_dx, lfeq_fwd_lfxs/ qed.
  36
  37 (* Inversion lemmas with generic extension of a context sensitive relation **)
  38
  39 lemma tc_lfxs_inv_lex_lfeq: ∀R. c_reflexive … R →
  40                             lexs_frees_confluent (cext2 R) cfull →
  41                             s_rs_transitive_isid cfull (cext2 R) →
  42                             lfeq_transitive R →
  43                             ∀L1,L2,T. L1 ⪤**[R, T] L2 →
  44                             ∃∃L. L1 ⪤[LTC … R] L & L ≡[T] L2.
  45 #R #H1R #H2R #H3R #H4R #L1 #L2 #T #H
  46 @(tc_lfxs_ind_sn … H1R … H) -H -L2
  47 [ /4 width=3 by lfeq_refl, lex_refl, inj, ex2_intro/
  48 | #L0 #L2 #_ #HL02 * #L * #f0 #Hf0 #HL1 #HL0
  49   lapply (lfeq_lfxs_trans … HL0 … HL02) -L0 // * #f1 #Hf1 #HL2
  50   elim (lexs_sdj_split … ceq_ext … HL2 f0 ?) -HL2
  51   [ #L0 #HL0 #HL02 |*: /2 width=1 by ext2_refl, sdj_isid_dx/ ]
  52   lapply (lexs_sdj … HL0 f1 ?) /2 width=1 by sdj_isid_sn/ #H
  53   elim (H2R … Hf1 … H) -H #f2 #Hf2 #Hf21
  54   lapply (sle_lexs_trans … HL02 … Hf21) -f1 // #HL02
  55   lapply (lexs_co ?? cfull (LTC … (cext2 R)) … HL1) -HL1 /2 width=1 by ext2_inv_tc/ #HL1
  56   /8 width=11 by lexs_inv_tc_dx, lexs_tc_dx, lexs_co, ext2_tc, ext2_refl, step, ex2_intro/ (**) (* full auto too slow *)
  57 ]
  58 qed-.