matita/matita/contribs/lambdadelta/basic_2/multiple/mr2.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/rat_3.ma".
  16 include "basic_2/grammar/term_vector.ma".
  17
  18 (* MULTIPLE RELOCATION WITH PAIRS *******************************************)
  19
  20 inductive at: list2 nat nat → relation nat ≝
  21 | at_nil: ∀i. at (◊) i i
  22 | at_lt : ∀des,d,e,i1,i2. i1 < d →
  23           at des i1 i2 → at ({d, e} @ des) i1 i2
  24 | at_ge : ∀des,d,e,i1,i2. d ≤ i1 →
  25           at des (i1 + e) i2 → at ({d, e} @ des) i1 i2
  26 .
  27
  28 interpretation "application (multiple relocation with pairs)"
  29    'RAt i1 des i2 = (at des i1 i2).
  30
  31 (* Basic inversion lemmas ***************************************************)
  32
  33 fact at_inv_nil_aux: ∀des,i1,i2. @⦃i1, des⦄ ≡ i2 → des = ◊ → i1 = i2.
  34 #des #i1 #i2 * -des -i1 -i2
  35 [ //
  36 | #des #d #e #i1 #i2 #_ #_ #H destruct
  37 | #des #d #e #i1 #i2 #_ #_ #H destruct
  38 ]
  39 qed-.
  40
  41 lemma at_inv_nil: ∀i1,i2. @⦃i1, ◊⦄ ≡ i2 → i1 = i2.
  42 /2 width=3 by at_inv_nil_aux/ qed-.
  43
  44 fact at_inv_cons_aux: ∀des,i1,i2. @⦃i1, des⦄ ≡ i2 →
  45                       ∀d,e,des0. des = {d, e} @ des0 →
  46                       i1 < d ∧ @⦃i1, des0⦄ ≡ i2 ∨
  47                       d ≤ i1 ∧ @⦃i1 + e, des0⦄ ≡ i2.
  48 #des #i1 #i2 * -des -i1 -i2
  49 [ #i #d #e #des #H destruct
  50 | #des1 #d1 #e1 #i1 #i2 #Hid1 #Hi12 #d2 #e2 #des2 #H destruct /3 width=1 by or_introl, conj/
  51 | #des1 #d1 #e1 #i1 #i2 #Hdi1 #Hi12 #d2 #e2 #des2 #H destruct /3 width=1 by or_intror, conj/
  52 ]
  53 qed-.
  54
  55 lemma at_inv_cons: ∀des,d,e,i1,i2. @⦃i1, {d, e} @ des⦄ ≡ i2 →
  56                    i1 < d ∧ @⦃i1, des⦄ ≡ i2 ∨
  57                    d ≤ i1 ∧ @⦃i1 + e, des⦄ ≡ i2.
  58 /2 width=3 by at_inv_cons_aux/ qed-.
  59
  60 lemma at_inv_cons_lt: ∀des,d,e,i1,i2. @⦃i1, {d, e} @ des⦄ ≡ i2 →
  61                       i1 < d → @⦃i1, des⦄ ≡ i2.
  62 #des #d #e #i1 #e2 #H
  63 elim (at_inv_cons … H) -H * // #Hdi1 #_ #Hi1d
  64 lapply (le_to_lt_to_lt … Hdi1 Hi1d) -Hdi1 -Hi1d #Hd
  65 elim (lt_refl_false … Hd)
  66 qed-.
  67
  68 lemma at_inv_cons_ge: ∀des,d,e,i1,i2. @⦃i1, {d, e} @ des⦄ ≡ i2 →
  69                       d ≤ i1 → @⦃i1 + e, des⦄ ≡ i2.
  70 #des #d #e #i1 #e2 #H
  71 elim (at_inv_cons … H) -H * // #Hi1d #_ #Hdi1
  72 lapply (le_to_lt_to_lt … Hdi1 Hi1d) -Hdi1 -Hi1d #Hd
  73 elim (lt_refl_false … Hd)
  74 qed-.