matita/matita/contribs/lambdadelta/basic_2/multiple/mr2_minus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_minus.ma".
  16 include "basic_2/notation/relations/rminus_3.ma".
  17 include "basic_2/multiple/mr2.ma".
  18
  19 (* MULTIPLE RELOCATION WITH PAIRS *******************************************)
  20
  21 inductive minuss: nat → relation (list2 ynat nat) ≝
  22 | minuss_nil: ∀i. minuss i (◊) (◊)
  23 | minuss_lt : ∀cs1,cs2,l,m,i. yinj i < l → minuss i cs1 cs2 →
  24               minuss i ({l, m} @ cs1) ({l - i, m} @ cs2)
  25 | minuss_ge : ∀cs1,cs2,l,m,i. l ≤ yinj i → minuss (m + i) cs1 cs2 →
  26               minuss i ({l, m} @ cs1) cs2
  27 .
  28
  29 interpretation "minus (multiple relocation with pairs)"
  30    'RMinus cs1 i cs2 = (minuss i cs1 cs2).
  31
  32 (* Basic inversion lemmas ***************************************************)
  33
  34 fact minuss_inv_nil1_aux: ∀cs1,cs2,i. cs1 ▭ i ≡ cs2 → cs1 = ◊ → cs2 = ◊.
  35 #cs1 #cs2 #i * -cs1 -cs2 -i
  36 [ //
  37 | #cs1 #cs2 #l #m #i #_ #_ #H destruct
  38 | #cs1 #cs2 #l #m #i #_ #_ #H destruct
  39 ]
  40 qed-.
  41
  42 lemma minuss_inv_nil1: ∀cs2,i. ◊ ▭ i ≡ cs2 → cs2 = ◊.
  43 /2 width=4 by minuss_inv_nil1_aux/ qed-.
  44
  45 fact minuss_inv_cons1_aux: ∀cs1,cs2,i. cs1 ▭ i ≡ cs2 →
  46                            ∀l,m,cs. cs1 = {l, m} @ cs →
  47                            l ≤ i ∧ cs ▭ m + i ≡ cs2 ∨
  48                            ∃∃cs0. i < l & cs ▭ i ≡ cs0 &
  49                                    cs2 = {l - i, m} @ cs0.
  50 #cs1 #cs2 #i * -cs1 -cs2 -i
  51 [ #i #l #m #cs #H destruct
  52 | #cs1 #cs #l1 #m1 #i1 #Hil1 #Hcs #l2 #m2 #cs2 #H destruct /3 width=3 by ex3_intro, or_intror/
  53 | #cs1 #cs #l1 #m1 #i1 #Hli1 #Hcs #l2 #m2 #cs2 #H destruct /3 width=1 by or_introl, conj/
  54 ]
  55 qed-.
  56
  57 lemma minuss_inv_cons1: ∀cs1,cs2,l,m,i. {l, m} @ cs1 ▭ i ≡ cs2 →
  58                         l ≤ i ∧ cs1 ▭ m + i ≡ cs2 ∨
  59                         ∃∃cs. i < l & cs1 ▭ i ≡ cs &
  60                                cs2 = {l - i, m} @ cs.
  61 /2 width=3 by minuss_inv_cons1_aux/ qed-.
  62
  63 lemma minuss_inv_cons1_ge: ∀cs1,cs2,l,m,i. {l, m} @ cs1 ▭ i ≡ cs2 →
  64                            l ≤ i → cs1 ▭ m + i ≡ cs2.
  65 #cs1 #cs2 #l #m #i #H
  66 elim (minuss_inv_cons1 … H) -H * // #cs #Hil #_ #_ #Hli
  67 elim (ylt_yle_false … Hil Hli)
  68 qed-.
  69
  70 lemma minuss_inv_cons1_lt: ∀cs1,cs2,l,m,i. {l, m} @ cs1 ▭ i ≡ cs2 →
  71                            i < l →
  72                            ∃∃cs. cs1 ▭ i ≡ cs & cs2 = {l - i, m} @ cs.
  73 #cs1 #cs2 #l #m #i #H elim (minuss_inv_cons1 … H) -H * /2 width=3 by ex2_intro/
  74 #Hli #_ #Hil elim (ylt_yle_false … Hil Hli)
  75 qed-.