matita/matita/contribs/lambdadelta/basic_2/reduction/cnx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/prednormal_5.ma".
  16 include "basic_2/reduction/cnr.ma".
  17 include "basic_2/reduction/cpx.ma".
  18
  19 (* NORMAL TERMS FOR CONTEXT-SENSITIVE EXTENDED REDUCTION ********************)
  20
  21 definition cnx: ∀h. sd h → relation3 genv lenv term ≝
  22                 λh,g,G,L. NF … (cpx h g G L) (eq …).
  23
  24 interpretation
  25    "normality for context-sensitive extended reduction (term)"
  26    'PRedNormal h g L T = (cnx h g L T).
  27
  28 (* Basic inversion lemmas ***************************************************)
  29
  30 lemma cnx_inv_sort: ∀h,g,G,L,k. ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃⋆k⦄ → deg h g k 0.
  31 #h #g #G #L #k #H elim (deg_total h g k)
  32 #l @(nat_ind_plus … l) -l // #l #_ #Hkl
  33 lapply (H (⋆(next h k)) ?) -H /2 width=2 by cpx_st/ -L -l #H destruct -H -e0 (**) (* destruct does not remove some premises *)
  34 lapply (next_lt h k) >e1 -e1 #H elim (lt_refl_false … H)
  35 qed-.
  36
  37 lemma cnx_inv_delta: ∀h,g,I,G,L,K,V,i. ⬇[i] L ≡ K.ⓑ{I}V → ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃#i⦄ → ⊥.
  38 #h #g #I #G #L #K #V #i #HLK #H
  39 elim (lift_total V 0 (i+1)) #W #HVW
  40 lapply (H W ?) -H [ /3 width=7 by cpx_delta/ ] -HLK #H destruct
  41 elim (lift_inv_lref2_be … HVW) -HVW //
  42 qed-.
  43
  44 lemma cnx_inv_abst: ∀h,g,a,G,L,V,T. ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃ⓛ{a}V.T⦄ →
  45                     ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃V⦄ ∧ ⦃G, L.ⓛV⦄ ⊢ ➡[h, g] 𝐍⦃T⦄.
  46 #h #g #a #G #L #V1 #T1 #HVT1 @conj
  47 [ #V2 #HV2 lapply (HVT1 (ⓛ{a}V2.T1) ?) -HVT1 /2 width=2 by cpx_pair_sn/ -HV2 #H destruct //
  48 | #T2 #HT2 lapply (HVT1 (ⓛ{a}V1.T2) ?) -HVT1 /2 width=2 by cpx_bind/ -HT2 #H destruct //
  49 ]
  50 qed-.
  51
  52 lemma cnx_inv_abbr: ∀h,g,G,L,V,T. ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃-ⓓV.T⦄ →
  53                     ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃V⦄ ∧ ⦃G, L.ⓓV⦄ ⊢ ➡[h, g] 𝐍⦃T⦄.
  54 #h #g #G #L #V1 #T1 #HVT1 @conj
  55 [ #V2 #HV2 lapply (HVT1 (-ⓓV2.T1) ?) -HVT1 /2 width=2 by cpx_pair_sn/ -HV2 #H destruct //
  56 | #T2 #HT2 lapply (HVT1 (-ⓓV1.T2) ?) -HVT1 /2 width=2 by cpx_bind/ -HT2 #H destruct //
  57 ]
  58 qed-.
  59
  60 lemma cnx_inv_zeta: ∀h,g,G,L,V,T. ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃+ⓓV.T⦄ → ⊥.
  61 #h #g #G #L #V #T #H elim (is_lift_dec T 0 1)
  62 [ * #U #HTU
  63   lapply (H U ?) -H /2 width=3 by cpx_zeta/ #H destruct
  64   elim (lift_inv_pair_xy_y … HTU)
  65 | #HT
  66   elim (cpr_delift G(⋆) V T (⋆.ⓓV) 0) // #T2 #T1 #HT2 #HT12
  67   lapply (H (+ⓓV.T2) ?) -H /5 width=1 by cpr_cpx, tpr_cpr, cpr_bind/ -HT2
  68   #H destruct /3 width=2 by ex_intro/
  69 ]
  70 qed-.
  71
  72 lemma cnx_inv_appl: ∀h,g,G,L,V,T. ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃ⓐV.T⦄ →
  73                     ∧∧ ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃V⦄ & ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃T⦄ & 𝐒⦃T⦄.
  74 #h #g #G #L #V1 #T1 #HVT1 @and3_intro
  75 [ #V2 #HV2 lapply (HVT1 (ⓐV2.T1) ?) -HVT1 /2 width=1 by cpx_pair_sn/ -HV2 #H destruct //
  76 | #T2 #HT2 lapply (HVT1 (ⓐV1.T2) ?) -HVT1 /2 width=1 by cpx_flat/ -HT2 #H destruct //
  77 | generalize in match HVT1; -HVT1 elim T1 -T1 * // #a * #W1 #U1 #_ #_ #H
  78   [ elim (lift_total V1 0 1) #V2 #HV12
  79     lapply (H (ⓓ{a}W1.ⓐV2.U1) ?) -H /3 width=3 by cpr_cpx, cpr_theta/ -HV12 #H destruct
  80   | lapply (H (ⓓ{a}ⓝW1.V1.U1) ?) -H /3 width=1 by cpr_cpx, cpr_beta/ #H destruct
  81   ]
  82 ]
  83 qed-.
  84
  85 lemma cnx_inv_eps: ∀h,g,G,L,V,T. ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃ⓝV.T⦄ → ⊥.
  86 #h #g #G #L #V #T #H lapply (H T ?) -H
  87 /2 width=4 by cpx_eps, discr_tpair_xy_y/
  88 qed-.
  89
  90 (* Basic forward lemmas *****************************************************)
  91
  92 lemma cnx_fwd_cnr: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃T⦄ → ⦃G, L⦄ ⊢ ➡ 𝐍⦃T⦄.
  93 #h #g #G #L #T #H #U #HTU
  94 @H /2 width=1 by cpr_cpx/ (**) (* auto fails because a δ-expansion gets in the way *)
  95 qed-.
  96
  97 (* Basic properties *********************************************************)
  98
  99 lemma cnx_sort: ∀h,g,G,L,k. deg h g k 0 → ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃⋆k⦄.
 100 #h #g #G #L #k #Hk #X #H elim (cpx_inv_sort1 … H) -H // * #l #Hkl #_
 101 lapply (deg_mono … Hkl Hk) -h -L <plus_n_Sm #H destruct
 102 qed.
 103
 104 lemma cnx_sort_iter: ∀h,g,G,L,k,l. deg h g k l → ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃⋆((next h)^l k)⦄.
 105 #h #g #G #L #k #l #Hkl
 106 lapply (deg_iter … l Hkl) -Hkl <minus_n_n /2 width=6 by cnx_sort/
 107 qed.
 108
 109 lemma cnx_lref_free: ∀h,g,G,L,i. |L| ≤ i → ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃#i⦄.
 110 #h #g #G #L #i #Hi #X #H elim (cpx_inv_lref1 … H) -H // *
 111 #I #K #V1 #V2 #HLK lapply (drop_fwd_length_lt2 … HLK) -HLK
 112 #H elim (lt_refl_false i) /2 width=3 by lt_to_le_to_lt/
 113 qed.
 114
 115 lemma cnx_lref_atom: ∀h,g,G,L,i. ⬇[i] L ≡ ⋆ → ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃#i⦄.
 116 #h #g #G #L #i #HL @cnx_lref_free >(drop_fwd_length … HL) -HL //
 117 qed.
 118
 119 lemma cnx_abst: ∀h,g,a,G,L,W,T. ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃W⦄ → ⦃G, L.ⓛW⦄ ⊢ ➡[h, g] 𝐍⦃T⦄ →
 120                 ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃ⓛ{a}W.T⦄.
 121 #h #g #a #G #L #W #T #HW #HT #X #H
 122 elim (cpx_inv_abst1 … H) -H #W0 #T0 #HW0 #HT0 #H destruct
 123 >(HW … HW0) -W0 >(HT … HT0) -T0 //
 124 qed.
 125
 126 lemma cnx_appl_simple: ∀h,g,G,L,V,T. ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃V⦄ → ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃T⦄ → 𝐒⦃T⦄ →
 127                        ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃ⓐV.T⦄.
 128 #h #g #G #L #V #T #HV #HT #HS #X #H
 129 elim (cpx_inv_appl1_simple … H) -H // #V0 #T0 #HV0 #HT0 #H destruct
 130 >(HV … HV0) -V0 >(HT … HT0) -T0 //
 131 qed.
 132
 133 axiom cnx_dec: ∀h,g,G,L,T1. ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃T1⦄ ∨
 134                ∃∃T2. ⦃G, L⦄ ⊢ T1 ➡[h, g] T2 & (T1 = T2 → ⊥).