matita/matita/contribs/lambdadelta/basic_2/reduction/cpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/pred_4.ma".
  16 include "basic_2/grammar/genv.ma".
  17 include "basic_2/grammar/cl_shift.ma".
  18 include "basic_2/relocation/ldrop_append.ma".
  19 include "basic_2/relocation/lsubr.ma".
  20
  21 (* CONTEXT-SENSITIVE PARALLEL REDUCTION FOR TERMS ***************************)
  22
  23 (* activate genv *)
  24 (* Basic_1: includes: pr0_delta1 pr2_delta1 pr2_thin_dx *)
  25 (* Note: cpr_flat: does not hold in basic_1 *)
  26 inductive cpr: relation4 genv lenv term term ≝
  27 | cpr_atom : ∀I,G,L. cpr G L (⓪{I}) (⓪{I})
  28 | cpr_delta: ∀G,L,K,V,V2,W2,i.
  29              ⇩[i] L ≡ K. ⓓV → cpr G K V V2 →
  30              ⇧[0, i + 1] V2 ≡ W2 → cpr G L (#i) W2
  31 | cpr_bind : ∀a,I,G,L,V1,V2,T1,T2.
  32              cpr G L V1 V2 → cpr G (L.ⓑ{I}V1) T1 T2 →
  33              cpr G L (ⓑ{a,I}V1.T1) (ⓑ{a,I}V2.T2)
  34 | cpr_flat : ∀I,G,L,V1,V2,T1,T2.
  35              cpr G L V1 V2 → cpr G L T1 T2 →
  36              cpr G L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  37 | cpr_zeta : ∀G,L,V,T1,T,T2. cpr G (L.ⓓV) T1 T →
  38              ⇧[0, 1] T2 ≡ T → cpr G L (+ⓓV.T1) T2
  39 | cpr_tau  : ∀G,L,V,T1,T2. cpr G L T1 T2 → cpr G L (ⓝV.T1) T2
  40 | cpr_beta : ∀a,G,L,V1,V2,W1,W2,T1,T2.
  41              cpr G L V1 V2 → cpr G L W1 W2 → cpr G (L.ⓛW1) T1 T2 →
  42              cpr G L (ⓐV1.ⓛ{a}W1.T1) (ⓓ{a}ⓝW2.V2.T2)
  43 | cpr_theta: ∀a,G,L,V1,V,V2,W1,W2,T1,T2.
  44              cpr G L V1 V → ⇧[0, 1] V ≡ V2 → cpr G L W1 W2 → cpr G (L.ⓓW1) T1 T2 →
  45              cpr G L (ⓐV1.ⓓ{a}W1.T1) (ⓓ{a}W2.ⓐV2.T2)
  46 .
  47
  48 interpretation "context-sensitive parallel reduction (term)"
  49    'PRed G L T1 T2 = (cpr G L T1 T2).
  50
  51 (* Basic properties *********************************************************)
  52
  53 lemma lsubr_cpr_trans: ∀G. lsub_trans … (cpr G) lsubr.
  54 #G #L1 #T1 #T2 #H elim H -G -L1 -T1 -T2
  55 [ //
  56 | #G #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  57   elim (lsubr_fwd_ldrop2_abbr … HL12 … HLK1) -L1 *
  58   /3 width=6 by cpr_delta/
  59 |3,7: /4 width=1 by lsubr_bind, cpr_bind, cpr_beta/
  60 |4,6: /3 width=1 by cpr_flat, cpr_tau/
  61 |5,8: /4 width=3 by lsubr_bind, cpr_zeta, cpr_theta/
  62 ]
  63 qed-.
  64
  65 (* Basic_1: was by definition: pr2_free *)
  66 lemma tpr_cpr: ∀G,T1,T2. ⦃G, ⋆⦄ ⊢ T1 ➡ T2 → ∀L. ⦃G, L⦄ ⊢ T1 ➡ T2.
  67 #G #T1 #T2 #HT12 #L
  68 lapply (lsubr_cpr_trans … HT12 L ?) //
  69 qed.
  70
  71 (* Basic_1: includes by definition: pr0_refl *)
  72 lemma cpr_refl: ∀G,T,L. ⦃G, L⦄ ⊢ T ➡ T.
  73 #G #T elim T -T // * /2 width=1 by cpr_bind, cpr_flat/
  74 qed.
  75
  76 (* Basic_1: was: pr2_head_1 *)
  77 lemma cpr_pair_sn: ∀I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡ V2 →
  78                    ∀T. ⦃G, L⦄ ⊢ ②{I}V1.T ➡ ②{I}V2.T.
  79 * /2 width=1 by cpr_bind, cpr_flat/ qed.
  80
  81 lemma cpr_delift: ∀G,K,V,T1,L,d. ⇩[d] L ≡ (K.ⓓV) →
  82                   ∃∃T2,T. ⦃G, L⦄ ⊢ T1 ➡ T2 & ⇧[d, 1] T ≡ T2.
  83 #G #K #V #T1 elim T1 -T1
  84 [ * /2 width=4 by cpr_atom, lift_sort, lift_gref, ex2_2_intro/
  85   #i #L #d #HLK elim (lt_or_eq_or_gt i d)
  86   #Hid [1,3: /3 width=4 by cpr_atom, lift_lref_ge_minus, lift_lref_lt, ex2_2_intro/ ]
  87   destruct
  88   elim (lift_total V 0 (i+1)) #W #HVW
  89   elim (lift_split … HVW i i) /3 width=6 by cpr_delta, ex2_2_intro/
  90 | * [ #a ] #I #W1 #U1 #IHW1 #IHU1 #L #d #HLK
  91   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  92   [ elim (IHU1 (L. ⓑ{I}W1) (d+1)) -IHU1 /3 width=9 by ldrop_drop, cpr_bind, lift_bind, ex2_2_intro/
  93   | elim (IHU1 … HLK) -IHU1 -HLK /3 width=8 by cpr_flat, lift_flat, ex2_2_intro/
  94   ]
  95 ]
  96 qed-.
  97
  98 lemma cpr_append: ∀G. l_appendable_sn … (cpr G).
  99 #G #K #T1 #T2 #H elim H -G -K -T1 -T2
 100 /2 width=3 by cpr_bind, cpr_flat, cpr_zeta, cpr_tau, cpr_beta, cpr_theta/
 101 #G #K #K0 #V1 #V2 #W2 #i #HK0 #_ #HVW2 #IHV12 #L
 102 lapply (ldrop_fwd_length_lt2 … HK0) #H
 103 @(cpr_delta … (L@@K0) V1 … HVW2) //
 104 @(ldrop_O1_append_sn_le … HK0) /2 width=2 by lt_to_le/ (**) (* /3/ does not work *)
 105 qed.
 106
 107 (* Basic inversion lemmas ***************************************************)
 108
 109 fact cpr_inv_atom1_aux: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → ∀I. T1 = ⓪{I} →
 110                         T2 = ⓪{I} ∨
 111                         ∃∃K,V,V2,i. ⇩[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 112                                     ⇧[O, i + 1] V2 ≡ T2 & I = LRef i.
 113 #G #L #T1 #T2 * -G -L -T1 -T2
 114 [ #I #G #L #J #H destruct /2 width=1 by or_introl/
 115 | #L #G #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #J #H destruct /3 width=8 by ex4_4_intro, or_intror/
 116 | #a #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
 117 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
 118 | #G #L #V #T1 #T #T2 #_ #_ #J #H destruct
 119 | #G #L #V #T1 #T2 #_ #J #H destruct
 120 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #J #H destruct
 121 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #J #H destruct
 122 ]
 123 qed-.
 124
 125 lemma cpr_inv_atom1: ∀I,G,L,T2. ⦃G, L⦄ ⊢ ⓪{I} ➡ T2 →
 126                      T2 = ⓪{I} ∨
 127                      ∃∃K,V,V2,i. ⇩[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 128                                  ⇧[O, i + 1] V2 ≡ T2 & I = LRef i.
 129 /2 width=3 by cpr_inv_atom1_aux/ qed-.
 130
 131 (* Basic_1: includes: pr0_gen_sort pr2_gen_sort *)
 132 lemma cpr_inv_sort1: ∀G,L,T2,k. ⦃G, L⦄ ⊢ ⋆k ➡ T2 → T2 = ⋆k.
 133 #G #L #T2 #k #H
 134 elim (cpr_inv_atom1 … H) -H //
 135 * #K #V #V2 #i #_ #_ #_ #H destruct
 136 qed-.
 137
 138 (* Basic_1: includes: pr0_gen_lref pr2_gen_lref *)
 139 lemma cpr_inv_lref1: ∀G,L,T2,i. ⦃G, L⦄ ⊢ #i ➡ T2 →
 140                      T2 = #i ∨
 141                      ∃∃K,V,V2. ⇩[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 142                                ⇧[O, i + 1] V2 ≡ T2.
 143 #G #L #T2 #i #H
 144 elim (cpr_inv_atom1 … H) -H /2 width=1 by or_introl/
 145 * #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=6 by ex3_3_intro, or_intror/
 146 qed-.
 147
 148 lemma cpr_inv_gref1: ∀G,L,T2,p. ⦃G, L⦄ ⊢ §p ➡ T2 → T2 = §p.
 149 #G #L #T2 #p #H
 150 elim (cpr_inv_atom1 … H) -H //
 151 * #K #V #V2 #i #_ #_ #_ #H destruct
 152 qed-.
 153
 154 fact cpr_inv_bind1_aux: ∀G,L,U1,U2. ⦃G, L⦄ ⊢ U1 ➡ U2 →
 155                         ∀a,I,V1,T1. U1 = ⓑ{a,I}V1. T1 → (
 156                         ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡ T2 &
 157                                  U2 = ⓑ{a,I}V2.T2
 158                         ) ∨
 159                         ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⇧[0, 1] U2 ≡ T &
 160                              a = true & I = Abbr.
 161 #G #L #U1 #U2 * -L -U1 -U2
 162 [ #I #G #L #b #J #W1 #U1 #H destruct
 163 | #L #G #K #V #V2 #W2 #i #_ #_ #_ #b #J #W #U1 #H destruct
 164 | #a #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #b #J #W #U1 #H destruct /3 width=5 by ex3_2_intro, or_introl/
 165 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #b #J #W #U1 #H destruct
 166 | #G #L #V #T1 #T #T2 #HT1 #HT2 #b #J #W #U1 #H destruct /3 width=3 by ex4_intro, or_intror/
 167 | #G #L #V #T1 #T2 #_ #b #J #W #U1 #H destruct
 168 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #b #J #W #U1 #H destruct
 169 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #b #J #W #U1 #H destruct
 170 ]
 171 qed-.
 172
 173 lemma cpr_inv_bind1: ∀a,I,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡ U2 → (
 174                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡ T2 &
 175                               U2 = ⓑ{a,I}V2.T2
 176                      ) ∨
 177                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⇧[0, 1] U2 ≡ T &
 178                           a = true & I = Abbr.
 179 /2 width=3 by cpr_inv_bind1_aux/ qed-.
 180
 181 (* Basic_1: includes: pr0_gen_abbr pr2_gen_abbr *)
 182 lemma cpr_inv_abbr1: ∀a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{a}V1.T1 ➡ U2 → (
 183                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L. ⓓV1⦄ ⊢ T1 ➡ T2 &
 184                               U2 = ⓓ{a}V2.T2
 185                      ) ∨
 186                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⇧[0, 1] U2 ≡ T & a = true.
 187 #a #G #L #V1 #T1 #U2 #H
 188 elim (cpr_inv_bind1 … H) -H *
 189 /3 width=5 by ex3_2_intro, ex3_intro, or_introl, or_intror/
 190 qed-.
 191
 192 (* Basic_1: includes: pr0_gen_abst pr2_gen_abst *)
 193 lemma cpr_inv_abst1: ∀a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{a}V1.T1 ➡ U2 →
 194                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ➡ T2 &
 195                               U2 = ⓛ{a}V2.T2.
 196 #a #G #L #V1 #T1 #U2 #H
 197 elim (cpr_inv_bind1 … H) -H *
 198 [ /3 width=5 by ex3_2_intro/
 199 | #T #_ #_ #_ #H destruct
 200 ]
 201 qed-.
 202
 203 fact cpr_inv_flat1_aux: ∀G,L,U,U2. ⦃G, L⦄ ⊢ U ➡ U2 →
 204                         ∀I,V1,U1. U = ⓕ{I}V1.U1 →
 205                         ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 206                                     U2 = ⓕ{I} V2. T2
 207                          | (⦃G, L⦄ ⊢ U1 ➡ U2 ∧ I = Cast)
 208                          | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 209                                                ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 & U1 = ⓛ{a}W1.T1 &
 210                                                U2 = ⓓ{a}ⓝW2.V2.T2 & I = Appl
 211                          | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⇧[0,1] V ≡ V2 &
 212                                                  ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 213                                                  U1 = ⓓ{a}W1.T1 &
 214                                                  U2 = ⓓ{a}W2.ⓐV2.T2 & I = Appl.
 215 #G #L #U #U2 * -L -U -U2
 216 [ #I #G #L #J #W1 #U1 #H destruct
 217 | #G #L #K #V #V2 #W2 #i #_ #_ #_ #J #W #U1 #H destruct
 218 | #a #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #W #U1 #H destruct
 219 | #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W #U1 #H destruct /3 width=5 by or4_intro0, ex3_2_intro/
 220 | #G #L #V #T1 #T #T2 #_ #_ #J #W #U1 #H destruct
 221 | #G #L #V #T1 #T2 #HT12 #J #W #U1 #H destruct /3 width=1 by or4_intro1, conj/
 222 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #J #W #U1 #H destruct /3 width=11 by or4_intro2, ex6_6_intro/
 223 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #J #W #U1 #H destruct /3 width=13 by or4_intro3, ex7_7_intro/
 224 ]
 225 qed-.
 226
 227 lemma cpr_inv_flat1: ∀I,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓕ{I}V1.U1 ➡ U2 →
 228                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 229                                  U2 = ⓕ{I}V2.T2
 230                       | (⦃G, L⦄ ⊢ U1 ➡ U2 ∧ I = Cast)
 231                       | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 232                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 & U1 = ⓛ{a}W1.T1 &
 233                                             U2 = ⓓ{a}ⓝW2.V2.T2 & I = Appl
 234                       | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⇧[0,1] V ≡ V2 &
 235                                               ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 236                                               U1 = ⓓ{a}W1.T1 &
 237                                               U2 = ⓓ{a}W2.ⓐV2.T2 & I = Appl.
 238 /2 width=3 by cpr_inv_flat1_aux/ qed-.
 239
 240 (* Basic_1: includes: pr0_gen_appl pr2_gen_appl *)
 241 lemma cpr_inv_appl1: ∀G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓐV1.U1 ➡ U2 →
 242                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 243                                  U2 = ⓐV2.T2
 244                       | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 245                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 &
 246                                             U1 = ⓛ{a}W1.T1 & U2 = ⓓ{a}ⓝW2.V2.T2
 247                       | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⇧[0,1] V ≡ V2 &
 248                                               ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 249                                               U1 = ⓓ{a}W1.T1 & U2 = ⓓ{a}W2.ⓐV2.T2.
 250 #G #L #V1 #U1 #U2 #H elim (cpr_inv_flat1 … H) -H *
 251 [ /3 width=5 by or3_intro0, ex3_2_intro/
 252 | #_ #H destruct
 253 | /3 width=11 by or3_intro1, ex5_6_intro/
 254 | /3 width=13 by or3_intro2, ex6_7_intro/
 255 ]
 256 qed-.
 257
 258 (* Note: the main property of simple terms *)
 259 lemma cpr_inv_appl1_simple: ∀G,L,V1,T1,U. ⦃G, L⦄ ⊢ ⓐV1. T1 ➡ U → 𝐒⦃T1⦄ →
 260                             ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ T1 ➡ T2 &
 261                                      U = ⓐV2. T2.
 262 #G #L #V1 #T1 #U #H #HT1
 263 elim (cpr_inv_appl1 … H) -H *
 264 [ /2 width=5/
 265 | #a #V2 #W1 #W2 #U1 #U2 #_ #_ #_ #H #_ destruct
 266   elim (simple_inv_bind … HT1)
 267 | #a #V #V2 #W1 #W2 #U1 #U2 #_ #_ #_ #_ #H #_ destruct
 268   elim (simple_inv_bind … HT1)
 269 ]
 270 qed-.
 271
 272 (* Basic_1: includes: pr0_gen_cast pr2_gen_cast *)
 273 lemma cpr_inv_cast1: ∀G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝ V1. U1 ➡ U2 → (
 274                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 275                               U2 = ⓝ V2. T2
 276                      ) ∨ ⦃G, L⦄ ⊢ U1 ➡ U2.
 277 #G #L #V1 #U1 #U2 #H elim (cpr_inv_flat1 … H) -H *
 278 [ /3 width=5 by ex3_2_intro, or_introl/
 279 | /2 width=1 by or_intror/
 280 | #a #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #H destruct
 281 | #a #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #H destruct
 282 ]
 283 qed-.
 284
 285 (* Basic forward lemmas *****************************************************)
 286
 287 lemma cpr_fwd_bind1_minus: ∀I,G,L,V1,T1,T. ⦃G, L⦄ ⊢ -ⓑ{I}V1.T1 ➡ T → ∀b.
 288                            ∃∃V2,T2. ⦃G, L⦄ ⊢ ⓑ{b,I}V1.T1 ➡ ⓑ{b,I}V2.T2 &
 289                                     T = -ⓑ{I}V2.T2.
 290 #I #G #L #V1 #T1 #T #H #b
 291 elim (cpr_inv_bind1 … H) -H *
 292 [ #V2 #T2 #HV12 #HT12 #H destruct /3 width=4 by cpr_bind, ex2_2_intro/
 293 | #T2 #_ #_ #H destruct
 294 ]
 295 qed-.
 296
 297 lemma cpr_fwd_shift1: ∀G,L1,L,T1,T. ⦃G, L⦄ ⊢ L1 @@ T1 ➡ T →
 298                       ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 299 #G #L1 @(lenv_ind_dx … L1) -L1 normalize
 300 [ #L #T1 #T #HT1
 301   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 302 | #I #L1 #V1 #IH #L #T1 #X
 303   >shift_append_assoc normalize #H
 304   elim (cpr_inv_bind1 … H) -H *
 305   [ #V0 #T0 #_ #HT10 #H destruct
 306     elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 307     >append_length >HL12 -HL12
 308     @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] /2 width=3 by trans_eq/ (**) (* explicit constructor *)
 309   | #T #_ #_ #H destruct
 310   ]
 311 ]
 312 qed-.
 313
 314 (* Basic_1: removed theorems 11:
 315             pr0_subst0_back pr0_subst0_fwd pr0_subst0
 316             pr2_head_2 pr2_cflat clear_pr2_trans
 317             pr2_gen_csort pr2_gen_cflat pr2_gen_cbind
 318             pr2_gen_ctail pr2_ctail
 319 *)
 320 (* Basic_1: removed local theorems 4:
 321             pr0_delta_tau pr0_cong_delta
 322             pr2_free_free pr2_free_delta
 323 *)