matita/matita/contribs/lambdadelta/basic_2/reduction/cpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/pred_5.ma".
  16 include "basic_2/static/ssta.ma".
  17 include "basic_2/reduction/cpr.ma".
  18
  19 (* CONTEXT-SENSITIVE EXTENDED PARALLEL REDUCTION FOR TERMS ******************)
  20
  21 inductive cpx (h) (g): lenv → relation term ≝
  22 | cpx_atom : ∀I,L. cpx h g L (⓪{I}) (⓪{I})
  23 | cpx_sort : ∀L,k,l. deg h g k (l+1) → cpx h g L (⋆k) (⋆(next h k))
  24 | cpx_delta: ∀I,L,K,V,V2,W2,i.
  25              ⇩[0, i] L ≡ K.ⓑ{I}V → cpx h g K V V2 →
  26              ⇧[0, i + 1] V2 ≡ W2 → cpx h g L (#i) W2
  27 | cpx_bind : ∀a,I,L,V1,V2,T1,T2.
  28              cpx h g L V1 V2 → cpx h g (L. ⓑ{I}V1) T1 T2 →
  29              cpx h g L (ⓑ{a,I}V1.T1) (ⓑ{a,I}V2.T2)
  30 | cpx_flat : ∀I,L,V1,V2,T1,T2.
  31              cpx h g L V1 V2 → cpx h g L T1 T2 →
  32              cpx h g L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  33 | cpx_zeta : ∀L,V,T1,T,T2. cpx h g (L.ⓓV) T1 T →
  34              ⇧[0, 1] T2 ≡ T → cpx h g L (+ⓓV.T1) T2
  35 | cpx_tau  : ∀L,V,T1,T2. cpx h g L T1 T2 → cpx h g L (ⓝV.T1) T2
  36 | cpx_ti   : ∀L,V1,V2,T. cpx h g L V1 V2 → cpx h g L (ⓝV1.T) V2
  37 | cpx_beta : ∀a,L,V1,V2,W1,W2,T1,T2.
  38              cpx h g L V1 V2 → cpx h g L W1 W2 → cpx h g (L.ⓛW1) T1 T2 →
  39              cpx h g L (ⓐV1.ⓛ{a}W1.T1) (ⓓ{a}ⓝW2.V2.T2)
  40 | cpx_theta: ∀a,L,V1,V,V2,W1,W2,T1,T2.
  41              cpx h g L V1 V → ⇧[0, 1] V ≡ V2 → cpx h g L W1 W2 →
  42              cpx h g (L.ⓓW1) T1 T2 →
  43              cpx h g L (ⓐV1.ⓓ{a}W1.T1) (ⓓ{a}W2.ⓐV2.T2)
  44 .
  45
  46 interpretation
  47    "context-sensitive extended parallel reduction (term)"
  48    'PRed h g L T1 T2 = (cpx h g L T1 T2).
  49
  50 (* Basic properties *********************************************************)
  51
  52 lemma lsubx_cpx_trans: ∀h,g. lsub_trans … (cpx h g) lsubx.
  53 #h #g #L1 #T1 #T2 #H elim H -L1 -T1 -T2
  54 [ //
  55 | /2 width=2/
  56 | #I #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  57   elim (lsubx_fwd_ldrop2_bind … HL12 … HLK1) -HL12 -HLK1 *
  58   [ /3 width=7/ | /4 width=7/ ]
  59 |4,9: /4 width=1/
  60 |5,7,8: /3 width=1/
  61 |6,10: /4 width=3/
  62 ]
  63 qed-.
  64
  65 (* Note: this is "∀h,g,L. reflexive … (cpx h g L)" *)
  66 lemma cpx_refl: ∀h,g,T,L. ⦃h, L⦄ ⊢ T ➡[g] T.
  67 #h #g #T elim T -T // * /2 width=1/
  68 qed.
  69
  70 lemma cpr_cpx: ∀h,g,L,T1,T2. L ⊢ T1 ➡ T2 → ⦃h, L⦄ ⊢ T1 ➡[g] T2.
  71 #h #g #L #T1 #T2 #H elim H -L -T1 -T2 // /2 width=1/ /2 width=3/ /2 width=7/
  72 qed.
  73
  74 fact ssta_cpx_aux: ∀h,g,L,T1,T2,l0. ⦃h, L⦄ ⊢ T1 •[g] ⦃l0, T2⦄ →
  75                    ∀l. l0 = l+1 → ⦃h, L⦄ ⊢ T1 ➡[g] T2.
  76 #h #g #L #T1 #T2 #l0 #H elim H -L -T1 -T2 -l0 /2 width=2/ /2 width=7/ /3 width=2/ /3 width=7/
  77 qed-.
  78
  79 lemma ssta_cpx: ∀h,g,L,T1,T2,l. ⦃h, L⦄ ⊢ T1 •[g] ⦃l+1, T2⦄ → ⦃h, L⦄ ⊢ T1 ➡[g] T2.
  80 /2 width=4 by ssta_cpx_aux/ qed.
  81
  82 lemma cpx_pair_sn: ∀h,g,I,L,V1,V2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 →
  83                    ∀T. ⦃h, L⦄ ⊢ ②{I}V1.T ➡[g] ②{I}V2.T.
  84 #h #g * /2 width=1/ qed.
  85
  86 lemma cpx_delift: ∀h,g,I,K,V,T1,L,d. ⇩[0, d] L ≡ (K.ⓑ{I}V) →
  87                   ∃∃T2,T.  ⦃h, L⦄ ⊢ T1 ➡[g] T2 & ⇧[d, 1] T ≡ T2.
  88 #h #g #I #K #V #T1 elim T1 -T1
  89 [ * #i #L #d #HLK /2 width=4/
  90   elim (lt_or_eq_or_gt i d) #Hid [1,3: /3 width=4/ ]
  91   destruct
  92   elim (lift_total V 0 (i+1)) #W #HVW
  93   elim (lift_split … HVW i i) // /3 width=7/
  94 | * [ #a ] #I #W1 #U1 #IHW1 #IHU1 #L #d #HLK
  95   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  96   [ elim (IHU1 (L. ⓑ{I} W1) (d+1)) -IHU1 /2 width=1/ -HLK /3 width=9/
  97   | elim (IHU1 … HLK) -IHU1 -HLK /3 width=8/
  98   ]
  99 ]
 100 qed-.
 101
 102 lemma cpx_append: ∀h,g. l_appendable_sn … (cpx h g).
 103 #h #g #K #T1 #T2 #H elim H -K -T1 -T2 // /2 width=1/ /2 width=3/
 104 #I #K #K0 #V1 #V2 #W2 #i #HK0 #_ #HVW2 #IHV12 #L
 105 lapply (ldrop_fwd_length_lt2 … HK0) #H
 106 @(cpx_delta … I … (L@@K0) V1 … HVW2) //
 107 @(ldrop_O1_append_sn_le … HK0) /2 width=2/ (**) (* /3/ does not work *)
 108 qed.
 109
 110 (* Basic inversion lemmas ***************************************************)
 111
 112 fact cpx_inv_atom1_aux: ∀h,g,L,T1,T2. ⦃h, L⦄ ⊢ T1 ➡[g] T2 → ∀J. T1 = ⓪{J} →
 113                         ∨∨ T2 = ⓪{J}
 114                          | ∃∃k,l. deg h g k (l+1) & T2 = ⋆(next h k) & J = Sort k
 115                          | ∃∃I,K,V,V2,i. ⇩[O, i] L ≡ K.ⓑ{I}V & ⦃h, K⦄ ⊢ V ➡[g] V2 &
 116                                          ⇧[O, i + 1] V2 ≡ T2 & J = LRef i.
 117 #h #g #L #T1 #T2 * -L -T1 -T2
 118 [ #I #L #J #H destruct /2 width=1/
 119 | #L #k #l #Hkl #J #H destruct /3 width=5/
 120 | #I #L #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #J #H destruct /3 width=9/
 121 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
 122 | #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
 123 | #L #V #T1 #T #T2 #_ #_ #J #H destruct
 124 | #L #V #T1 #T2 #_ #J #H destruct
 125 | #L #V1 #V2 #T #_ #J #H destruct
 126 | #a #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #J #H destruct
 127 | #a #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #J #H destruct
 128 ]
 129 qed-.
 130
 131 lemma cpx_inv_atom1: ∀h,g,J,L,T2. ⦃h, L⦄ ⊢ ⓪{J} ➡[g] T2 →
 132                      ∨∨ T2 = ⓪{J}
 133                       | ∃∃k,l. deg h g k (l+1) & T2 = ⋆(next h k) & J = Sort k
 134                       | ∃∃I,K,V,V2,i. ⇩[O, i] L ≡ K.ⓑ{I}V & ⦃h, K⦄ ⊢ V ➡[g] V2 &
 135                                       ⇧[O, i + 1] V2 ≡ T2 & J = LRef i.
 136 /2 width=3 by cpx_inv_atom1_aux/ qed-.
 137
 138 lemma cpx_inv_sort1: ∀h,g,L,T2,k. ⦃h, L⦄ ⊢ ⋆k ➡[g] T2 → T2 = ⋆k ∨
 139                      ∃∃l. deg h g k (l+1) & T2 = ⋆(next h k).
 140 #h #g #L #T2 #k #H
 141 elim (cpx_inv_atom1 … H) -H /2 width=1/ *
 142 [ #k0 #l0 #Hkl0 #H1 #H2 destruct /3 width=4/
 143 | #I #K #V #V2 #i #_ #_ #_ #H destruct
 144 ]
 145 qed-.
 146
 147 lemma cpx_inv_lref1: ∀h,g,L,T2,i. ⦃h, L⦄ ⊢ #i ➡[g] T2 →
 148                      T2 = #i ∨
 149                      ∃∃I,K,V,V2. ⇩[O, i] L ≡ K. ⓑ{I}V & ⦃h, K⦄ ⊢ V ➡[g] V2 &
 150                                  ⇧[O, i + 1] V2 ≡ T2.
 151 #h #g #L #T2 #i #H
 152 elim (cpx_inv_atom1 … H) -H /2 width=1/ *
 153 [ #k #l #_ #_ #H destruct
 154 | #I #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=7/
 155 ]
 156 qed-.
 157
 158 lemma cpx_inv_gref1: ∀h,g,L,T2,p.  ⦃h, L⦄ ⊢ §p ➡[g] T2 → T2 = §p.
 159 #h #g #L #T2 #p #H
 160 elim (cpx_inv_atom1 … H) -H // *
 161 [ #k #l #_ #_ #H destruct
 162 | #I #K #V #V2 #i #_ #_ #_ #H destruct
 163 ]
 164 qed-.
 165
 166 fact cpx_inv_bind1_aux: ∀h,g,L,U1,U2. ⦃h, L⦄ ⊢ U1 ➡[g] U2 →
 167                         ∀a,J,V1,T1. U1 = ⓑ{a,J}V1.T1 → (
 168                         ∃∃V2,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L.ⓑ{J}V1⦄ ⊢ T1 ➡[g] T2 &
 169                                  U2 = ⓑ{a,J}V2.T2
 170                         ) ∨
 171                         ∃∃T. ⦃h, L.ⓓV1⦄ ⊢ T1 ➡[g] T & ⇧[0, 1] U2 ≡ T &
 172                              a = true & J = Abbr.
 173 #h #g #L #U1 #U2 * -L -U1 -U2
 174 [ #I #L #b #J #W #U1 #H destruct
 175 | #L #k #l #_ #b #J #W #U1 #H destruct
 176 | #I #L #K #V #V2 #W2 #i #_ #_ #_ #b #J #W #U1 #H destruct
 177 | #a #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #b #J #W #U1 #H destruct /3 width=5/
 178 | #I #L #V1 #V2 #T1 #T2 #_ #_ #b #J #W #U1 #H destruct
 179 | #L #V #T1 #T #T2 #HT1 #HT2 #b #J #W #U1 #H destruct /3 width=3/
 180 | #L #V #T1 #T2 #_ #b #J #W #U1 #H destruct
 181 | #L #V1 #V2 #T #_ #b #J #W #U1 #H destruct
 182 | #a #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #b #J #W #U1 #H destruct
 183 | #a #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #b #J #W #U1 #H destruct
 184 ]
 185 qed-.
 186
 187 lemma cpx_inv_bind1: ∀h,g,a,I,L,V1,T1,U2. ⦃h, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡[g] U2 → (
 188                      ∃∃V2,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L.ⓑ{I}V1⦄ ⊢ T1 ➡[g] T2 &
 189                               U2 = ⓑ{a,I} V2. T2
 190                      ) ∨
 191                      ∃∃T. ⦃h, L.ⓓV1⦄ ⊢ T1 ➡[g] T & ⇧[0, 1] U2 ≡ T &
 192                           a = true & I = Abbr.
 193 /2 width=3 by cpx_inv_bind1_aux/ qed-.
 194
 195 lemma cpx_inv_abbr1: ∀h,g,a,L,V1,T1,U2. ⦃h, L⦄ ⊢ ⓓ{a}V1.T1 ➡[g] U2 → (
 196                      ∃∃V2,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L.ⓓV1⦄ ⊢ T1 ➡[g] T2 &
 197                               U2 = ⓓ{a} V2. T2
 198                      ) ∨
 199                      ∃∃T. ⦃h, L.ⓓV1⦄ ⊢ T1 ➡[g] T & ⇧[0, 1] U2 ≡ T & a = true.
 200 #h #g #a #L #V1 #T1 #U2 #H
 201 elim (cpx_inv_bind1 … H) -H * /3 width=3/ /3 width=5/
 202 qed-.
 203
 204 lemma cpx_inv_abst1: ∀h,g,a,L,V1,T1,U2.  ⦃h, L⦄ ⊢ ⓛ{a}V1.T1 ➡[g] U2 →
 205                      ∃∃V2,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 &  ⦃h, L.ⓛV1⦄ ⊢ T1 ➡[g] T2 &
 206                               U2 = ⓛ{a} V2. T2.
 207 #h #g #a #L #V1 #T1 #U2 #H
 208 elim (cpx_inv_bind1 … H) -H *
 209 [ /3 width=5/
 210 | #T #_ #_ #_ #H destruct
 211 ]
 212 qed-.
 213
 214 fact cpx_inv_flat1_aux: ∀h,g,L,U,U2. ⦃h, L⦄ ⊢ U ➡[g] U2 →
 215                         ∀J,V1,U1. U = ⓕ{J}V1.U1 →
 216                         ∨∨ ∃∃V2,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L⦄ ⊢ U1 ➡[g] T2 &
 217                                     U2 = ⓕ{J}V2.T2
 218                          | (⦃h, L⦄ ⊢ U1 ➡[g] U2 ∧ J = Cast)
 219                          | (⦃h, L⦄ ⊢ V1 ➡[g] U2 ∧ J = Cast)
 220                          | ∃∃a,V2,W1,W2,T1,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L⦄ ⊢ W1 ➡[g] W2 &
 221                                                ⦃h, L.ⓛW1⦄ ⊢ T1 ➡[g] T2 &
 222                                                U1 = ⓛ{a}W1.T1 &
 223                                                U2 = ⓓ{a}ⓝW2.V2.T2 & J = Appl
 224                          | ∃∃a,V,V2,W1,W2,T1,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V & ⇧[0,1] V ≡ V2 &
 225                                                  ⦃h, L⦄ ⊢ W1 ➡[g] W2 & ⦃h, L.ⓓW1⦄ ⊢ T1 ➡[g] T2 &
 226                                                  U1 = ⓓ{a}W1.T1 &
 227                                                  U2 = ⓓ{a}W2.ⓐV2.T2 & J = Appl.
 228 #h #g #L #U #U2 * -L -U -U2
 229 [ #I #L #J #W #U1 #H destruct
 230 | #L #k #l #_ #J #W #U1 #H destruct
 231 | #I #L #K #V #V2 #W2 #i #_ #_ #_ #J #W #U1 #H destruct
 232 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #W #U1 #H destruct
 233 | #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W #U1 #H destruct /3 width=5/
 234 | #L #V #T1 #T #T2 #_ #_ #J #W #U1 #H destruct
 235 | #L #V #T1 #T2 #HT12 #J #W #U1 #H destruct /3 width=1/
 236 | #L #V1 #V2 #T #HV12 #J #W #U1 #H destruct /3 width=1/
 237 | #a #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #J #W #U1 #H destruct /3 width=11/
 238 | #a #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #J #W #U1 #H destruct /3 width=13/
 239 ]
 240 qed-.
 241
 242 lemma cpx_inv_flat1: ∀h,g,I,L,V1,U1,U2. ⦃h, L⦄ ⊢ ⓕ{I}V1.U1 ➡[g] U2 →
 243                      ∨∨ ∃∃V2,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L⦄ ⊢ U1 ➡[g] T2 &
 244                                  U2 = ⓕ{I} V2. T2
 245                       | (⦃h, L⦄ ⊢ U1 ➡[g] U2 ∧ I = Cast)
 246                       | (⦃h, L⦄ ⊢ V1 ➡[g] U2 ∧ I = Cast)
 247                       | ∃∃a,V2,W1,W2,T1,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L⦄ ⊢ W1 ➡[g] W2 &
 248                                             ⦃h, L.ⓛW1⦄ ⊢ T1 ➡[g] T2 &
 249                                             U1 = ⓛ{a}W1.T1 &
 250                                             U2 = ⓓ{a}ⓝW2.V2.T2 & I = Appl
 251                       | ∃∃a,V,V2,W1,W2,T1,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V & ⇧[0,1] V ≡ V2 &
 252                                               ⦃h, L⦄ ⊢ W1 ➡[g] W2 & ⦃h, L.ⓓW1⦄ ⊢ T1 ➡[g] T2 &
 253                                               U1 = ⓓ{a}W1.T1 &
 254                                               U2 = ⓓ{a}W2.ⓐV2.T2 & I = Appl.
 255 /2 width=3 by cpx_inv_flat1_aux/ qed-.
 256
 257 lemma cpx_inv_appl1: ∀h,g,L,V1,U1,U2. ⦃h, L⦄ ⊢ ⓐ V1.U1 ➡[g] U2 →
 258                      ∨∨ ∃∃V2,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L⦄ ⊢ U1 ➡[g] T2 &
 259                                  U2 = ⓐ V2. T2
 260                       | ∃∃a,V2,W1,W2,T1,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L⦄ ⊢ W1 ➡[g] W2 &
 261                                             ⦃h, L.ⓛW1⦄ ⊢ T1 ➡[g] T2 &
 262                                             U1 = ⓛ{a}W1.T1 & U2 = ⓓ{a}ⓝW2.V2.T2
 263                       | ∃∃a,V,V2,W1,W2,T1,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V & ⇧[0,1] V ≡ V2 &
 264                                               ⦃h, L⦄ ⊢ W1 ➡[g] W2 & ⦃h, L.ⓓW1⦄ ⊢ T1 ➡[g] T2 &
 265                                               U1 = ⓓ{a}W1.T1 & U2 = ⓓ{a}W2. ⓐV2. T2.
 266 #h #g #L #V1 #U1 #U2 #H elim (cpx_inv_flat1 … H) -H *
 267 [ /3 width=5/
 268 |2,3: #_ #H destruct
 269 | /3 width=11/
 270 | /3 width=13/
 271 ]
 272 qed-.
 273
 274 (* Note: the main property of simple terms *)
 275 lemma cpx_inv_appl1_simple: ∀h,g,L,V1,T1,U. ⦃h, L⦄ ⊢ ⓐV1.T1 ➡[g] U → 𝐒⦃T1⦄ →
 276                             ∃∃V2,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L⦄ ⊢ T1 ➡[g] T2 &
 277                                      U = ⓐV2.T2.
 278 #h #g #L #V1 #T1 #U #H #HT1
 279 elim (cpx_inv_appl1 … H) -H *
 280 [ /2 width=5/
 281 | #a #V2 #W1 #W2 #U1 #U2 #_ #_ #_ #H #_ destruct
 282   elim (simple_inv_bind … HT1)
 283 | #a #V #V2 #W1 #W2 #U1 #U2 #_ #_ #_ #_ #H #_ destruct
 284   elim (simple_inv_bind … HT1)
 285 ]
 286 qed-.
 287
 288 lemma cpx_inv_cast1: ∀h,g,L,V1,U1,U2. ⦃h, L⦄ ⊢ ⓝV1.U1 ➡[g] U2 →
 289                      ∨∨ ∃∃V2,T2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 & ⦃h, L⦄ ⊢ U1 ➡[g] T2 &
 290                                  U2 = ⓝ V2. T2
 291                       | ⦃h, L⦄ ⊢ U1 ➡[g] U2
 292                       | ⦃h, L⦄ ⊢ V1 ➡[g] U2.
 293 #h #g #L #V1 #U1 #U2 #H elim (cpx_inv_flat1 … H) -H *
 294 [ /3 width=5/
 295 |2,3: /2 width=1/
 296 | #a #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #H destruct
 297 | #a #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #H destruct
 298 ]
 299 qed-.
 300
 301 (* Basic forward lemmas *****************************************************)
 302
 303 lemma cpx_fwd_bind1_minus: ∀h,g,I,L,V1,T1,T. ⦃h, L⦄ ⊢ -ⓑ{I}V1.T1 ➡[g] T → ∀b.
 304                            ∃∃V2,T2. ⦃h, L⦄ ⊢ ⓑ{b,I}V1.T1 ➡[g] ⓑ{b,I}V2.T2 &
 305                                     T = -ⓑ{I}V2.T2.
 306 #h #g #I #L #V1 #T1 #T #H #b
 307 elim (cpx_inv_bind1 … H) -H *
 308 [ #V2 #T2 #HV12 #HT12 #H destruct /3 width=4/
 309 | #T2 #_ #_ #H destruct
 310 ]
 311 qed-.
 312
 313 lemma cpx_fwd_shift1: ∀h,g,L1,L,T1,T. ⦃h, L⦄ ⊢ L1 @@ T1 ➡[g] T →
 314                       ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 315 #h #g #L1 @(lenv_ind_dx … L1) -L1 normalize
 316 [ #L #T1 #T #HT1
 317   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 318 | #I #L1 #V1 #IH #L #T1 #X
 319   >shift_append_assoc normalize #H
 320   elim (cpx_inv_bind1 … H) -H *
 321   [ #V0 #T0 #_ #HT10 #H destruct
 322     elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 323     >append_length >HL12 -HL12
 324     @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] // /2 width=3/ (**) (* explicit constructor *)
 325   | #T #_ #_ #H destruct
 326   ]
 327 ]
 328 qed-.