matita/matita/contribs/lambdadelta/basic_2/reduction/cpx_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/ldrop_ldrop.ma".
  16 include "basic_2/multiple/fqus_alt.ma".
  17 include "basic_2/static/ssta.ma".
  18 include "basic_2/reduction/cpx.ma".
  19
  20 (* CONTEXT-SENSITIVE EXTENDED PARALLEL REDUCTION FOR TERMS ******************)
  21
  22 (* Advanced properties ******************************************************)
  23
  24 lemma ssta_cpx: ∀h,g,G,L,T1,T2,l. ⦃G, L⦄ ⊢ T1 •[h, g] T2 →
  25                 ⦃G, L⦄ ⊢ T1 ▪[h, g] l+1 → ⦃G, L⦄ ⊢ T1 ➡[h, g] T2.
  26 #h #g #G #L #T1 #T2 #l #H elim H -G -L -T1 -T2
  27 [ /3 width=4 by cpx_st, da_inv_sort/
  28 | #G #L #K #V #U #W #i #HLK #_ #HWU #IHVW #H
  29   elim (da_inv_lref … H) -H * #K0 #V0 [| #l0 ] #HLK0
  30   lapply (ldrop_mono … HLK0 … HLK) -HLK0 #H destruct /3 width=7 by cpx_delta/
  31 | #G #L #K #W #U #l0 #i #HLK #_ #HWU #H
  32   elim (da_inv_lref … H) -H * #K0 #W0 [| #l1 ] #HLK0
  33   lapply (ldrop_mono … HLK0 … HLK) -HLK0 #H destruct /2 width=7 by cpx_delta/
  34 | /4 width=2 by cpx_bind, da_inv_bind/
  35 | /4 width=3 by cpx_flat, da_inv_flat/
  36 | /4 width=3 by cpx_eps, da_inv_flat/
  37 ]
  38 qed.
  39
  40 (* Relocation properties ****************************************************)
  41
  42 lemma cpx_lift: ∀h,g,G. l_liftable (cpx h g G).
  43 #h #g #G #K #T1 #T2 #H elim H -G -K -T1 -T2
  44 [ #I #G #K #L #s #d #e #_ #U1 #H1 #U2 #H2
  45   >(lift_mono … H1 … H2) -H1 -H2 //
  46 | #G #K #k #l #Hkl #L #s #d #e #_ #U1 #H1 #U2 #H2
  47   >(lift_inv_sort1 … H1) -U1
  48   >(lift_inv_sort1 … H2) -U2 /2 width=2 by cpx_st/
  49 | #I #G #K #KV #V #V2 #W2 #i #HKV #HV2 #HVW2 #IHV2 #L #s #d #e #HLK #U1 #H #U2 #HWU2
  50   elim (lift_inv_lref1 … H) * #Hid #H destruct
  51   [ elim (lift_trans_ge … HVW2 … HWU2) -W2 // <minus_plus #W2 #HVW2 #HWU2
  52     elim (ldrop_trans_le … HLK … HKV) -K /2 width=2 by lt_to_le/ #X #HLK #H
  53     elim (ldrop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ -Hid
  54     #K #Y #HKV #HVY #H destruct /3 width=10 by cpx_delta/
  55   | lapply (lift_trans_be … HVW2 … HWU2 ? ?) -W2 /2 width=1 by le_S/ >plus_plus_comm_23 #HVU2
  56     lapply (ldrop_trans_ge_comm … HLK … HKV ?) -K /3 width=7 by cpx_delta, ldrop_inv_gen/
  57   ]
  58 | #a #I #G #K #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L #s #d #e #HLK #U1 #H1 #U2 #H2
  59   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1 destruct
  60   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct /4 width=6 by cpx_bind, ldrop_skip/
  61 | #I #G #K #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L #s #d #e #HLK #U1 #H1 #U2 #H2
  62   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1 destruct
  63   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct /3 width=6 by cpx_flat/
  64 | #G #K #V #T1 #T #T2 #_ #HT2 #IHT1 #L #s #d #e #HLK #U1 #H #U2 #HTU2
  65   elim (lift_inv_bind1 … H) -H #VV1 #TT1 #HVV1 #HTT1 #H destruct
  66   elim (lift_conf_O1 … HTU2 … HT2) -T2 /4 width=6 by cpx_zeta, ldrop_skip/
  67 | #G #K #V #T1 #T2 #_ #IHT12 #L #s #d #e #HLK #U1 #H #U2 #HTU2
  68   elim (lift_inv_flat1 … H) -H #VV1 #TT1 #HVV1 #HTT1 #H destruct /3 width=6 by cpx_eps/
  69 | #G #K #V1 #V2 #T #_ #IHV12 #L #s #d #e #HLK #U1 #H #U2 #HVU2
  70   elim (lift_inv_flat1 … H) -H #VV1 #TT1 #HVV1 #HTT1 #H destruct /3 width=6 by cpx_ct/
  71 | #a #G #K #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #L #s #d #e #HLK #X1 #HX1 #X2 #HX2
  72   elim (lift_inv_flat1 … HX1) -HX1 #V0 #X #HV10 #HX #HX1 destruct
  73   elim (lift_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT10 #HX destruct
  74   elim (lift_inv_bind1 … HX2) -HX2 #X #T3 #HX #HT23 #HX2 destruct
  75   elim (lift_inv_flat1 … HX) -HX #W3 #V3 #HW23 #HV23 #HX destruct /4 width=6 by cpx_beta, ldrop_skip/
  76 | #a #G #K #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV1 #IHW12 #IHT12 #L #s #d #e #HLK #X1 #HX1 #X2 #HX2
  77   elim (lift_inv_flat1 … HX1) -HX1 #V0 #X #HV10 #HX #HX1 destruct
  78   elim (lift_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT10 #HX destruct
  79   elim (lift_inv_bind1 … HX2) -HX2 #W3 #X #HW23 #HX #HX2 destruct
  80   elim (lift_inv_flat1 … HX) -HX #V3 #T3 #HV3 #HT23 #HX destruct
  81   elim (lift_trans_ge … HV2 … HV3) -V2 /4 width=6 by cpx_theta, ldrop_skip/
  82 ]
  83 qed.
  84
  85 lemma cpx_inv_lift1: ∀h,g,G. l_deliftable_sn (cpx h g G).
  86 #h #g #G #L #U1 #U2 #H elim H -G -L -U1 -U2
  87 [ * #i #G #L #K #s #d #e #_ #T1 #H
  88   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by cpx_atom, lift_sort, ex2_intro/
  89   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct /3 width=3 by cpx_atom, lift_lref_ge_minus, lift_lref_lt, ex2_intro/
  90   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by cpx_atom, lift_gref, ex2_intro/
  91   ]
  92 | #G #L #k #l #Hkl #K #s #d #e #_ #T1 #H
  93   lapply (lift_inv_sort2 … H) -H #H destruct /3 width=3 by cpx_st, lift_sort, ex2_intro/
  94 | #I #G #L #LV #V #V2 #W2 #i #HLV #HV2 #HVW2 #IHV2 #K #s #d #e #HLK #T1 #H
  95   elim (lift_inv_lref2 … H) -H * #Hid #H destruct
  96   [ elim (ldrop_conf_lt … HLK … HLV) -L // #L #U #HKL #HLV #HUV
  97     elim (IHV2 … HLV … HUV) -V #U2 #HUV2 #HU2
  98     elim (lift_trans_le … HUV2 … HVW2) -V2 // >minus_plus <plus_minus_m_m /3 width=9 by cpx_delta, ex2_intro/
  99   | elim (le_inv_plus_l … Hid) #Hdie #Hei
 100     lapply (ldrop_conf_ge … HLK … HLV ?) -L // #HKLV
 101     elim (lift_split … HVW2 d (i - e + 1)) -HVW2 /3 width=1 by le_S, le_S_S/ -Hid -Hdie
 102     #V1 #HV1 >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O /3 width=9 by cpx_delta, ex2_intro/
 103   ]
 104 | #a #I #G #L #V1 #V2 #U1 #U2 #_ #_ #IHV12 #IHU12 #K #s #d #e #HLK #X #H
 105   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 106   elim (IHV12 … HLK … HWV1) -IHV12 #W2 #HW12 #HWV2
 107   elim (IHU12 … HTU1) -IHU12 -HTU1 /3 width=6 by cpx_bind, ldrop_skip, lift_bind, ex2_intro/
 108 | #I #G #L #V1 #V2 #U1 #U2 #_ #_ #IHV12 #IHU12 #K #s #d #e #HLK #X #H
 109   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 110   elim (IHV12 … HLK … HWV1) -V1
 111   elim (IHU12 … HLK … HTU1) -U1 -HLK /3 width=5 by cpx_flat, lift_flat, ex2_intro/
 112 | #G #L #V #U1 #U #U2 #_ #HU2 #IHU1 #K #s #d #e #HLK #X #H
 113   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 114   elim (IHU1 (K.ⓓW1) s … HTU1) /2 width=1/ -L -U1 #T #HTU #HT1
 115   elim (lift_div_le … HU2 … HTU) -U /3 width=5 by cpx_zeta, ex2_intro/
 116 | #G #L #V #U1 #U2 #_ #IHU12 #K #s #d #e #HLK #X #H
 117   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 118   elim (IHU12 … HLK … HTU1) -L -U1 /3 width=3 by cpx_eps, ex2_intro/
 119 | #G #L #V1 #V2 #U1 #_ #IHV12 #K #s #d #e #HLK #X #H
 120   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 121   elim (IHV12 … HLK … HWV1) -L -V1 /3 width=3 by cpx_ct, ex2_intro/
 122 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #K #s #d #e #HLK #X #HX
 123   elim (lift_inv_flat2 … HX) -HX #V0 #Y #HV01 #HY #HX destruct
 124   elim (lift_inv_bind2 … HY) -HY #W0 #T0 #HW01 #HT01 #HY destruct
 125   elim (IHV12 … HLK … HV01) -V1 #V3 #HV32 #HV03
 126   elim (IHT12 (K.ⓛW0) s … HT01) -T1 /2 width=1 by ldrop_skip/ #T3 #HT32 #HT03
 127   elim (IHW12 … HLK … HW01) -W1
 128   /4 width=7 by cpx_beta, lift_bind, lift_flat, ex2_intro/
 129 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV1 #IHW12 #IHT12 #K #s #d #e #HLK #X #HX
 130   elim (lift_inv_flat2 … HX) -HX #V0 #Y #HV01 #HY #HX destruct
 131   elim (lift_inv_bind2 … HY) -HY #W0 #T0 #HW01 #HT01 #HY destruct
 132   elim (IHV1 … HLK … HV01) -V1 #V3 #HV3 #HV03
 133   elim (IHT12 (K.ⓓW0) s … HT01) -T1 /2 width=1 by ldrop_skip/ #T3 #HT32 #HT03
 134   elim (IHW12 … HLK … HW01) -W1 #W3 #HW32 #HW03
 135   elim (lift_trans_le … HV3 … HV2) -V
 136   /4 width=9 by cpx_theta, lift_bind, lift_flat, ex2_intro/
 137 ]
 138 qed-.
 139
 140 (* Properties on supclosure *************************************************)
 141
 142 lemma fqu_cpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
 143                      ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 →
 144                      ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐ ⦃G2, L2, U2⦄.
 145 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
 146 /3 width=3 by fqu_pair_sn, fqu_bind_dx, fqu_flat_dx, cpx_pair_sn, cpx_bind, cpx_flat, ex2_intro/
 147 [ #I #G #L #V2 #U2 #HVU2
 148   elim (lift_total U2 0 1)
 149   /4 width=7 by fqu_drop, cpx_delta, ldrop_pair, ldrop_drop, ex2_intro/
 150 | #G #L #K #T1 #U1 #e #HLK1 #HTU1 #T2 #HTU2
 151   elim (lift_total T2 0 (e+1))
 152   /3 width=11 by cpx_lift, fqu_drop, ex2_intro/
 153 ]
 154 qed-.
 155
 156 lemma fqu_ssta_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
 157                       ∀U2. ⦃G2, L2⦄ ⊢ T2 •[h, g] U2 →
 158                       ∀l. ⦃G2, L2⦄ ⊢ T2 ▪[h, g] l+1 →
 159                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐ ⦃G2, L2, U2⦄.
 160 /3 width=5 by fqu_cpx_trans, ssta_cpx/ qed-.
 161
 162 lemma fquq_cpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
 163                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 →
 164                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
 165 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #U2 #HTU2 elim (fquq_inv_gen … H) -H
 166 [ #HT12 elim (fqu_cpx_trans … HT12 … HTU2) /3 width=3 by fqu_fquq, ex2_intro/
 167 | * #H1 #H2 #H3 destruct /2 width=3 by ex2_intro/
 168 ]
 169 qed-.
 170
 171 lemma fquq_ssta_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
 172                        ∀U2. ⦃G2, L2⦄ ⊢ T2 •[h, g] U2 →
 173                        ∀l. ⦃G2, L2⦄ ⊢ T2 ▪[h, g] l+1 →
 174                        ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
 175 /3 width=5 by fquq_cpx_trans, ssta_cpx/ qed-.
 176
 177 lemma fqup_cpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
 178                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 →
 179                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐+ ⦃G2, L2, U2⦄.
 180 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
 181 [ #G2 #L2 #T2 #H12 #U2 #HTU2 elim (fqu_cpx_trans … H12 … HTU2) -T2
 182   /3 width=3 by fqu_fqup, ex2_intro/
 183 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #U2 #HTU2
 184   elim (fqu_cpx_trans … HT2 … HTU2) -T2 #T2 #HT2 #HTU2
 185   elim (IHT1 … HT2) -T /3 width=7 by fqup_strap1, ex2_intro/
 186 ]
 187 qed-.
 188
 189 lemma fqus_cpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
 190                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 →
 191                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐* ⦃G2, L2, U2⦄.
 192 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #U2 #HTU2 elim (fqus_inv_gen … H) -H
 193 [ #HT12 elim (fqup_cpx_trans … HT12 … HTU2) /3 width=3 by fqup_fqus, ex2_intro/
 194 | * #H1 #H2 #H3 destruct /2 width=3 by ex2_intro/
 195 ]
 196 qed-.
 197
 198 lemma fqu_cpx_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
 199                          ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 → (T2 = U2 → ⊥) →
 200                          ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐ ⦃G2, L2, U2⦄.
 201 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
 202 [ #I #G #L #V1 #V2 #HV12 #_ elim (lift_total V2 0 1)
 203   #U2 #HVU2 @(ex3_intro … U2)
 204   [1,3: /3 width=7 by fqu_drop, cpx_delta, ldrop_pair, ldrop_drop/
 205   | #H destruct /2 width=7 by lift_inv_lref2_be/
 206   ]
 207 | #I #G #L #V1 #T #V2 #HV12 #H @(ex3_intro … (②{I}V2.T))
 208   [1,3: /2 width=4 by fqu_pair_sn, cpx_pair_sn/
 209   | #H0 destruct /2 width=1 by/
 210   ]
 211 | #a #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓑ{a,I}V.T2))
 212   [1,3: /2 width=4 by fqu_bind_dx, cpx_bind/
 213   | #H0 destruct /2 width=1 by/
 214   ]
 215 | #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓕ{I}V.T2))
 216   [1,3: /2 width=4 by fqu_flat_dx, cpx_flat/
 217   | #H0 destruct /2 width=1 by/
 218   ]
 219 | #G #L #K #T1 #U1 #e #HLK #HTU1 #T2 #HT12 #H elim (lift_total T2 0 (e+1))
 220   #U2 #HTU2 @(ex3_intro … U2)
 221   [1,3: /2 width=10 by cpx_lift, fqu_drop/
 222   | #H0 destruct /3 width=5 by lift_inj/
 223 ]
 224 qed-.
 225
 226 lemma fquq_cpx_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
 227                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 → (T2 = U2 → ⊥) →
 228                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
 229 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fquq_inv_gen … H12) -H12
 230 [ #H12 elim (fqu_cpx_trans_neq … H12 … HTU2 H) -T2
 231   /3 width=4 by fqu_fquq, ex3_intro/
 232 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 233 ]
 234 qed-.
 235
 236 lemma fqup_cpx_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
 237                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 → (T2 = U2 → ⊥) →
 238                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐+ ⦃G2, L2, U2⦄.
 239 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind_dx … H) -G1 -L1 -T1
 240 [ #G1 #L1 #T1 #H12 #U2 #HTU2 #H elim (fqu_cpx_trans_neq … H12 … HTU2 H) -T2
 241   /3 width=4 by fqu_fqup, ex3_intro/
 242 | #G #G1 #L #L1 #T #T1 #H1 #_ #IH12 #U2 #HTU2 #H elim (IH12 … HTU2 H) -T2
 243   #U1 #HTU1 #H #H12 elim (fqu_cpx_trans_neq … H1 … HTU1 H) -T1
 244   /3 width=8 by fqup_strap2, ex3_intro/
 245 ]
 246 qed-.
 247
 248 lemma fqus_cpx_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
 249                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 → (T2 = U2 → ⊥) →
 250                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐* ⦃G2, L2, U2⦄.
 251 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fqus_inv_gen … H12) -H12
 252 [ #H12 elim (fqup_cpx_trans_neq … H12 … HTU2 H) -T2
 253   /3 width=4 by fqup_fqus, ex3_intro/
 254 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 255 ]
 256 qed-.