matita/matita/contribs/lambdadelta/basic_2/reduction/crx_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/ldrop_ldrop.ma".
  16 include "basic_2/reduction/crx.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED REDUCIBLE TERMS *******************************)
  19
  20 (* Properties on relocation *************************************************)
  21
  22 lemma crx_lift: ∀h,g,K,T. ⦃h, K⦄ ⊢ 𝐑[g]⦃T⦄ → ∀L,d,e. ⇩[d, e] L ≡ K →
  23                 ∀U. ⇧[d, e] T ≡ U → ⦃h, L⦄ ⊢ 𝐑[g]⦃U⦄.
  24 #h #g #K #T #H elim H -K -T
  25 [ #K #k #l #Hkl #L #d #e #_ #X #H
  26   >(lift_inv_sort1 … H) -X /2 width=2/
  27 | #I #K #K0 #V #i #HK0 #L #d #e #HLK #X #H
  28   elim (lift_inv_lref1 … H) -H * #Hid #H destruct
  29   [ elim (ldrop_trans_lt … HLK … HK0) -K // /2 width=4/
  30   | lapply (ldrop_trans_ge … HLK … HK0 ?) -K // /2 width=4/
  31   ]
  32 | #K #V #T #_ #IHV #L #d #e #HLK #X #H
  33   elim (lift_inv_flat1 … H) -H #W #U #HVW #_ #H destruct /3 width=4/
  34 | #K #V #T #_ #IHT #L #d #e #HLK #X #H
  35   elim (lift_inv_flat1 … H) -H #W #U #_ #HTU #H destruct /3 width=4/
  36 | #I #K #V #T #HI #L #d #e #_ #X #H
  37   elim (lift_fwd_pair1 … H) -H #W #U #_ #H destruct /2 width=1/
  38 | #a #I #K #V #T #HI #_ #IHV #L #d #e #HLK #X #H
  39   elim (lift_inv_bind1 … H) -H #W #U #HVW #_ #H destruct /3 width=4/
  40 | #a #I #K #V #T #HI #_ #IHT #L #d #e #HLK #X #H
  41   elim (lift_inv_bind1 … H) -H #W #U #HVW #HTU #H destruct /4 width=4/
  42 | #a #K #V #V0 #T #L #d #e #_ #X #H
  43   elim (lift_inv_flat1 … H) -H #W #X0 #_ #H0 #H destruct
  44   elim (lift_inv_bind1 … H0) -H0 #W0 #U #_ #_ #H0 destruct /2 width=1/
  45 | #a #K #V #V0 #T #L #d #e #_ #X #H
  46   elim (lift_inv_flat1 … H) -H #W #X0 #_ #H0 #H destruct
  47   elim (lift_inv_bind1 … H0) -H0 #W0 #U #_ #_ #H0 destruct /2 width=1/
  48 ]
  49 qed.
  50
  51 lemma crx_inv_lift: ∀h,g,L,U. ⦃h, L⦄ ⊢ 𝐑[g]⦃U⦄ → ∀K,d,e. ⇩[d, e] L ≡ K →
  52                     ∀T. ⇧[d, e] T ≡ U → ⦃h, K⦄ ⊢ 𝐑[g]⦃T⦄.
  53 #h #g #L #U #H elim H -L -U
  54 [ #L #k #l #Hkl #K #d #e #_ #X #H
  55   >(lift_inv_sort2 … H) -X /2 width=2/
  56 | #I #L #L0 #W #i #HK0 #K #d #e #HLK #X #H
  57   elim (lift_inv_lref2 … H) -H * #Hid #H destruct
  58   [ elim (ldrop_conf_lt … HLK … HK0) -L // /2 width=4/
  59   | lapply (ldrop_conf_ge … HLK … HK0 ?) -L // /2 width=4/
  60   ]
  61 | #L #W #U #_ #IHW #K #d #e #HLK #X #H
  62   elim (lift_inv_flat2 … H) -H #V #T #HVW #_ #H destruct /3 width=4/
  63 | #L #W #U #_ #IHU #K #d #e #HLK #X #H
  64   elim (lift_inv_flat2 … H) -H #V #T #_ #HTU #H destruct /3 width=4/
  65 | #I #L #W #U #HI #K #d #e #_ #X #H
  66   elim (lift_fwd_pair2 … H) -H #V #T #_ #H destruct /2 width=1/
  67 | #a #I #L #W #U #HI #_ #IHW #K #d #e #HLK #X #H
  68   elim (lift_inv_bind2 … H) -H #V #T #HVW #_ #H destruct /3 width=4/
  69 | #a #I #L #W #U #HI #_ #IHU #K #d #e #HLK #X #H
  70   elim (lift_inv_bind2 … H) -H #V #T #HVW #HTU #H destruct /4 width=4/
  71 | #a #L #W #W0 #U #K #d #e #_ #X #H
  72   elim (lift_inv_flat2 … H) -H #V #X0 #_ #H0 #H destruct
  73   elim (lift_inv_bind2 … H0) -H0 #V0 #T #_ #_ #H0 destruct /2 width=1/
  74 | #a #L #W #W0 #U #K #d #e #_ #X #H
  75   elim (lift_inv_flat2 … H) -H #V #X0 #_ #H0 #H destruct
  76   elim (lift_inv_bind2 … H0) -H0 #V0 #T #_ #_ #H0 destruct /2 width=1/
  77 ]
  78 qed.