matita/matita/contribs/lambdadelta/basic_2/reduction/fpbc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/btpredproper_8.ma".
  16 include "basic_2/relocation/fquq_alt.ma".
  17 include "basic_2/reduction/fpb.ma".
  18
  19 (* "BIG TREE" PROPER PARALLEL REDUCTION FOR CLOSURES ************************)
  20
  21 inductive fpbc (h) (g) (G1) (L1) (T1): relation3 genv lenv term ≝
  22 | fpbc_fqu: ∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ → fpbc h g G1 L1 T1 G2 L2 T2
  23 | fpbc_cpx: ∀T2. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] T2 → (T1 = T2 → ⊥) → fpbc h g G1 L1 T1 G1 L1 T2
  24 .
  25
  26 interpretation
  27    "'big tree' proper parallel reduction (closure)"
  28    'BTPRedProper h g G1 L1 T1 G2 L2 T2 = (fpbc h g G1 L1 T1 G2 L2 T2).
  29
  30 (* Basic properties *********************************************************)
  31
  32 lemma fpbc_fpb: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻[h, g] ⦃G2, L2, T2⦄ →
  33                 ⦃G1, L1, T1⦄ ≽[h, g] ⦃G2, L2, T2⦄.
  34 #h #g #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2
  35 /3 width=1 by fpb_fquq, fpb_cpx, fqu_fquq/
  36 qed.
  37
  38 lemma cpr_fpbc: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → (T1 = T2 → ⊥) →
  39                 ⦃G, L, T1⦄ ≻[h, g] ⦃G, L, T2⦄.
  40 /3 width=1 by fpbc_cpx, cpr_cpx/ qed.
  41
  42 (* Inversion lemmas on "big tree" parallel reduction for closures ***********)
  43
  44 lemma fpb_inv_fpbc: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≽[h, g] ⦃G2, L2, T2⦄ →
  45                     ⦃G1, L1, T1⦄ ≻[h, g] ⦃G2, L2, T2⦄ ∨
  46                     ∧∧ G1 = G2 & ⦃G1, L1⦄ ⊢ ➡[h, g] L2 & T1 = T2.
  47 #h #g #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2
  48 /3 width=1 by and3_intro, or_intror/
  49 [ #G2 #L2 #T2 #H elim (fquq_inv_gen … H) -H [| * ]
  50   /3 width=1 by fpbc_fqu, and3_intro, or_introl, or_intror/
  51 | #T2 #HT12 elim (term_eq_dec T1 T2) #H destruct
  52   /4 width=1 by and3_intro, or_introl, or_intror, fpbc_cpx/
  53 ]
  54 qed-.