matita/matita/contribs/lambdadelta/basic_2/reduction/lpr_lpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lpx_sn_lpx_sn.ma".
  16 include "basic_2/substitution/fsupp.ma".
  17 include "basic_2/reduction/lpr_ldrop.ma".
  18
  19 (* SN PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS *****************************)
  20
  21 (* Main properties on context-sensitive parallel reduction for terms ********)
  22
  23 fact cpr_conf_lpr_atom_atom:
  24    ∀I,L1,L2. ∃∃T. L1 ⊢ ⓪{I} ➡ T & L2 ⊢ ⓪{I} ➡ T.
  25 /2 width=3/ qed-.
  26
  27 fact cpr_conf_lpr_atom_delta:
  28    ∀L0,i. (
  29       ∀L,T. ⦃L0, #i⦄ ⊃+ ⦃L, T⦄ →
  30       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
  31       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
  32       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
  33    ) →
  34    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  35    ∀V2. K0 ⊢ V0 ➡ V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  36    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
  37    ∃∃T. L1 ⊢ #i ➡ T & L2 ⊢ T2 ➡ T.
  38 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  39 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  40 elim (lpr_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  41 elim (lpr_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  42 elim (lpr_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  43 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  44 lapply (fsupp_lref … HLK0) -HLK0 #HLK0
  45 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  46 elim (lift_total V 0 (i+1)) #T #HVT
  47 lapply (cpr_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  48 qed-.
  49
  50 (* Basic_1: includes: pr0_delta_delta pr2_delta_delta *)
  51 fact cpr_conf_lpr_delta_delta:
  52    ∀L0,i. (
  53       ∀L,T. ⦃L0, #i⦄ ⊃+ ⦃L, T⦄ →
  54       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
  55       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
  56       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
  57    ) →
  58    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  59    ∀V1. K0 ⊢ V0 ➡ V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  60    ∀KX,VX. ⇩[O, i] L0 ≡ KX.ⓓVX →
  61    ∀V2. KX ⊢ VX ➡ V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  62    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
  63    ∃∃T. L1 ⊢ T1 ➡ T & L2 ⊢ T2 ➡ T.
  64 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  65 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  66 lapply (ldrop_mono … H … HLK0) -H #H destruct
  67 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  68 elim (lpr_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  69 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  70 elim (lpr_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  71 elim (lpr_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  72 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  73 lapply (fsupp_lref … HLK0) -HLK0 #HLK0
  74 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  75 elim (lift_total V 0 (i+1)) #T #HVT
  76 lapply (cpr_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
  77 lapply (cpr_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
  78 qed-.
  79
  80 fact cpr_conf_lpr_bind_bind:
  81    ∀a,I,L0,V0,T0. (
  82       ∀L,T. ⦃L0,ⓑ{a,I}V0.T0⦄ ⊃+ ⦃L, T⦄ →
  83       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
  84       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
  85       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
  86    ) →
  87    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓑ{I}V0 ⊢ T0 ➡ T1 →
  88    ∀V2. L0 ⊢ V0 ➡ V2 → ∀T2. L0.ⓑ{I}V0 ⊢ T0 ➡ T2 →
  89    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
  90    ∃∃T. L1 ⊢ ⓑ{a,I}V1.T1 ➡ T & L2 ⊢ ⓑ{a,I}V2.T2 ➡ T.
  91 #a #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
  92 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
  93 elim (IH … HV01 … HV02 … HL01 … HL02) //
  94 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
  95 qed-.
  96
  97 fact cpr_conf_lpr_bind_zeta:
  98    ∀L0,V0,T0. (
  99       ∀L,T. ⦃L0,+ⓓV0.T0⦄ ⊃+ ⦃L, T⦄ →
 100       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 101       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 102       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 103    ) →
 104    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓓV0 ⊢ T0 ➡ T1 →
 105    ∀T2. L0.ⓓV0 ⊢ T0 ➡ T2 → ∀X2. ⇧[O, 1] X2 ≡ T2 →
 106    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 107    ∃∃T. L1 ⊢ +ⓓV1.T1 ➡ T & L2 ⊢ X2 ➡ T.
 108 #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 109 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 110 elim (IH … HT01 … HT02 (L1.ⓓV1) … (L2.ⓓV1)) -IH -HT01 -HT02 // /2 width=1/ -L0 -V0 -T0 #T #HT1 #HT2
 111 elim (cpr_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=1/ /3 width=3/
 112 qed-.
 113
 114 fact cpr_conf_lpr_zeta_zeta:
 115    ∀L0,V0,T0. (
 116       ∀L,T. ⦃L0,+ⓓV0.T0⦄ ⊃+ ⦃L, T⦄ →
 117       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 118       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 119       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 120    ) →
 121    ∀T1. L0.ⓓV0 ⊢ T0 ➡ T1 → ∀X1. ⇧[O, 1] X1 ≡ T1 →
 122    ∀T2. L0.ⓓV0 ⊢ T0 ➡ T2 → ∀X2. ⇧[O, 1] X2 ≡ T2 →
 123    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 124    ∃∃T. L1 ⊢ X1 ➡ T & L2 ⊢ X2 ➡ T.
 125 #L0 #V0 #T0 #IH #T1 #HT01 #X1 #HXT1
 126 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 127 elim (IH … HT01 … HT02 (L1.ⓓV0) … (L2.ⓓV0)) -IH -HT01 -HT02 // /2 width=1/ -L0 -T0 #T #HT1 #HT2
 128 elim (cpr_inv_lift1 … HT1 L1 … HXT1) -T1 /2 width=1/ #T1 #HT1 #HXT1
 129 elim (cpr_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=1/ #T2 #HT2 #HXT2
 130 lapply (lift_inj … HT2 … HT1) -T #H destruct /2 width=3/
 131 qed-.
 132
 133 fact cpr_conf_lpr_flat_flat:
 134    ∀I,L0,V0,T0. (
 135       ∀L,T. ⦃L0,ⓕ{I}V0.T0⦄ ⊃+ ⦃L, T⦄ →
 136       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 137       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 138       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 139    ) →
 140    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0 ⊢ T0 ➡ T1 →
 141    ∀V2. L0 ⊢ V0 ➡ V2 → ∀T2. L0 ⊢ T0 ➡ T2 →
 142    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 143    ∃∃T. L1 ⊢ ⓕ{I}V1.T1 ➡ T & L2 ⊢ ⓕ{I}V2.T2 ➡ T.
 144 #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 145 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 146 elim (IH … HV01 … HV02 … HL01 … HL02) //
 147 elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
 148 qed-.
 149
 150 fact cpr_conf_lpr_flat_tau:
 151    ∀L0,V0,T0. (
 152       ∀L,T. ⦃L0,ⓝV0.T0⦄ ⊃+ ⦃L, T⦄ →
 153       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 154       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 155       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 156    ) →
 157    ∀V1,T1. L0 ⊢ T0 ➡ T1 → ∀T2. L0 ⊢ T0 ➡ T2 →
 158    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 159    ∃∃T. L1 ⊢ ⓝV1.T1 ➡ T & L2 ⊢ T2 ➡ T.
 160 #L0 #V0 #T0 #IH #V1 #T1 #HT01
 161 #T2 #HT02 #L1 #HL01 #L2 #HL02
 162 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /3 width=3/
 163 qed-.
 164
 165 fact cpr_conf_lpr_tau_tau:
 166    ∀L0,V0,T0. (
 167       ∀L,T. ⦃L0,ⓝV0.T0⦄ ⊃+ ⦃L, T⦄ →
 168       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 169       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 170       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 171    ) →
 172    ∀T1. L0 ⊢ T0 ➡ T1 → ∀T2. L0 ⊢ T0 ➡ T2 →
 173    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 174    ∃∃T. L1 ⊢ T1 ➡ T & L2 ⊢ T2 ➡ T.
 175 #L0 #V0 #T0 #IH #T1 #HT01
 176 #T2 #HT02 #L1 #HL01 #L2 #HL02
 177 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /2 width=3/
 178 qed-.
 179
 180 fact cpr_conf_lpr_flat_beta:
 181    ∀a,L0,V0,W0,T0. (
 182       ∀L,T. ⦃L0,ⓐV0.ⓛ{a}W0.T0⦄ ⊃+ ⦃L, T⦄ →
 183       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 184       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 185       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 186    ) →
 187    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0 ⊢ ⓛ{a}W0.T0 ➡ T1 →
 188    ∀V2. L0 ⊢ V0 ➡ V2 → ∀T2. L0.ⓛW0 ⊢ T0 ➡ T2 →
 189    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 190    ∃∃T. L1 ⊢ ⓐV1.T1 ➡ T & L2 ⊢ ⓓ{a}V2.T2 ➡ T.
 191 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #X #H
 192 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 193 elim (cpr_inv_abst1 … H) -H #W1 #T1 #HW01 #HT01 #H destruct
 194 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 195 elim (IH … HT01 … HT02 (L1.ⓛW1) … (L2.ⓛW1)) /2 width=1/ -L0 -V0 -W0 -T0 #T #HT1 #HT2
 196 lapply (cpr_lsubr_trans … HT2 (L2.ⓓV2) ?) -HT2 /2 width=1/ /3 width=5/
 197 qed-.
 198
 199 (* Basic-1: includes:
 200             pr0_cong_upsilon_refl pr0_cong_upsilon_zeta
 201             pr0_cong_upsilon_cong pr0_cong_upsilon_delta
 202 *)
 203 fact cpr_conf_lpr_flat_theta:
 204    ∀a,L0,V0,W0,T0. (
 205       ∀L,T. ⦃L0,ⓐV0.ⓓ{a}W0.T0⦄ ⊃+ ⦃L, T⦄ →
 206       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 207       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 208       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 209    ) →
 210    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0 ⊢ ⓓ{a}W0.T0 ➡ T1 →
 211    ∀V2. L0 ⊢ V0 ➡ V2 → ∀U2. ⇧[O, 1] V2 ≡ U2 →
 212    ∀W2. L0 ⊢ W0 ➡ W2 → ∀T2. L0.ⓓW0 ⊢ T0 ➡ T2 →
 213    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 214    ∃∃T. L1 ⊢ ⓐV1.T1 ➡ T & L2 ⊢ ⓓ{a}W2.ⓐU2.T2 ➡ T.
 215 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #X #H
 216 #V2 #HV02 #U2 #HVU2 #W2 #HW02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 217 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 218 elim (lift_total V 0 1) #U #HVU
 219 lapply (cpr_lift … HV2 (L2.ⓓW2) … HVU2 … HVU) -HVU2 /2 width=1/ #HU2
 220 elim (cpr_inv_abbr1 … H) -H *
 221 [ #W1 #T1 #HW01 #HT01 #H destruct
 222   elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1/
 223   elim (IH … HT01 … HT02 (L1.ⓓW1) … (L2.ⓓW2)) /2 width=1/ -L0 -V0 -W0 -T0
 224   /4 width=7 by cpr_bind, cpr_flat, cpr_theta, ex2_intro/ (**) (* timeout=35 *)
 225 | #T1 #HT01 #HXT1 #H destruct
 226   elim (IH … HT01 … HT02 (L1.ⓓW2) … (L2.ⓓW2)) /2 width=1/ -L0 -V0 -W0 -T0 #T #HT1 #HT2
 227   elim (cpr_inv_lift1 … HT1 L1 … HXT1) -HXT1 /2 width=1/ #Y #HYT #HXY
 228   @(ex2_intro … (ⓐV.Y)) /2 width=1/ /3 width=5/ (**) (* auto /4 width=9/ is too slow *)
 229 ]
 230 qed-.
 231
 232 fact cpr_conf_lpr_beta_beta:
 233    ∀a,L0,V0,W0,T0. (
 234       ∀L,T. ⦃L0,ⓐV0.ⓛ{a}W0.T0⦄ ⊃+ ⦃L, T⦄ →
 235       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 236       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 237       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 238    ) →
 239    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓛW0 ⊢ T0 ➡ T1 →
 240    ∀V2. L0 ⊢ V0 ➡ V2 → ∀T2. L0.ⓛW0 ⊢ T0 ➡ T2 →
 241    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 242    ∃∃T. L1 ⊢ ⓓ{a}V1.T1 ➡ T & L2 ⊢ ⓓ{a}V2.T2 ➡ T.
 243 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #T1 #HT01
 244 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 245 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 246 elim (IH … HT01 … HT02 (L1.ⓛW0) … (L2.ⓛW0)) /2 width=1/ -L0 -V0 -T0 #T #HT1 #HT2
 247 lapply (cpr_lsubr_trans … HT1 (L1.ⓓV1) ?) -HT1 /2 width=1/
 248 lapply (cpr_lsubr_trans … HT2 (L2.ⓓV2) ?) -HT2 /2 width=1/ /3 width=5/
 249 qed-.
 250
 251 (* Basic_1: was: pr0_upsilon_upsilon *)
 252 fact cpr_conf_lpr_theta_theta:
 253    ∀a,L0,V0,W0,T0. (
 254       ∀L,T. ⦃L0,ⓐV0.ⓓ{a}W0.T0⦄ ⊃+ ⦃L, T⦄ →
 255       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 256       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 257       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 258    ) →
 259    ∀V1. L0 ⊢ V0 ➡ V1 → ∀U1. ⇧[O, 1] V1 ≡ U1 →
 260    ∀W1. L0 ⊢ W0 ➡ W1 → ∀T1. L0.ⓓW0 ⊢ T0 ➡ T1 →
 261    ∀V2. L0 ⊢ V0 ➡ V2 → ∀U2. ⇧[O, 1] V2 ≡ U2 →
 262    ∀W2. L0 ⊢ W0 ➡ W2 → ∀T2. L0.ⓓW0 ⊢ T0 ➡ T2 →
 263    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 264    ∃∃T. L1 ⊢ ⓓ{a}W1.ⓐU1.T1 ➡ T & L2 ⊢ ⓓ{a}W2.ⓐU2.T2 ➡ T.
 265 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #U1 #HVU1 #W1 #HW01 #T1 #HT01
 266 #V2 #HV02 #U2 #HVU2 #W2 #HW02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 267 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 268 elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1/
 269 elim (IH … HT01 … HT02 (L1.ⓓW1) … (L2.ⓓW2)) /2 width=1/ -L0 -V0 -W0 -T0
 270 elim (lift_total V 0 1) #U #HVU
 271 lapply (cpr_lift … HV1 (L1.ⓓW1) … HVU1 … HVU) -HVU1 /2 width=1/
 272 lapply (cpr_lift … HV2 (L2.ⓓW2) … HVU2 … HVU) -HVU2 /2 width=1/
 273 /4 width=7 by cpr_bind, cpr_flat, ex2_intro/ (**) (* timeout 40 *)
 274 qed-.
 275
 276 theorem cpr_conf_lpr: lpx_sn_confluent cpr cpr.
 277 #L0 #T0 @(fsupp_wf_ind … L0 T0) -L0 -T0 #L #T #IH #L0 * [|*]
 278 [ #I0 #HL #HT #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 279   elim (cpr_inv_atom1 … H1) -H1
 280   elim (cpr_inv_atom1 … H2) -H2
 281   [ #H2 #H1 destruct
 282     /2 width=1 by cpr_conf_lpr_atom_atom/
 283   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 284     /3 width=10 by cpr_conf_lpr_atom_delta/
 285   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 286     /4 width=10 by ex2_commute, cpr_conf_lpr_atom_delta/
 287   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 288     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 289     /3 width=17 by cpr_conf_lpr_delta_delta/
 290   ]
 291 | #a #I #V0 #T0 #HL #HT #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 292   elim (cpr_inv_bind1 … H1) -H1 *
 293   [ #V1 #T1 #HV01 #HT01 #H1
 294   | #T1 #HT01 #HXT1 #H11 #H12
 295   ]
 296   elim (cpr_inv_bind1 … H2) -H2 *
 297   [1,3: #V2 #T2 #HV02 #HT02 #H2
 298   |2,4: #T2 #HT02 #HXT2 #H21 #H22
 299   ] destruct
 300   [ /3 width=10 by cpr_conf_lpr_bind_bind/
 301   | /4 width=11 by ex2_commute, cpr_conf_lpr_bind_zeta/
 302   | /3 width=11 by cpr_conf_lpr_bind_zeta/
 303   | /3 width=12 by cpr_conf_lpr_zeta_zeta/
 304   ]
 305 | #I #V0 #T0 #HL #HT #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 306   elim (cpr_inv_flat1 … H1) -H1 *
 307   [ #V1 #T1 #HV01 #HT01 #H1
 308   | #HX1 #H1
 309   | #a1 #V1 #Y1 #Z1 #T1 #HV01 #HZT1 #H11 #H12 #H13
 310   | #a1 #V1 #U1 #Y1 #W1 #Z1 #T1 #HV01 #HVU1 #HYW1 #HZT1 #H11 #H12 #H13
 311   ]
 312   elim (cpr_inv_flat1 … H2) -H2 *
 313   [1,5,9,13: #V2 #T2 #HV02 #HT02 #H2
 314   |2,6,10,14: #HX2 #H2
 315   |3,7,11,15: #a2 #V2 #Y2 #Z2 #T2 #HV02 #HZT2 #H21 #H22 #H23
 316   |4,8,12,16: #a2 #V2 #U2 #Y2 #W2 #Z2 #T2 #HV02 #HVU2 #HYW2 #HZT2 #H21 #H22 #H23
 317   ] destruct
 318   [ /3 width=10 by cpr_conf_lpr_flat_flat/
 319   | /4 width=8 by ex2_commute, cpr_conf_lpr_flat_tau/
 320   | /4 width=11 by ex2_commute, cpr_conf_lpr_flat_beta/
 321   | /4 width=14 by ex2_commute, cpr_conf_lpr_flat_theta/
 322   | /3 width=8 by cpr_conf_lpr_flat_tau/
 323   | /3 width=7 by cpr_conf_lpr_tau_tau/
 324   | /3 width=11 by cpr_conf_lpr_flat_beta/
 325   | /3 width=11 by cpr_conf_lpr_beta_beta/
 326   | /3 width=14 by cpr_conf_lpr_flat_theta/
 327   | /3 width=17 by cpr_conf_lpr_theta_theta/
 328   ]
 329 ]
 330 qed-.
 331
 332 (* Basic_1: includes: pr0_confluence pr2_confluence *)
 333 theorem cpr_conf: ∀L. confluent … (cpr L).
 334 /2 width=6 by cpr_conf_lpr/ qed-.
 335
 336 (* Properties on context-sensitive parallel reduction for terms *************)
 337
 338 lemma lpr_cpr_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ➡ T1 → ∀L1. L0 ⊢ ➡ L1 →
 339                        ∃∃T. L1 ⊢ T0 ➡ T & L1 ⊢ T1 ➡ T.
 340 #L0 #T0 #T1 #HT01 #L1 #HL01
 341 elim (cpr_conf_lpr … HT01 T0 … HL01 … HL01) // -L0 /2 width=3/
 342 qed-.
 343
 344 lemma lpr_cpr_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ➡ T1 → ∀L1. L0 ⊢ ➡ L1 →
 345                        ∃∃T. L1 ⊢ T0 ➡ T & L0 ⊢ T1 ➡ T.
 346 #L0 #T0 #T1 #HT01 #L1 #HL01
 347 elim (cpr_conf_lpr … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 348 qed-.
 349
 350 (* Main properties **********************************************************)
 351
 352 theorem lpr_conf: confluent … lpr.
 353 /3 width=6 by lpx_sn_conf, cpr_conf_lpr/
 354 qed-.