matita/matita/contribs/lambdadelta/basic_2/reduction/lpx_lleq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/lleq_leq.ma".
  16 include "basic_2/substitution/lleq_ldrop.ma".
  17 include "basic_2/reduction/cpx_leq.ma".
  18 include "basic_2/reduction/lpx_ldrop.ma".
  19
  20 (* SN EXTENDED PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS ********************)
  21
  22 (* Properties on lazy equivalence for local environments ********************)
  23
  24 axiom lleq_lpx_trans: ∀h,g,G,L2,K2. ⦃G, L2⦄ ⊢ ➡[h, g] K2 →
  25                       ∀L1,T,d. L1 ⋕[T, d] L2 →
  26                       ∃∃K1. ⦃G, L1⦄ ⊢ ➡[h, g] K1 & K1 ⋕[T, d] K2.
  27
  28 lemma lpx_lleq_fqu_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  29                           ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[T1, 0] L1 →
  30                           ∃∃K2. ⦃G1, K1, T1⦄ ⊐ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[T2, 0] L2.
  31 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  32 [ #I #G1 #L1 #V1 #X #H1 #H2 elim (lpx_inv_pair2 … H1) -H1
  33   #K0 #V0 #H1KL1 #_ #H destruct
  34   elim (lleq_inv_lref_ge_dx … H2 ? I L1 V1) -H2 //
  35   #K1 #H #H2KL1 lapply (ldrop_inv_O2 … H) -H #H destruct
  36   /2 width=4 by fqu_lref_O, ex3_intro/
  37 | * [ #a ] #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H
  38   [ elim (lleq_inv_bind … H)
  39   | elim (lleq_inv_flat … H)
  40   ] -H /2 width=4 by fqu_pair_sn, ex3_intro/
  41 | #a #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_bind_O … H) -H
  42   /3 width=4 by lpx_pair, fqu_bind_dx, ex3_intro/
  43 | #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_flat … H) -H
  44   /2 width=4 by fqu_flat_dx, ex3_intro/
  45 | #G1 #L1 #L #T1 #U1 #e #HL1 #HTU1 #K1 #H1KL1 #H2KL1
  46   elim (ldrop_O1_le (e+1) K1)
  47   [ #K #HK1 lapply (lleq_inv_lift_le … H2KL1 … HK1 HL1 … HTU1 ?) -H2KL1 //
  48     #H2KL elim (lpx_ldrop_trans_O1 … H1KL1 … HL1) -L1
  49     #K0 #HK10 #H1KL lapply (ldrop_mono … HK10 … HK1) -HK10 #H destruct
  50     /3 width=4 by fqu_drop, ex3_intro/
  51   | lapply (ldrop_fwd_length_le2 … HL1) -L -T1 -g
  52     lapply (lleq_fwd_length … H2KL1) //
  53   ]
  54 ]
  55 qed-.
  56
  57 lemma lpx_lleq_fquq_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  58                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[T1, 0] L1 →
  59                            ∃∃K2. ⦃G1, K1, T1⦄ ⊐⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[T2, 0] L2.
  60 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  61 elim (fquq_inv_gen … H) -H
  62 [ #H elim (lpx_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  63   /3 width=4 by fqu_fquq, ex3_intro/
  64 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
  65 ]
  66 qed-.
  67
  68 lemma lpx_lleq_fqup_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
  69                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[T1, 0] L1 →
  70                            ∃∃K2. ⦃G1, K1, T1⦄ ⊐+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[T2, 0] L2.
  71 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  72 [ #G2 #L2 #T2 #H #K1 #H1KL1 #H2KL1 elim (lpx_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  73   /3 width=4 by fqu_fqup, ex3_intro/
  74 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #K1 #H1KL1 #H2KL1 elim (IHT1 … H2KL1) // -L1
  75   #K #HT1 #H1KL #H2KL elim (lpx_lleq_fqu_trans … HT2 … H1KL H2KL) -L
  76   /3 width=5 by fqup_strap1, ex3_intro/
  77 ]
  78 qed-.
  79
  80 lemma lpx_lleq_fqus_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
  81                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[T1, 0] L1 →
  82                            ∃∃K2. ⦃G1, K1, T1⦄ ⊐* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[T2, 0] L2.
  83 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  84 elim (fqus_inv_gen … H) -H
  85 [ #H elim (lpx_lleq_fqup_trans … H … H1KL1 H2KL1) -L1
  86   /3 width=4 by fqup_fqus, ex3_intro/
  87 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
  88 ]
  89 qed-.
  90
  91 fact leq_lpx_trans_lleq_aux: ∀h,g,G,L1,L0,d,e. L1 ≃[d, e] L0 → e = ∞ →
  92                              ∀L2. ⦃G, L0⦄ ⊢ ➡[h, g] L2 →
  93                              ∃∃L. L ≃[d, e] L2 & ⦃G, L1⦄ ⊢ ➡[h, g] L &
  94                                   (∀T. L0 ⋕[T, d] L2 ↔ L1 ⋕[T, d] L).
  95 #h #g #G #L1 #L0 #d #e #H elim H -L1 -L0 -d -e
  96 [ #d #e #_ #L2 #H >(lpx_inv_atom1 … H) -H
  97   /3 width=5 by ex3_intro, conj/
  98 | #I1 #I0 #L1 #L0 #V1 #V0 #_ #_ #He destruct
  99 | #I #L1 #L0 #V1 #e #HL10 #IHL10 #He #Y #H
 100   elim (lpx_inv_pair1 … H) -H #L2 #V2 #HL02 #HV02 #H destruct
 101   lapply (ysucc_inv_Y_dx … He) -He #He
 102   elim (IHL10 … HL02) // -IHL10 -HL02 #L #HL2 #HL1 #IH
 103   @(ex3_intro … (L.ⓑ{I}V2)) /3 width=3 by lpx_pair, leq_cpx_trans, leq_pair/
 104   #T elim (IH T) #HL0dx #HL0sn
 105   @conj #H @(lleq_leq_repl … H) -H /3 width=1 by leq_sym, leq_pair_O_Y/
 106 | #I1 #I0 #L1 #L0 #V1 #V0 #d #e #HL10 #IHL10 #He #Y #H
 107   elim (lpx_inv_pair1 … H) -H #L2 #V2 #HL02 #HV02 #H destruct
 108   elim (IHL10 … HL02) // -IHL10 -HL02 #L #HL2 #HL1 #IH
 109   @(ex3_intro … (L.ⓑ{I1}V1)) /3 width=1 by lpx_pair, leq_succ/
 110   #T elim (IH T) #HL0dx #HL0sn
 111   @conj #H @(lleq_leq_repl … H) -H /3 width=1 by leq_sym, leq_succ/
 112 ]
 113 qed-.
 114
 115 lemma leq_lpx_trans_lleq: ∀h,g,G,L1,L0,d. L1 ≃[d, ∞] L0 →
 116                           ∀L2. ⦃G, L0⦄ ⊢ ➡[h, g] L2 →
 117                           ∃∃L. L ≃[d, ∞] L2 & ⦃G, L1⦄ ⊢ ➡[h, g] L &
 118                                (∀T. L0 ⋕[T, d] L2 ↔ L1 ⋕[T, d] L).
 119 /2 width=1 by leq_lpx_trans_lleq_aux/ qed-.