matita/matita/contribs/lambdadelta/basic_2/relocation/cpy.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_max.ma".
  16 include "basic_2/notation/relations/extpsubst_6.ma".
  17 include "basic_2/grammar/genv.ma".
  18 include "basic_2/grammar/cl_shift.ma".
  19 include "basic_2/relocation/ldrop_append.ma".
  20 include "basic_2/relocation/lsuby.ma".
  21
  22 (* CONTEXT-SENSITIVE EXTENDED ORDINARY SUBSTITUTION FOR TERMS ***************)
  23
  24 (* activate genv *)
  25 inductive cpy: ynat → ynat → relation4 genv lenv term term ≝
  26 | cpy_atom : ∀I,G,L,d,e. cpy d e G L (⓪{I}) (⓪{I})
  27 | cpy_subst: ∀I,G,L,K,V,W,i,d,e. d ≤ yinj i → i < d+e →
  28              ⇩[i] L ≡ K.ⓑ{I}V → ⇧[0, i+1] V ≡ W → cpy d e G L (#i) W
  29 | cpy_bind : ∀a,I,G,L,V1,V2,T1,T2,d,e.
  30              cpy d e G L V1 V2 → cpy (⫯d) e G (L.ⓑ{I}V2) T1 T2 →
  31              cpy d e G L (ⓑ{a,I}V1.T1) (ⓑ{a,I}V2.T2)
  32 | cpy_flat : ∀I,G,L,V1,V2,T1,T2,d,e.
  33              cpy d e G L V1 V2 → cpy d e G L T1 T2 →
  34              cpy d e G L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  35 .
  36
  37 interpretation "context-sensitive extended ordinary substritution (term)"
  38    'ExtPSubst G L T1 d e T2 = (cpy d e G L T1 T2).
  39
  40 (* Basic properties *********************************************************)
  41
  42 lemma lsuby_cpy_trans: ∀G,d,e. lsub_trans … (cpy d e G) (lsuby d e).
  43 #G #d #e #L1 #T1 #T2 #H elim H -G -L1 -T1 -T2 -d -e
  44 [ //
  45 | #I #G #L1 #K1 #V #W #i #d #e #Hdi #Hide #HLK1 #HVW #L2 #HL12
  46   elim (lsuby_fwd_ldrop2_be … HL12 … HLK1) -HL12 -HLK1 /2 width=5 by cpy_subst/
  47 | /4 width=1 by lsuby_succ, cpy_bind/
  48 | /3 width=1 by cpy_flat/
  49 ]
  50 qed-.
  51
  52 lemma cpy_refl: ∀G,T,L,d,e. ⦃G, L⦄ ⊢ T ▶×[d, e] T.
  53 #G #T elim T -T // * /2 width=1 by cpy_bind, cpy_flat/
  54 qed.
  55
  56 lemma cpy_full: ∀I,G,K,V,T1,L,d. ⇩[d] L ≡ K.ⓑ{I}V →
  57                 ∃∃T2,T. ⦃G, L⦄ ⊢ T1 ▶×[d, 1] T2 & ⇧[d, 1] T ≡ T2.
  58 #I #G #K #V #T1 elim T1 -T1
  59 [ * #i #L #d #HLK
  60   /2 width=4 by lift_sort, lift_gref, ex2_2_intro/
  61   elim (lt_or_eq_or_gt i d) #Hid
  62   /3 width=4 by lift_lref_ge_minus, lift_lref_lt, ex2_2_intro/
  63   destruct
  64   elim (lift_total V 0 (i+1)) #W #HVW
  65   elim (lift_split … HVW i i)
  66   /4 width=5 by cpy_subst, ylt_inj, ex2_2_intro/
  67 | * [ #a ] #J #W1 #U1 #IHW1 #IHU1 #L #d #HLK
  68   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  69   [ elim (IHU1 (L.ⓑ{J}W2) (d+1)) -IHU1
  70     /3 width=9 by cpy_bind, ldrop_drop, lift_bind, ex2_2_intro/
  71   | elim (IHU1 … HLK) -IHU1 -HLK
  72     /3 width=8 by cpy_flat, lift_flat, ex2_2_intro/
  73   ]
  74 ]
  75 qed-.
  76
  77 lemma cpy_weak: ∀G,L,T1,T2,d1,e1. ⦃G, L⦄ ⊢ T1 ▶×[d1, e1] T2 →
  78                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  79                 ⦃G, L⦄ ⊢ T1 ▶×[d2, e2] T2.
  80 #G #L #T1 #T2 #d1 #e1 #H elim H -G -L -T1 -T2 -d1 -e1 //
  81 [ /3 width=5 by cpy_subst, ylt_yle_trans, yle_trans/
  82 | /4 width=3 by cpy_bind, ylt_yle_trans, yle_succ/
  83 | /3 width=1 by cpy_flat/
  84 ]
  85 qed-.
  86
  87 lemma cpy_weak_top: ∀G,L,T1,T2,d,e.
  88                     ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ⦃G, L⦄ ⊢ T1 ▶×[d, |L| - d] T2.
  89 #G #L #T1 #T2 #d #e #H elim H -G -L -T1 -T2 -d -e //
  90 [ #I #G #L #K #V #W #i #d #e #Hdi #_ #HLK #HVW
  91   lapply (ldrop_fwd_length_lt2 … HLK)
  92   /4 width=5 by cpy_subst, ylt_yle_trans, ylt_inj/
  93 | #a #I #G #L #V1 #V2 normalize in match (|L.ⓑ{I}V2|); (**) (* |?| does not work *)
  94   /2 width=1 by cpy_bind/
  95 | /2 width=1 by cpy_flat/
  96 ]
  97 qed-.
  98
  99 lemma cpy_weak_full: ∀G,L,T1,T2,d,e.
 100                      ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ⦃G, L⦄ ⊢ T1 ▶×[0, |L|] T2.
 101 #G #L #T1 #T2 #d #e #HT12
 102 lapply (cpy_weak … HT12 0 (d + e) ? ?) -HT12
 103 /2 width=2 by cpy_weak_top/
 104 qed-.
 105
 106 lemma cpy_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 107               ∀T1,d,e. ⇧[d, e] T1 ≡ U1 →
 108               d ≤ dt → d + e ≤ dt + et →
 109               ∃∃T2. ⦃G, L⦄ ⊢ U1 ▶×[d+e, dt+et-(d+e)] U2 & ⇧[d, e] T2 ≡ U2.
 110 #G #L #U1 #U2 #dt #et #H elim H -G -L -U1 -U2 -dt -et
 111 [ * #i #G #L #dt #et #T1 #d #e #H #_
 112   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 113   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 114   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 115   ]
 116 | #I #G #L #K #V #W #i #dt #et #Hdti #Hidet #HLK #HVW #T1 #d #e #H #Hddt #Hdedet
 117   elim (lift_inv_lref2 … H) -H * #Hid #H destruct [ -V -Hidet -Hdedet | -Hdti -Hddt ]
 118   [ elim (ylt_yle_false … Hddt) -Hddt /3 width=3 by yle_ylt_trans, ylt_inj/
 119   | elim (le_inv_plus_l … Hid) #Hdie #Hei
 120     elim (lift_split … HVW d (i-e+1) ? ? ?) [2,3,4: /2 width=1 by le_S_S, le_S/ ] -Hdie
 121     #T2 #_ >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O #H -Hei
 122     @(ex2_intro … H) -H @(cpy_subst … HLK HVW) /2 width=1 by yle_inj/ >ymax_pre_sn_comm // (**) (* explicit constructor *)
 123   ]
 124 | #a #I #G #L #W1 #W2 #U1 #U2 #dt #et #_ #_ #IHW12 #IHU12 #X #d #e #H #Hddt #Hdedet
 125   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 126   elim (IHW12 … HVW1) -V1 -IHW12 //
 127   elim (IHU12 … HTU1) -T1 -IHU12 /2 width=1 by yle_succ/
 128   <yplus_inj >yplus_SO2 >yplus_succ1 >yplus_succ1
 129   /3 width=2 by cpy_bind, lift_bind, ex2_intro/
 130 | #I #G #L #W1 #W2 #U1 #U2 #dt #et #_ #_ #IHW12 #IHU12 #X #d #e #H #Hddt #Hdedet
 131   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 132   elim (IHW12 … HVW1) -V1 -IHW12 // elim (IHU12 … HTU1) -T1 -IHU12
 133   /3 width=2 by cpy_flat, lift_flat, ex2_intro/
 134 ]
 135 qed-.
 136
 137 lemma cpy_split_up: ∀G,L,T1,T2,d,e. ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ∀i. i ≤ d + e →
 138                     ∃∃T. ⦃G, L⦄ ⊢ T1 ▶×[d, i-d] T & ⦃G, L⦄ ⊢ T ▶×[i, d+e-i] T2.
 139 #G #L #T1 #T2 #d #e #H elim H -G -L -T1 -T2 -d -e
 140 [ /2 width=3 by ex2_intro/
 141 | #I #G #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hjde
 142   elim (ylt_split i j) [ -Hide -Hjde | -Hdi ]
 143   /4 width=9 by cpy_subst, ylt_yle_trans, ex2_intro/
 144 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hide
 145   elim (IHV12 i) -IHV12 // #V
 146   elim (IHT12 (i+1)) -IHT12 /2 width=1 by yle_succ/ -Hide
 147   >yplus_SO2 >yplus_succ1 #T #HT1 #HT2
 148   lapply (lsuby_cpy_trans … HT1 (L.ⓑ{I}V) ?) -HT1
 149   /3 width=5 by lsuby_succ, ex2_intro, cpy_bind/
 150 | #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hide
 151   elim (IHV12 i) -IHV12 // elim (IHT12 i) -IHT12 // -Hide
 152   /3 width=5 by ex2_intro, cpy_flat/
 153 ]
 154 qed-.
 155
 156 lemma cpy_split_down: ∀G,L,T1,T2,d,e. ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ∀i. i ≤ d + e →
 157                       ∃∃T. ⦃G, L⦄ ⊢ T1 ▶×[i, d+e-i] T & ⦃G, L⦄ ⊢ T ▶×[d, i-d] T2.
 158 #G #L #T1 #T2 #d #e #H elim H -G -L -T1 -T2 -d -e
 159 [ /2 width=3 by ex2_intro/
 160 | #I #G #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hjde
 161   elim (ylt_split i j) [ -Hide -Hjde | -Hdi ]
 162   /4 width=9 by cpy_subst, ylt_yle_trans, ex2_intro/
 163 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hide
 164   elim (IHV12 i) -IHV12 // #V
 165   elim (IHT12 (i+1)) -IHT12 /2 width=1 by yle_succ/ -Hide
 166   >yplus_SO2 >yplus_succ1 #T #HT1 #HT2
 167   lapply (lsuby_cpy_trans … HT1 (L. ⓑ{I} V) ?) -HT1
 168   /3 width=5 by lsuby_succ, ex2_intro, cpy_bind/
 169 | #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hide
 170   elim (IHV12 i) -IHV12 // elim (IHT12 i) -IHT12 // -Hide
 171   /3 width=5 by ex2_intro, cpy_flat/
 172 ]
 173 qed-.
 174
 175 lemma cpy_append: ∀G,d,e. l_appendable_sn … (cpy d e G).
 176 #G #d #e #K #T1 #T2 #H elim H -G -K -T1 -T2 -d -e
 177 /2 width=1 by cpy_atom, cpy_bind, cpy_flat/
 178 #I #G #K #K0 #V #W #i #d #e #Hdi #Hide #HK0 #HVW #L
 179 lapply (ldrop_fwd_length_lt2 … HK0) #H
 180 @(cpy_subst I … (L@@K0) … HVW) // (**) (* /4/ does not work *)
 181 @(ldrop_O1_append_sn_le … HK0) /2 width=2 by lt_to_le/
 182 qed-.
 183
 184 (* Basic inversion lemmas ***************************************************)
 185
 186 fact cpy_inv_atom1_aux: ∀G,L,T1,T2,d,e. ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ∀J. T1 = ⓪{J} →
 187                         T2 = ⓪{J} ∨
 188                         ∃∃I,K,V,i. d ≤ yinj i & i < d + e &
 189                                    ⇩[i] L ≡ K.ⓑ{I}V &
 190                                    ⇧[O, i+1] V ≡ T2 &
 191                                    J = LRef i.
 192 #G #L #T1 #T2 #d #e * -G -L -T1 -T2 -d -e
 193 [ #I #G #L #d #e #J #H destruct /2 width=1 by or_introl/
 194 | #I #G #L #K #V #T2 #i #d #e #Hdi #Hide #HLK #HVT2 #J #H destruct /3 width=9 by ex5_4_intro, or_intror/
 195 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 196 | #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 197 ]
 198 qed-.
 199
 200 lemma cpy_inv_atom1: ∀I,G,L,T2,d,e. ⦃G, L⦄ ⊢ ⓪{I} ▶×[d, e] T2 →
 201                      T2 = ⓪{I} ∨
 202                      ∃∃J,K,V,i. d ≤ yinj i & i < d + e &
 203                                 ⇩[i] L ≡ K.ⓑ{J}V &
 204                                 ⇧[O, i+1] V ≡ T2 &
 205                                 I = LRef i.
 206 /2 width=4 by cpy_inv_atom1_aux/ qed-.
 207
 208 lemma cpy_inv_sort1: ∀G,L,T2,k,d,e. ⦃G, L⦄ ⊢ ⋆k ▶×[d, e] T2 → T2 = ⋆k.
 209 #G #L #T2 #k #d #e #H
 210 elim (cpy_inv_atom1 … H) -H //
 211 * #I #K #V #i #_ #_ #_ #_ #H destruct
 212 qed-.
 213
 214 lemma cpy_inv_lref1: ∀G,L,T2,i,d,e. ⦃G, L⦄ ⊢ #i ▶×[d, e] T2 →
 215                      T2 = #i ∨
 216                      ∃∃I,K,V. d ≤ i & i < d + e &
 217                               ⇩[i] L ≡ K.ⓑ{I}V &
 218                               ⇧[O, i+1] V ≡ T2.
 219 #G #L #T2 #i #d #e #H
 220 elim (cpy_inv_atom1 … H) -H /2 width=1 by or_introl/
 221 * #I #K #V #j #Hdj #Hjde #HLK #HVT2 #H destruct /3 width=5 by ex4_3_intro, or_intror/
 222 qed-.
 223
 224 lemma cpy_inv_gref1: ∀G,L,T2,p,d,e. ⦃G, L⦄ ⊢ §p ▶×[d, e] T2 → T2 = §p.
 225 #G #L #T2 #p #d #e #H
 226 elim (cpy_inv_atom1 … H) -H //
 227 * #I #K #V #i #_ #_ #_ #_ #H destruct
 228 qed-.
 229
 230 fact cpy_inv_bind1_aux: ∀G,L,U1,U2,d,e. ⦃G, L⦄ ⊢ U1 ▶×[d, e] U2 →
 231                         ∀a,I,V1,T1. U1 = ⓑ{a,I}V1.T1 →
 232                         ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶×[d, e] V2 &
 233                                  ⦃G, L. ⓑ{I}V2⦄ ⊢ T1 ▶×[⫯d, e] T2 &
 234                                  U2 = ⓑ{a,I}V2.T2.
 235 #G #L #U1 #U2 #d #e * -G -L -U1 -U2 -d -e
 236 [ #I #G #L #d #e #b #J #W1 #U1 #H destruct
 237 | #I #G #L #K #V #W #i #d #e #_ #_ #_ #_ #b #J #W1 #U1 #H destruct
 238 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #b #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 239 | #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #b #J #W1 #U1 #H destruct
 240 ]
 241 qed-.
 242
 243 lemma cpy_inv_bind1: ∀a,I,G,L,V1,T1,U2,d,e. ⦃G, L⦄ ⊢ ⓑ{a,I} V1. T1 ▶×[d, e] U2 →
 244                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶×[d, e] V2 &
 245                               ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ▶×[⫯d, e] T2 &
 246                               U2 = ⓑ{a,I}V2.T2.
 247 /2 width=3 by cpy_inv_bind1_aux/ qed-.
 248
 249 fact cpy_inv_flat1_aux: ∀G,L,U1,U2,d,e. ⦃G, L⦄ ⊢ U1 ▶×[d, e] U2 →
 250                         ∀I,V1,T1. U1 = ⓕ{I}V1.T1 →
 251                         ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶×[d, e] V2 &
 252                                  ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 &
 253                                  U2 = ⓕ{I}V2.T2.
 254 #G #L #U1 #U2 #d #e * -G -L -U1 -U2 -d -e
 255 [ #I #G #L #d #e #J #W1 #U1 #H destruct
 256 | #I #G #L #K #V #W #i #d #e #_ #_ #_ #_ #J #W1 #U1 #H destruct
 257 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #J #W1 #U1 #H destruct
 258 | #I #G #L #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 259 ]
 260 qed-.
 261
 262 lemma cpy_inv_flat1: ∀I,G,L,V1,T1,U2,d,e. ⦃G, L⦄ ⊢ ⓕ{I} V1. T1 ▶×[d, e] U2 →
 263                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶×[d, e] V2 &
 264                               ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 &
 265                               U2 = ⓕ{I}V2.T2.
 266 /2 width=3 by cpy_inv_flat1_aux/ qed-.
 267
 268
 269 fact cpy_inv_refl_O2_aux: ∀G,L,T1,T2,d,e. ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → e = 0 → T1 = T2.
 270 #G #L #T1 #T2 #d #e #H elim H -G -L -T1 -T2 -d -e
 271 [ //
 272 | #I #G #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #H destruct
 273   elim (ylt_yle_false … Hdi) -Hdi //
 274 | /3 width=1 by eq_f2/
 275 | /3 width=1 by eq_f2/
 276 ]
 277 qed-.
 278
 279 lemma cpy_inv_refl_O2: ∀G,L,T1,T2,d. ⦃G, L⦄ ⊢ T1 ▶×[d, 0] T2 → T1 = T2.
 280 /2 width=6 by cpy_inv_refl_O2_aux/ qed-.
 281
 282 lemma cpy_inv_lift1_eq: ∀G,T1,U1,d,e. ⇧[d, e] T1 ≡ U1 →
 283                         ∀L,U2. ⦃G, L⦄ ⊢ U1 ▶×[d, e] U2 → U1 = U2.
 284 #G #T1 #U1 #d #e #HTU1 #L #U2 #HU12 elim (cpy_up … HU12 … HTU1) -HU12 -HTU1
 285 /2 width=4 by cpy_inv_refl_O2/
 286 qed-.
 287
 288 (* Basic forward lemmas *****************************************************)
 289
 290 lemma cpy_fwd_tw: ∀G,L,T1,T2,d,e. ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ♯{T1} ≤ ♯{T2}.
 291 #G #L #T1 #T2 #d #e #H elim H -G -L -T1 -T2 -d -e normalize
 292 /3 width=1 by monotonic_le_plus_l, le_plus/
 293 qed-.
 294
 295 lemma cpy_fwd_shift1: ∀G,L1,L,T1,T,d,e. ⦃G, L⦄ ⊢ L1 @@ T1 ▶×[d, e] T →
 296                       ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 297 #G #L1 @(lenv_ind_dx … L1) -L1 normalize
 298 [ #L #T1 #T #d #e #HT1
 299   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 300 | #I #L1 #V1 #IH #L #T1 #X #d #e
 301   >shift_append_assoc normalize #H
 302   elim (cpy_inv_bind1 … H) -H
 303   #V0 #T0 #_ #HT10 #H destruct
 304   elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 305   >append_length >HL12 -HL12
 306   @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] (**) (* explicit constructor *)
 307   /2 width=3 by trans_eq/
 308 ]
 309 qed-.