matita/matita/contribs/lambdadelta/basic_2/relocation/cpy_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/ldrop_ldrop.ma".
  16 include "basic_2/relocation/cpy.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED ORDINARY SUBSTITUTION FOR TERMS ***************)
  19
  20 (* Properties on relocation *************************************************)
  21
  22 lemma cpy_lift_le: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶×[dt, et] T2 →
  23                    ∀L,U1,U2,s,d,e. ⇩[s, d, e] L ≡ K →
  24                    ⇧[d, e] T1 ≡ U1 → ⇧[d, e] T2 ≡ U2 →
  25                    dt + et ≤ d → ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2.
  26 #G #K #T1 #T2 #dt #et #H elim H -G -K -T1 -T2 -dt -et
  27 [ #I #G #K #dt #et #L #U1 #U2 #s #d #e #_ #H1 #H2 #_
  28   >(lift_mono … H1 … H2) -H1 -H2 //
  29 | #I #G #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #s #d #e #HLK #H #HWU2 #Hdetd
  30   lapply (ylt_yle_trans … Hdetd … Hidet) -Hdetd #Hid
  31   lapply (ylt_inv_inj … Hid) -Hid #Hid
  32   lapply (lift_inv_lref1_lt … H … Hid) -H #H destruct
  33   elim (lift_trans_ge … HVW … HWU2) -W // <minus_plus #W #HVW #HWU2
  34   elim (ldrop_trans_le … HLK … HKV) -K /2 width=2 by lt_to_le/ #X #HLK #H
  35   elim (ldrop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ -Hid #K #Y #_ #HVY
  36   >(lift_mono … HVY … HVW) -Y -HVW #H destruct /2 width=5 by cpy_subst/
  37 | #a #I #G #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #d #e #HLK #H1 #H2 #Hdetd
  38   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  39   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  40   /4 width=7 by cpy_bind, ldrop_skip, yle_succ/
  41 | #G #I #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #d #e #HLK #H1 #H2 #Hdetd
  42   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  43   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  44   /3 width=7 by cpy_flat/
  45 ]
  46 qed-.
  47
  48 lemma cpy_lift_be: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶×[dt, et] T2 →
  49                    ∀L,U1,U2,s,d,e. ⇩[s, d, e] L ≡ K →
  50                    ⇧[d, e] T1 ≡ U1 → ⇧[d, e] T2 ≡ U2 →
  51                    dt ≤ d → d ≤ dt + et → ⦃G, L⦄ ⊢ U1 ▶×[dt, et + e] U2.
  52 #G #K #T1 #T2 #dt #et #H elim H -G -K -T1 -T2 -dt -et
  53 [ #I #G #K #dt #et #L #U1 #U2 #s #d #e #_ #H1 #H2 #_ #_
  54   >(lift_mono … H1 … H2) -H1 -H2 //
  55 | #I #G #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #s #d #e #HLK #H #HWU2 #Hdtd #_
  56   elim (lift_inv_lref1 … H) -H * #Hid #H destruct
  57   [ -Hdtd
  58     lapply (ylt_yle_trans … (dt+et+e) … Hidet) // -Hidet #Hidete
  59     elim (lift_trans_ge … HVW … HWU2) -W // <minus_plus #W #HVW #HWU2
  60     elim (ldrop_trans_le … HLK … HKV) -K /2 width=2 by lt_to_le/ #X #HLK #H
  61     elim (ldrop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ -Hid #K #Y #_ #HVY
  62     >(lift_mono … HVY … HVW) -V #H destruct /2 width=5 by cpy_subst/
  63   | -Hdti
  64     elim (yle_inv_inj2 … Hdtd) -Hdtd #dtt #Hdtd #H destruct
  65     lapply (transitive_le … Hdtd Hid) -Hdtd #Hdti
  66     lapply (lift_trans_be … HVW … HWU2 ? ?) -W /2 width=1 by le_S/ >plus_plus_comm_23 #HVU2
  67     lapply (ldrop_trans_ge_comm … HLK … HKV ?) -K // -Hid
  68     /4 width=5 by cpy_subst, ldrop_inv_gen, monotonic_ylt_plus_dx, yle_plus_dx1_trans, yle_inj/
  69   ]
  70 | #a #I #G #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #d #e #HLK #H1 #H2 #Hdtd #Hddet
  71   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  72   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  73   /4 width=7 by cpy_bind, ldrop_skip, yle_succ/
  74 | #I #G #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #d #e #HLK #H1 #H2 #Hdetd
  75   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  76   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  77   /3 width=7 by cpy_flat/
  78 ]
  79 qed-.
  80
  81 lemma cpy_lift_ge: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶×[dt, et] T2 →
  82                    ∀L,U1,U2,s,d,e. ⇩[s, d, e] L ≡ K →
  83                    ⇧[d, e] T1 ≡ U1 → ⇧[d, e] T2 ≡ U2 →
  84                    d ≤ dt → ⦃G, L⦄ ⊢ U1 ▶×[dt+e, et] U2.
  85 #G #K #T1 #T2 #dt #et #H elim H -G -K -T1 -T2 -dt -et
  86 [ #I #G #K #dt #et #L #U1 #U2 #s #d #e #_ #H1 #H2 #_
  87   >(lift_mono … H1 … H2) -H1 -H2 //
  88 | #I #G #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #s #d #e #HLK #H #HWU2 #Hddt
  89   lapply (yle_trans … Hddt … Hdti) -Hddt #Hid
  90   elim (yle_inv_inj2 … Hid) -Hid #dd #Hddi #H0 destruct
  91   lapply (lift_inv_lref1_ge … H … Hddi) -H #H destruct
  92   lapply (lift_trans_be … HVW … HWU2 ? ?) -W /2 width=1 by le_S/ >plus_plus_comm_23 #HVU2
  93   lapply (ldrop_trans_ge_comm … HLK … HKV ?) -K // -Hddi
  94   /3 width=5 by cpy_subst, ldrop_inv_gen, monotonic_ylt_plus_dx, monotonic_yle_plus_dx/
  95 | #a #I #G #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #d #e #HLK #H1 #H2 #Hddt
  96   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  97   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  98   /4 width=6 by cpy_bind, ldrop_skip, yle_succ/
  99 | #I #G #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #d #e #HLK #H1 #H2 #Hddt
 100   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
 101   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
 102   /3 width=6 by cpy_flat/
 103 ]
 104 qed-.
 105
 106 (* Inversion lemmas on relocation *******************************************)
 107
 108 lemma cpy_inv_lift1_le: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 109                         ∀K,s,d,e. ⇩[s, d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 110                         dt + et ≤ d →
 111                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[dt, et] T2 & ⇧[d, e] T2 ≡ U2.
 112 #G #L #U1 #U2 #dt #et #H elim H -G -L -U1 -U2 -dt -et
 113 [ * #i #G #L #dt #et #K #s #d #e #_ #T1 #H #_
 114   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 115   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 116   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 117   ]
 118 | #I #G #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #s #d #e #HLK #T1 #H #Hdetd
 119   lapply (ylt_yle_trans … Hdetd … Hidet) -Hdetd #Hid
 120   lapply (ylt_inv_inj … Hid) -Hid #Hid
 121   lapply (lift_inv_lref2_lt … H … Hid) -H #H destruct
 122   elim (ldrop_conf_lt … HLK … HLKV) -L // #L #U #HKL #_ #HUV
 123   elim (lift_trans_le … HUV … HVW) -V // >minus_plus <plus_minus_m_m // -Hid /3 width=5 by cpy_subst, ex2_intro/
 124 | #a #I #G #L #W1 #W2 #U1 #U2 #dt #et #_ #_ #IHW12 #IHU12 #K #s #d #e #HLK #X #H #Hdetd
 125   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 126   elim (IHW12 … HLK … HVW1) -W1 // #V2 #HV12 #HVW2
 127   elim (IHU12 … HTU1) -IHU12 -HTU1
 128   /3 width=6 by cpy_bind, yle_succ, ldrop_skip, lift_bind, ex2_intro/
 129 | #I #G #L #W1 #W2 #U1 #U2 #dt #et #_ #_ #IHW12 #IHU12 #K #s #d #e #HLK #X #H #Hdetd
 130   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 131   elim (IHW12 … HLK … HVW1) -W1 //
 132   elim (IHU12 … HLK … HTU1) -U1 -HLK
 133   /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 134 ]
 135 qed-.
 136
 137 lemma cpy_inv_lift1_be: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 138                         ∀K,s,d,e. ⇩[s, d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 139                         dt ≤ d → yinj d + e ≤ dt + et →
 140                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[dt, et-e] T2 & ⇧[d, e] T2 ≡ U2.
 141 #G #L #U1 #U2 #dt #et #H elim H -G -L -U1 -U2 -dt -et
 142 [ * #i #G #L #dt #et #K #s #d #e #_ #T1 #H #_ #_
 143   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 144   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 145   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 146   ]
 147 | #I #G #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #s #d #e #HLK #T1 #H #Hdtd #Hdedet
 148   lapply (yle_fwd_plus_ge_inj … Hdtd Hdedet) #Heet
 149   elim (lift_inv_lref2 … H) -H * #Hid #H destruct [ -Hdtd -Hidet | -Hdti -Hdedet ]
 150   [ lapply (ylt_yle_trans i d (dt+(et-e)) ? ?) /2 width=1 by ylt_inj/
 151     [ >yplus_minus_assoc_inj /2 width=1 by yle_plus_to_minus_inj2/ ] -Hdedet #Hidete
 152     elim (ldrop_conf_lt … HLK … HLKV) -L // #L #U #HKL #_ #HUV
 153     elim (lift_trans_le … HUV … HVW) -V // >minus_plus <plus_minus_m_m // -Hid
 154     /3 width=5 by cpy_subst, ex2_intro/
 155   | elim (le_inv_plus_l … Hid) #Hdie #Hei
 156     lapply (yle_trans … Hdtd (i-e) ?) /2 width=1 by yle_inj/ -Hdtd #Hdtie
 157     lapply (ldrop_conf_ge … HLK … HLKV ?) -L // #HKV
 158     elim (lift_split … HVW d (i-e+1)) -HVW [2,3,4: /2 width=1 by le_S_S, le_S/ ] -Hid -Hdie
 159     #V1 #HV1 >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O #H
 160     @(ex2_intro … H) @(cpy_subst … HKV HV1) // (**) (* explicit constructor *)
 161     >yplus_minus_assoc_inj /3 width=1 by monotonic_ylt_minus_dx, yle_inj/
 162   ]
 163 | #a #I #G #L #W1 #W2 #U1 #U2 #dt #et #_ #_ #IHW12 #IHU12 #K #s #d #e #HLK #X #H #Hdtd #Hdedet
 164   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 165   elim (IHW12 … HLK … HVW1) -W1 // #V2 #HV12 #HVW2
 166   elim (IHU12 … HTU1) -U1
 167   /3 width=6 by cpy_bind, ldrop_skip, lift_bind, yle_succ, ex2_intro/
 168 | #I #G #L #W1 #W2 #U1 #U2 #dt #et #_ #_ #IHW12 #IHU12 #K #s #d #e #HLK #X #H #Hdtd #Hdedet
 169   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 170   elim (IHW12 … HLK … HVW1) -W1 //
 171   elim (IHU12 … HLK … HTU1) -U1 -HLK //
 172   /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 173 ]
 174 qed-.
 175
 176 lemma cpy_inv_lift1_ge: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 177                         ∀K,s,d,e. ⇩[s, d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 178                         yinj d + e ≤ dt →
 179                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[dt-e, et] T2 & ⇧[d, e] T2 ≡ U2.
 180 #G #L #U1 #U2 #dt #et #H elim H -G -L -U1 -U2 -dt -et
 181 [ * #i #G #L #dt #et #K #s #d #e #_ #T1 #H #_
 182   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 183   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 184   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 185   ]
 186 | #I #G #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #s #d #e #HLK #T1 #H #Hdedt
 187   lapply (yle_trans … Hdedt … Hdti) #Hdei
 188   elim (yle_inv_plus_inj2 … Hdedt) -Hdedt #_ #Hedt
 189   elim (yle_inv_plus_inj2 … Hdei) #Hdie #Hei
 190   lapply (lift_inv_lref2_ge  … H ?) -H /2 width=1 by yle_inv_inj/ #H destruct
 191   lapply (ldrop_conf_ge … HLK … HLKV ?) -L /2 width=1 by yle_inv_inj/ #HKV
 192   elim (lift_split … HVW d (i-e+1)) -HVW [2,3,4: /3 width=1 by yle_inv_inj, le_S_S, le_S/ ] -Hdei -Hdie
 193   #V0 #HV10 >plus_minus /2 width=1 by yle_inv_inj/ <minus_minus /3 width=1 by yle_inv_inj, le_S/ <minus_n_n <plus_n_O #H
 194   @(ex2_intro … H) @(cpy_subst … HKV HV10) (**) (* explicit constructor *)
 195   [ /2 width=1 by monotonic_yle_minus_dx/
 196   | <yplus_minus_comm_inj /2 width=1 by monotonic_ylt_minus_dx/
 197   ]
 198 | #a #I #G #L #W1 #W2 #U1 #U2 #dt #et #_ #_ #IHW12 #IHU12 #K #s #d #e #HLK #X #H #Hdetd
 199   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 200   elim (yle_inv_plus_inj2 … Hdetd) #_ #Hedt
 201   elim (IHW12 … HLK … HVW1) -W1 // #V2 #HV12 #HVW2
 202   elim (IHU12 … HTU1) -U1 [4: @ldrop_skip // |2,5: skip |3: /2 width=1 by yle_succ/ ]
 203   >yminus_succ1_inj /3 width=5 by cpy_bind, lift_bind, ex2_intro/
 204 | #I #G #L #W1 #W2 #U1 #U2 #dt #et #_ #_ #IHW12 #IHU12 #K #s #d #e #HLK #X #H #Hdetd
 205   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 206   elim (IHW12 … HLK … HVW1) -W1 //
 207   elim (IHU12 … HLK … HTU1) -U1 -HLK /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 208 ]
 209 qed-.
 210
 211 (* Advancd inversion lemmas on relocation ***********************************)
 212
 213 lemma cpy_inv_lift1_ge_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 214                            ∀K,s,d,e. ⇩[s, d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 215                            d ≤ dt → dt ≤ yinj d + e → yinj d + e ≤ dt + et →
 216                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[d, dt + et - (yinj d + e)] T2 & ⇧[d, e] T2 ≡ U2.
 217 #G #L #U1 #U2 #dt #et #HU12 #K #s #d #e #HLK #T1 #HTU1 #Hddt #Hdtde #Hdedet
 218 elim (cpy_split_up … HU12 (d + e)) -HU12 // -Hdedet #U #HU1 #HU2
 219 lapply (cpy_weak … HU1 d e ? ?) -HU1 // [ >ymax_pre_sn_comm // ] -Hddt -Hdtde #HU1
 220 lapply (cpy_inv_lift1_eq … HTU1 … HU1) -HU1 #HU1 destruct
 221 elim (cpy_inv_lift1_ge … HU2 … HLK … HTU1) -U -L /2 width=3 by ex2_intro/
 222 qed-.
 223
 224 lemma cpy_inv_lift1_be_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 225                            ∀K,s,d,e. ⇩[s, d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 226                            dt ≤ d → dt + et ≤ yinj d + e →
 227                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[dt, d-dt] T2 & ⇧[d, e] T2 ≡ U2.
 228 #G #L #U1 #U2 #dt #et #HU12 #K #s #d #e #HLK #T1 #HTU1 #Hdtd #Hdetde
 229 lapply (cpy_weak … HU12 dt (d+e-dt) ? ?) -HU12 //
 230 [ >ymax_pre_sn_comm /2 width=1 by yle_plus_dx1_trans/ ] -Hdetde #HU12
 231 elim (cpy_inv_lift1_be … HU12 … HLK … HTU1) -U1 -L /2 width=3 by ex2_intro/
 232 qed-.
 233
 234 lemma cpy_inv_lift1_le_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 235                            ∀K,s,d,e. ⇩[s, d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 236                            dt ≤ d → d ≤ dt + et → dt + et ≤ yinj d + e →
 237                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[dt, d - dt] T2 & ⇧[d, e] T2 ≡ U2.
 238 #G #L #U1 #U2 #dt #et #HU12 #K #s #d #e #HLK #T1 #HTU1 #Hdtd #Hddet #Hdetde
 239 elim (cpy_split_up … HU12 d) -HU12 // #U #HU1 #HU2
 240 elim (cpy_inv_lift1_le … HU1 … HLK … HTU1) -U1
 241 [2: >ymax_pre_sn_comm // ] -Hdtd #T #HT1 #HTU
 242 lapply (cpy_weak … HU2 d e ? ?) -HU2 //
 243 [ >ymax_pre_sn_comm // ] -Hddet -Hdetde #HU2
 244 lapply (cpy_inv_lift1_eq … HTU … HU2) -L #H destruct /2 width=3 by ex2_intro/
 245 qed-.